XL 2019 Rapatrier des données de plusieurs feuilles (nombre évolutif) dans un seul tableau récapitulatif

[battijo]

Bonjour tout le monde,

j'ai un fichier avec plusieurs feuilles formatées à l'identique.
je souhaiterais avoir une feuille avec un récapitulatif de certaines données de ces feuilles.
Le soucis, c'est qu'il agit d'un fichier alimenté au fil de l'eau et donc le nombre d'onglet créés est évolutif.
Sur le fichier joint, j'ai 3 feuilles créées et j'ai fait le tableau récap.
Mon but serait donc d'alimenter ce tableau, par une macro je pense, quand je le souhaite et quand j'estimerais avoir realisé assez de saisies.
En bref, alimenter un tableau avec autant de ligne qu'il y a de feuilles avec un bouton macro, qui me "scan" l'intégralité du classeur, et me ramène les données A2 à A4, B2 à B4 et C2 à C4 de chaque feuille.

En espérant avoir été clair.

par avance, dors et déja merci à ceux qui perdront du temps à y réfléchir.

Bonne journée

 

[job75]

Bonjour battijo,

Sub MAJ()
Dim w As Worksheet, n%
ReDim resu(1 To Worksheets.Count, 1 To 3)
For Each w In Worksheets
    If w.Name Like "Avis*" Then
        n = n + 1
        resu(n, 1) = w.Cells(1, 2)
        resu(n, 2) = w.Cells(2, 2)
        resu(n, 3) = w.Cells(3, 2)
    End If
Next
'---restitution---
With Sheets("Recap").[A2]
    If n Then .Resize(n, 3) = resu
    .Offset(n).Resize(Rows.Count - n - .Row + 1, 3).ClearContents 'RAZ en dessous
End With
End Sub

A+

 

[battijo]

Super, merci ca marche nickel...
Pour compléter mon fichier, je souhaiterais, une fois le récap généré, renommer chaque onglet Avis accompagné du nom de l'individu. J'ai trouvé des solutions, mais tous les onglets sont renommés (y compris recap) ou seul un onglet est renommé...je bug...cela est du a ma petite connaissance du vba.
Si quelqu'un peux m'aider?

dans tous les cas, deja un grand merci

 

[job75]

Pour compléter mon fichier, je souhaiterais, une fois le récap généré, renommer chaque onglet Avis accompagné du nom de l'individu.

Sub Renommer()
Dim w As Worksheet
For Each w In Worksheets
    If w.Name Like "Avis*" Then w.Name = "Avis " & w.Cells(1, 2)
Next
End Sub