Problème sur formule matricielle pour extraire des lignes d'une BD

[Barbapapa]

Bonjour à tous, j'ai adapté une formule que j'ai trouvé sur le site de Mr Boisgontier (merci à lui) que je cherche à adapter pour extraire des lignes d'une BD suivant 2 critères.
La formule est : {=INDEX(bdabs1;EQUIV(1;(bdabs3=$A$3)*(bdabs2=$E$3);0))} et je cherche à l'adapter en formule du type LIGNES($1:1)...... J'ai essayé mais je n'y arrive pas.
J'ai mis un exemple dans un fichier en pièce jointe.
Merci d'avance et bonne soirée !
Frédéric

 

[BOISGONTIER]

Re : Problème sur formule matricielle pour extraire des lignes d'une BD

Bonjour,

Cf pj

-sélectionner A5:F12
=SI(ESTERREUR(PETITE.VALEUR(SI((INDEX(BD;;2)=E3)*(INDEX(BD;;7)=A3);LIGNE(INDIRECT("1:"&LIGNES(BD))));LIGNE(1:10)));"";INDEX(BD;PETITE.VALEUR(SI((INDEX(BD;;2)=E3)*(INDEX(BD;;7)=A3);LIGNE(INDIRECT("1:"&LIGNES(BD))));LIGNE(1:100));COLONNE(A:F)))
-Valider avec maj+ctrl+entrée

ou Excel 7 +

=SiErreur(INDEX(BD;PETITE.VALEUR(SI((INDEX(BD;;2)=E3)*(INDEX(BD;;7)=A3);LIGNE(INDIRECT("1:"&LIGNES(BD))));LIGNE(1:100));COLONNE(A:F));"")

http://boisgontierjacques.free.fr/fichiers/Matriciel/FiltreBD2.xls


JB

 

[Barbapapa]

Re : Problème sur formule matricielle pour extraire des lignes d'une BD

Bonjour et merci de votre aide monsieur. Je vais essayer d'adapter votre formule à mon fichier.
Mais c'est toujours difficile d'expliquer ce que l'on veut même avec un fichier.
En fait j'aimerai mieux une formule différente pour chaque colonne afin de pouvoir afficher le résultat de la colonne que l'on veut. Dans ma bd d'origine il y a des colonnes dont je n'ai pas besoin d'afficher le résultat.
Je ne sais pas si c'est possible.
Encore merci et bonne soirée.
Frédéric

 

[BOISGONTIER]

Re : Problème sur formule matricielle pour extraire des lignes d'une BD

voir PJ

=SI(LIGNES($1:1)<=SOMME(($A$3=bdabs3)*($E$3=bdabs2));
INDEX(bdabs1;PETITE.VALEUR(SI(($A$3=bdabs3)*($E$3=bdabs2);LIGNE(INDIRECT("1:"&LIGNES(bdabs1))));LIGNES($1:1)));"")

http://boisgontierjacques.free.fr/fichiers/Matriciel/FiltreBD3.xls

JB

 

[Barbapapa]

Re : Problème sur formule matricielle pour extraire des lignes d'une BD

Encore merci, et merci pour votre rapidité. C'est ce que je cherchais. En plus j'aurai 2 exemples pour faire ce type de recherche.
Je vous souhaite une très bonne soirée !
Frédéric