XL 2013 Problème Formule

fanfan38

XLDnaute Barbatruc

• 13 Octobre 2017

• #2

Bonjour
Je te propose: =SI(ENT(E3)<>E3;E3*1000;E3)

A+ François

 

Vote positif 0 Vote négatif

pierrejean

XLDnaute Barbatruc

• 13 Octobre 2017

• #3

Bonjour Mud92
=SI(D3=ENT(D3);D3;D3*1000)

 

Pièces jointes

• Problème formule.xlsx

  8 KB · Affichages: 16

Vote positif 0 Vote négatif

Meud92

XLDnaute Nouveau

• 13 Octobre 2017

• #4

Merci François et Pierrejean pour votre aide !!! Cela à l'air de bien fonctionné...Je verrais lundi au boulot si ça fonctionne bien sur le gros fichier. Encore Merci et bonne soirée.

 

Vote positif 0 Vote négatif

Meud92

XLDnaute Nouveau

• 16 Octobre 2017

• #5

Bonjour Messieurs,
Je viens de découvrir d'autres soucis par rapport au fichier ci-dessous.
Ces données viennent d'un fichier américain et c'est pour cela que j'ai demandé votre aide.
Si vous pouviez regarder le fichier à nouveau j'ai mis des commentaires.
J'aimerais que dans la formule qui fonctionne très bien d'ailleurs on puisse rajouter que si le chiffre est écrit .345 ou 1.54 cela fasse 0,345 et 1,54. De même si le chiffre est écrit 1,456,78 cela fasse 1 456 780.
Pensez-vous que cela soit possible dans la même formule.
Car tous ces cas se retrouvent dans un même fichier.
Un grand merci pour votre aide !!!

 

Pièces jointes

• Problème formule (1).xlsx

  10.3 KB · Affichages: 21

Vote positif 0 Vote négatif

CISCO

XLDnaute Barbatruc

• 16 Octobre 2017

• #6

Bonjour

Et est-ce que par hasard, tu n'aurais pas des nombres du style 10,452.23, qui devrait donner 10 452,23 ?

@ plus

 

Vote positif 0 Vote négatif

Modeste geedee

XLDnaute Barbatruc

• 16 Octobre 2017

• #7

Bonsour®

Meud92 à dit:

Bonjour Messieurs,
Je viens de découvrir d'autres soucis par rapport au fichier ci-dessous.
Ces données viennent d'un fichier américain et c'est pour cela que j'ai demandé votre aide.
Si vous pouviez regarder le fichier à nouveau j'ai mis des commentaires.
J'aimerais que dans la formule qui fonctionne très bien d'ailleurs on puisse rajouter que si le chiffre est écrit .345 ou 1.54 cela fasse 0,345 et 1,54. De même si le chiffre est écrit 1,456,78 cela fasse 1 456 780.
Pensez-vous que cela soit possible dans la même formule.
Car tous ces cas se retrouvent dans un même fichier.
Un grand merci pour votre aide !!!

Cliquez pour agrandir...

=1*SUBSTITUE(SUBSTITUE(E1;",";"");".";",")

 

Vote positif 0 Vote négatif

CISCO

XLDnaute Barbatruc

• 16 Octobre 2017

• #8

Bonjour à tous

Tu peux faire avec

Code:

=--SUBSTITUE(SUBSTITUE(SI(CHERCHE(".";C3&".")=1;SUBSTITUE(C3;".";"0*");SUBSTITUE(C3;".";"*"))&REPT("0";SIERREUR(CHERCHE(",";DROITE("0"&C3;4))-1;0));",";"");"*";",")

@ plus

 

Vote positif 0 Vote négatif

Meud92

XLDnaute Nouveau

• 16 Octobre 2017

• #9

Bonjour cisco
Merci pour ton aide mais je débute sur excel et ne suit pas doué pour le moment avec des formules compliquées. Moi les bases ça va mais le reste...
Merci, la formule à l'air de bien fonctonnée, c'est génial !!! Un grand merci à toi.
Et tu as raison concernant le style 10,452.23, qui devrait donner 10 452,23 !! Je n'y avais pas pensé !!! Ta formule permet aussi de modifier ce genre de chiffre ?

 

Dernière édition: 16 Octobre 2017

Vote positif 0 Vote négatif

CISCO

XLDnaute Barbatruc

• 16 Octobre 2017

• #10

Bonjour

Un petit peu plus simple

Code:

--SUBSTITUE(SUBSTITUE(SUBSTITUE(C3;".";"*")&REPT("0";SIERREUR(CHERCHE(",";DROITE("0"&C3;4))-1;0));",";"");"*";",")

@ plus

P.S1 : C'est la même méthode que précédemment, sans chercher à transformer ,15 en 0,15, car Excel le fait automatiquement pour les valeurs au format nombre.

PS2 : La formule est compliquée pour aussi tenir compte des valeurs n'ayant pas trois caractères après la dernière virgule, du style 15,12 qu'il faut transformer en 15120. les écrits comme 4,456 ne posent pas de problème.

 

Vote positif 0 Vote négatif

Meud92

XLDnaute Nouveau

• 16 Octobre 2017

• #11

Alors là merci cisco, tu nous sauves !!! Ca à l'air de super bien fonctionné. On verra à l'usage avec ces putains de fichiers ricains !!! oups je m'égare !!! Bonne fin de journée à tous. Et merci à ceux qui m'ont aidé depuis le début aussi...

 

Vote positif 0 Vote négatif

Meud92

XLDnaute Nouveau

• 27 Octobre 2017

• #12

Bonjour CISCO
Excuse-moi de te déranger à nouveau mais pourrais-tu modifier la formule de manière à ce qu'un chiffre entier soit multiplier par mille. Par exemple, 1 devient 1000, 240 devient 240 000 etc...
Je sais que j'ai demandé à ce que les entiers soit laissé tel quel mais les ricains ont changé leur unité !!! Maudit soit-il...
En pièce jointe le fichier avec formule d'origine.
Bien sûr si quelqu'un d'autre sait il est le bienvenu !!!
Un grand merci à vous.

 

Pièces jointes

• conv_format_anglo_saxon_formcourte.xlsx

  10.8 KB · Affichages: 15

Vote positif 0 Vote négatif

CISCO

XLDnaute Barbatruc

• 27 Octobre 2017

• #13

Bonjour

Tu peux faire avec

Code:

=SI(ENT(B3)=B3;B3*1000;--SUBSTITUE(SUBSTITUE(SUBSTITUE(B3;".";"*")&REPT("0";SIERREUR(CHERCHE(",";DROITE("0"&B3;4))-1;0));",";"");"*";","))

C'est presque la même formule que l'autre fois, sauf le début.

@ plus

 

Vote positif 0 Vote négatif

Meud92

XLDnaute Nouveau

• 27 Octobre 2017

• #14

Merci CISCO. Il y a juste un soucis avec certains chiffres avec la nouvelle formule. Regarde le fichier. Il est indiqué "valeur" pour certains chiffres.

 

Pièces jointes

• conv_format_anglo_saxon_formcourte.xlsx

  9.7 KB · Affichages: 15

Vote positif 0 Vote négatif

CISCO

XLDnaute Barbatruc

• 27 Octobre 2017

• #15

Bonjour

Ca ira peut être mieux avec

Code:

SI(SIERREUR(ENT(B3)=B3;0);B3*1000;--SUBSTITUE(SUBSTITUE(SUBSTITUE(B3;".";"*")&REPT("0";SIERREUR(CHERCHE(",";DROITE("0"&B3;4))-1;0));",";"");"*";","))

Il ni a que le début qui change.

@ plus

 

Vote positif 0 Vote négatif