Problème de calcul de matrice

[Syldar]

Bonjour à tous !

J'ai un problème pour programme une feuille de personnage de jeux de rôle, c'est ma première feuille excel, aussi je galère.

Alors voilà mon problème, j'ai un tableau dont j'aimerai pouvoir rechercher une cellule dont le résultat approcherai un chiffre que je recherche, dans une colonne, pour que j'obtienne le résultat en début de ligne.

Pas très clair... Pour faire simple j'aimerai pouvoir faire une recherche automatique, comme dans un abaque, en partant d'une cellule et d'une colonne.

Dans le fichier Excel que j'envoie, j'ai mis trois cases en couleurs.

La case rouge donne est la colonne (base) dans laquelle il faut chercher dans le tableau (onglet tableau)

La case bleue indique le nombre approximatif qu'il faut trouver dans la colonne (sans le dépasser).

La case jaune doit contenir le résultat de ma recherche dans le tableau (donc dans l'exemple excel doit savoir automatiquement chercher dans la colonne base 26, 89, qui correspond à 4, qui est mon résultat).

Les chiffres en rouge du premier onglet se calculent tous seuls grâce à une formule simple, et ils sont destinés à fluctuer, ainsi que les points de dévelopement (Dev.), qui vont augmenter peu à peu, au cours du jeu.

Le top serait même de créer la formule dans la case jaune, et de m'expliquer ensuite comment reproduire ce schéma sur le reste.

Voilà, merci à tous pour d'eventuelles réponses et éclaircissements.

Have a nice day.

 

[carlos]

salut

es ce que rouge à 610 donne 14 en jaune pour beu à 26 ??

Juste pour etre sur de comprendre .

 

[syldar]

Hello !

Non, le point de départ c'est ce qui est en bleu, par exemple 310(bleu), et si on est en base 14(rouge), et bien cela nous donne 17 (avec 299, puisque le niveau suivant est à 329 points).

Merci !

 

[carlos]

Salut Syldar

Tu peux essayer cette formule , ca devrait marcher

=SI(F23="";"";INDIRECT("tableau!A"&EQUIV(F23;INDIRECT("tableau!"&ADRESSE(3;EQUIV(E23;Tableau!$B$1:$Z$1;0)+1;2)&":"&ADRESSE(43;EQUIV(E23;Tableau!$B$1:$Z$1;0)+1;2));1)+2))

Ton fichier est normalement operationnel.

Carlos

 

[Jean-Marie]

Bonjour

Autres solutions en utilisant les Fonctions INDEX et EQUIV

=INDEX(Tableau!$A$3:$A$43;EQUIV(F23;(INDEX(Tableau!$B$3:$Z$43;0;EQUIV(E23;Tableau!$B$1:$Z$1;0)));1);1)

En utilisant une valeur 0 dans le 2ème ou 3ème argument de la fonction INDEX, c'est toute la ligne ou la colonne qui est retournée comme une "matrice".

ou cette fonction, en remplaçant une fonction INDEX par un DECALER

=INDEX(Tableau!$A$3:$A$43;EQUIV(F23;(DECALER(Tableau!$A$3:$A$43;0;EQUIV(E23;Tableau!$B$1:$Z$1;0)));1);1)

@+Jean-Marie

 

[syldar]

Waouw !

Merci beaucoup, c'est vraiment génial, tout marche à la perfection !

Et tu as même fais tous les copier-coller, encore merci !!

Joyeux noël à toi et déjà une bonne année !

Syldar

 

[carlos]

Bravo J Marie

ta formule est encore plus simple que la mienne.