Plusieurs conditions avec ou

[Chasse]

Bonjour le forum
J'ai un petit problème de ou ? je n’arrive pas à trouver leur place.

=SI(MOIS(AUJOURDHUI())=1ou 4 ou 7 ou 10 ;D56;SI(MOIS(AUJOURDHUI())=2 ou 5 ou 8 ou 11;D57;D58))

Merci de votre aide

 

[CISCO]

Re : Plusieurs conditions avec ou

Bonjour

Tu peux essayer avec

=SI(OU(MOIS(AUJOURDHUI())=1;MOIS(AUJOURDHUI())=4;MOIS(AUJOURDHUI())=7;MOIS(AUJOURDHUI())=10);D56;SI(OU(MOIS(AUJOURDHUI())=2;MOIS(AUJOURDHUI())=5;MOIS(AUJOURDHUI())=8;MOIS(AUJOURDHUI())=11);D57);D58)

ou même peut être plus simplement
=CHOISIR(MOIS(AUJOURDHUI());D56;D57;D58;D56....) à compléter

@ plus

 

[ERIC S]

Re : Plusieurs conditions avec ou

bonjour

=CHOISIR(MOIS(AUJOURDHUI());G1;G2;G3;G4;G5;G6;G7;G8;G9;G10;G11;G12)

doit aussi marcher

Bonjour CISCO, plus rapide que moi

 

[abcd]

Re : Plusieurs conditions avec ou

Bonjour, salut Cisco,

A essayer :
=SI(MOD(MOIS(AUJOURDHUI())-1;3)=0;D56;SI(MOD(MOIS(AUJOURDHUI())-1;3)=1;D57;D58))

abcd

 

[CISCO]

Re : Plusieurs conditions avec ou

Rebonjour

En faisant un mixte de toutes les propositions, toujours en jouant sur le coté "multiple" de 3 ou pas, peut être avec

=CHOISIR(MOD(MOIS(AUJOURDHUI())-1;3)+1;D56;D57;D58)

@ plus

 

[abcd]

Re : Plusieurs conditions avec ou

Re,

Un petit mélange des deux propositions :
=CHOISIR(MOD(MOIS(AUJOURDHUI())-1;3)+1;D56;D57;D58)

A vérfier si les trois cellules (D56, D57 et D58) sont dans le bon ordre.

abcd

Edition :
Heureusement que l'heure s'affiche, faute de quoi ... (lol)

 

[CISCO]

Re : Plusieurs conditions avec ou

Re,


Edition :
Heureusement que l'heure s'affiche, faute de quoi ... (lol)

🙂🙂🙂🙂🙂🙂🙂

 

[Chasse]

Re : Plusieurs conditions avec ou

Merci a tous de vos réponses

Il y en a bien une qui va me servir et en plus il me restera mes "ou"

Bonne soirée

 

[Monique]

Re : Plusieurs conditions avec ou

Bonjour tous,

ou bien
=DECALER(D56;MOD(MOIS(AUJOURDHUI())-1;3);0)

ou bien
=INDEX(D56 : D58;MOD(MOIS(AUJOURDHUI())-1;3)+1)

 

[abcd]

Re : Plusieurs conditions avec ou

Re,

Te voilà devant un gros problème, il va falloir choisir entre la proposition de Cisco et la mienne !
Je ne voudrais pas être ta place.

abcd