Planning travaux- modification des dates

[harprune]

Bonjour à tous,

Je suis nouveau sur le forum et j'aurais besoin de votre aide pour peaufiner mon planning de travaux.

Vous trouverez la première ébauche en pièce jointe.
Comme vous pouvez le voir c'est un planning hebdomadaire.

Mon projet est de pouvoir modifier les mois et numéros de semaines annuelles du planning selon une date de début de planning et une date de fin de planning.


Pourriez vous m'aider ?

Merci!

 

[Gurgeh]

Re : Planning travaux- modification des dates

Salut harprune,

Je te propose une formule qui va te renvoyer

Semaine xx
(yy - zz)

xx étant le numéro de la semaine, yy le premier jour de la semaine xx, zz le vendredi de la semaine xx.

Tout d'abord, il faut l'année, que tu rentres en cellule D6, puis le numéro de la semaine de départ de ton calendrier, que tu rentres en D8.

La formule

=DATE($D$6;1;3)-JOURSEM(DATE($D$6;1;3))-5+7*$D$8

va te donner le premier jour de la semaine $D$8 de l'année $D$6
Pour avoir juste le numéro du jour, tu rajoutes la fonction JOUR()

=JOUR(DATE($D$6;1;3)-JOURSEM(DATE($D$6;1;3))-5+7*$D$8)

Et pour avoir le vendredi, tu ajoutes 4 :

=JOUR(DATE($D$6;1;3)-JOURSEM(DATE($D$6;1;3))-5+7*$D$8+4)

Ensuite, pour pouvoir tirer ta formule vers la droite, il faut que le numéro de semaine augmente de 1 à chaque nouvelle colonne, donc au lieu de mettre $D$8, on va mettre

$D$8+COLONNES($H:H)

ce qui augmentera de 1 pour chaque colonne à droite de la colonne H.

Avec un peu de cosmétique autour, voici la formule que tu dois utiliser et tirer vers la droite :

="Semaine "&$D$8+COLONNES($H:H)&CAR(10)&"("&JOUR(DATE($D$6;1;3)-JOURSEM(DATE($D$6;1;3))-5+7*($D$8+COLONNES($H:H)))&"-" & JOUR(DATE($D$6;1;3)-JOURSEM(DATE($D$6;1;3))-1+7*($D$8+COLONNES($H:H)))&")"

Et le tout dans le fichier joint pour mieux comprendre.

Gurgeh

 

[harprune]

Re : Planning travaux- modification des dates

Salut harprune,

Je te propose une formule qui va te renvoyer

Semaine xx
(yy - zz)

xx étant le numéro de la semaine, yy le premier jour de la semaine xx, zz le vendredi de la semaine xx.

Tout d'abord, il faut l'année, que tu rentres en cellule D6, puis le numéro de la semaine de départ de ton calendrier, que tu rentres en D8.

La formule

=DATE($D$6;1;3)-JOURSEM(DATE($D$6;1;3))-5+7*$D$8

va te donner le premier jour de la semaine $D$8 de l'année $D$6
Pour avoir juste le numéro du jour, tu rajoutes la fonction JOUR()

=JOUR(DATE($D$6;1;3)-JOURSEM(DATE($D$6;1;3))-5+7*$D$8)

Et pour avoir le vendredi, tu ajoutes 4 :

=JOUR(DATE($D$6;1;3)-JOURSEM(DATE($D$6;1;3))-5+7*$D$8+4)

Ensuite, pour pouvoir tirer ta formule vers la droite, il faut que le numéro de semaine augmente de 1 à chaque nouvelle colonne, donc au lieu de mettre $D$8, on va mettre

$D$8+COLONNES($H:H)

ce qui augmentera de 1 pour chaque colonne à droite de la colonne H.

Avec un peu de cosmétique autour, voici la formule que tu dois utiliser et tirer vers la droite :

="Semaine "&$D$8+COLONNES($H:H)&CAR(10)&"("&JOUR(DATE($D$6;1;3)-JOURSEM(DATE($D$6;1;3))-5+7*($D$8+COLONNES($H:H)))&"-" & JOUR(DATE($D$6;1;3)-JOURSEM(DATE($D$6;1;3))-1+7*($D$8+COLONNES($H:H)))&")"

Et le tout dans le fichier joint pour mieux comprendre.

Gurgeh

Merci Gurgeh pour ton aide.

Tu as mis "Et le tout dans le fichier joint pour mieux comprendre" mais je ne vois pas le fichier que tu as joint...

 

[harprune]

Re : Planning travaux- modification des dates

Merci Gurgeh pour ton aide.

Tu as mis "Et le tout dans le fichier joint pour mieux comprendre" mais je ne vois pas le fichier que tu as joint...

J'ai réussi !! Merci Gurgeh!

Aurais-tu une astuce pour afficher le mois automatiquement ?

 

[Gurgeh]

Re : Planning travaux- modification des dates

Ah tiens, le fichier n'est pas passé (trop gros). Je le remets.

Pour le mois, j'ai bien une solution, mais rien qui fusionne des cellules (par principe je ne travaille pas avec des cellules fusionnées, c'est pas éthique 😛)

Sinon, tu peux avoir le nom du mois d'une date donnée en faisant :

=TEXTE(date;"mmmm")

Gurgeh

 

[Gurgeh]

Re : Planning travaux- modification des dates

Bon, à la rigueur, tu peux mettre ça en H9 et tirer à droite :

=SI(OU(MOIS(DATE($D$6;1;3)-JOURSEM(DATE($D$6;1;3))-5+7*($D$8+COLONNES($H:H)))<>MOIS(DATE($D$6;1;3)-JOURSEM(DATE($D$6;1;3))-5+7*($D$8+COLONNES($H:H)-1));COLONNES($H:H)=1);TEXTE(DATE($D$6;1;3)-JOURSEM(DATE($D$6;1;3))-5+7*($D$8+COLONNES($H:H));"mmmm");"")

Cap t'affiche le nom du mois sur les colonnes correspondant à un changement de mois...

Gurgeh

 

[harprune]

Re : Planning travaux- modification des dates

Ah tiens, le fichier n'est pas passé (trop gros). Je le remets.

Pour le mois, j'ai bien une solution, mais rien qui fusionne des cellules (par principe je ne travaille pas avec des cellules fusionnées, c'est pas éthique 😛)

Sinon, tu peux avoir le nom du mois d'une date donnée en faisant :

=TEXTE(date;"mmmm")

Gurgeh

Je te remercie Gurgeh !!!