Planning travaux- modification des dates

Gurgeh à dit:

Salut harprune,

Je te propose une formule qui va te renvoyer

Code:

Semaine xx
(yy - zz)

xx étant le numéro de la semaine, yy le premier jour de la semaine xx, zz le vendredi de la semaine xx.

Tout d'abord, il faut l'année, que tu rentres en cellule D6, puis le numéro de la semaine de départ de ton calendrier, que tu rentres en D8.

La formule

Code:

=DATE($D$6;1;3)-JOURSEM(DATE($D$6;1;3))-5+7*$D$8

va te donner le premier jour de la semaine $D$8 de l'année $D$6
Pour avoir juste le numéro du jour, tu rajoutes la fonction JOUR()

Code:

=JOUR(DATE($D$6;1;3)-JOURSEM(DATE($D$6;1;3))-5+7*$D$8)

Et pour avoir le vendredi, tu ajoutes 4 :

Code:

=JOUR(DATE($D$6;1;3)-JOURSEM(DATE($D$6;1;3))-5+7*$D$8+4)

Ensuite, pour pouvoir tirer ta formule vers la droite, il faut que le numéro de semaine augmente de 1 à chaque nouvelle colonne, donc au lieu de mettre $D$8, on va mettre

Code:

$D$8+COLONNES($H:H)

ce qui augmentera de 1 pour chaque colonne à droite de la colonne H.

Avec un peu de cosmétique autour, voici la formule que tu dois utiliser et tirer vers la droite :

Code:

="Semaine "&$D$8+COLONNES($H:H)&CAR(10)&"("&JOUR(DATE($D$6;1;3)-JOURSEM(DATE($D$6;1;3))-5+7*($D$8+COLONNES($H:H)))&"-" & JOUR(DATE($D$6;1;3)-JOURSEM(DATE($D$6;1;3))-1+7*($D$8+COLONNES($H:H)))&")"

Et le tout dans le fichier joint pour mieux comprendre.

Gurgeh

Cliquez pour agrandir...

harprune à dit:

Merci Gurgeh pour ton aide.

Tu as mis "Et le tout dans le fichier joint pour mieux comprendre" mais je ne vois pas le fichier que tu as joint...

Cliquez pour agrandir...

Gurgeh à dit:

Ah tiens, le fichier n'est pas passé (trop gros). Je le remets.

Pour le mois, j'ai bien une solution, mais rien qui fusionne des cellules (par principe je ne travaille pas avec des cellules fusionnées, c'est pas éthique 😛)

Sinon, tu peux avoir le nom du mois d'une date donnée en faisant :

Code:

=TEXTE(date;"mmmm")

Gurgeh

Cliquez pour agrandir...