XL 2016 Petit souci avec un tableau

[Don pépé]

Bien le bonjour le forum 😉 ,
Voila j'ai fait un tableau nommer "Tableau1" sur la feuille BdClients, de se tableau je veux récupérer les données pour les mettres dans une autre feuille "Bilan".

J'ai fait ceci :

=SOMMEPROD((ANNEE(Tableau1[Début])=$B$1)*(ANNEE(Tableau1[Fin])=$B$1)*(MOIS(Tableau1[Début])=MOIS($A3))*(MOIS(Tableau1[Fin])=MOIS($A3))*Tableau1[Adulte])

B1 correspond à l'année et A3 au numéro du mois Janvier
Mon problème est quand je fait ceci:

=SOMMEPROD((ANNEE(Tableau1[Début])=$B$1)*(ANNEE(Tableau1[Fin])=$B$1)*(MOIS(Tableau1[Début])=MOIS($A4))*(MOIS(Tableau1[Fin])=MOIS($A4))*Tableau1[Adulte])

donc B1 toujours l'année et A4 le mois de Février, mais sa me prend toujours le mois de Janvier je ne comprend pas pourquoi.

J'aurais besoin de vos lumières car la je comprend pas pourquoi.

Merci a vous 😉

 

[JCGL]

Bonjour à tous,

Quelle est la valeur exacte en A3 ?

A+ à tous

 

[Don pépé]

Bonjour JCGL
Les valeurs sont:
A3 = 1
A4 = 2
et ainsi de suite jusqu'a A14 = 12

merci

 

[JCGL]

Bonjour à tous,

Alors ceci devrait convenir :

=SOMMEPROD((ANNEE(Tableau1[Début])=$B$1)*(ANNEE(Tableau1[Fin])=$B$1)*(MOIS(Tableau1[Début])=$A3)*(MOIS(Tableau1[Fin])=$A3)*Tableau1[Adulte])

Si en A3, tu avais Janvier (texte) :

=SOMMEPROD((ANNEE(Tableau1[Début])=$B$1)*(ANNEE(Tableau1[Fin])=$B$1)*(MOIS(Tableau1[Début])=MOIS(1&$A3))*(MOIS(Tableau1[Fin])=MOIS(1&$A3))*Tableau1[Adulte])

A+ à tous

 

[Don pépé]

Merci a toi cela me convient parfaitement. encore merci

 

[Don pépé]

J'ai encore une petite question.
dans le tableau1 sur ma feuille BdClients jai une colone avec comme nom Mode de règlement, je voudrais savoir comment compter le nombre de cellule comportant le mot cartes ??

 

[JCGL]

Bonjour à tous,

Peux-tu essayer avec :

=NB.SI(Tableau1[Mode de règlement];"Cartes")

A+ à tous

 

[Don pépé]

Merci,
Alors quand je met:

=SOMMEPROD((ANNEE(Tableau1[Début])=$D$1)*(ANNEE(Tableau1[Fin])=$D$1)*(MOIS(Tableau1[Début])=$A3)*(MOIS(Tableau1[Fin])=$A3)*NB.SI(Tableau1[Mode de règlement];"Cartes"))

sa me donne pas le bon compte
par contre quand je met juste la formule que tu a mis sa me donne le bon compte pourquoi ??

 

[JCGL]

Bonjour à tous,

Peux-tu essayer :

=SOMMEPROD((ANNEE(Tableau1[Début])=$C$1)*(ANNEE(Tableau1[Fin])=$C$1)*(MOIS(Tableau1[Début])=$A3)*(MOIS(Tableau1[Fin])=$A3)*(Tableau1[Mode de règlement]="Cartes"))

A+ à tous

 

[Don pépé]

merci pour tas réponse c'était une faute d'inattention de ma part 😉