Pb avec une formule

[Bcar]

Bonjour le Forum,
Voila mon souci est le suivant:
En I5 la cellule peut prendre des valeurs comprises entre 0% et 100%.
En I6 je souhaite que la cellule prenne la valeur 0,1,2,3,4 en fonction du taux contenu en I5.
J'ai donc ecris la formule ci dessous qui me renvoie "vrai" ou "faux":
=OU(SI(I5<0,25;0;0);SI((ET(I5>=0,25;I5<0,5));1;0);SI((ET(I5>=0,5;I5<0,65));2;0);SI((ET(I5>=0,65;I5<0,8));3;0);SI(I5>=0,8;4;0))
Pourquoi je n'obtiens pas le resultat du test SI correspondant à la valeur?
Merci par avance pour votre aide

 

[bcharef]

Re : Pb avec une formule

Bonjour Bcar,
Bonjour à toutes et à tous.

Si, j'ai bien compris le problème, essayez de consulter le fichier ci joint dans l'espoir qu'il vous conviendra.

A vous lire et bon courage.

Cordialement.

Bcharef.

 

[Gael]

Re : Pb avec une formule

Bonjour Bcar, bonjour Bcharef,

Tu peux aussi utiliser la formule suivante:

=EQUIV(I5;{0;0,25;0,5;0,65;0,8})-1

@+

Gael

 

[tbft]

Re : Pb avec une formule

Bonjour

en I6
=SOMME(SI(I5<0,25;0;0);SI((ET(I5>=0,25;I5<0,5));1;0);SI((ET(I5>=0,5;I5<0,65));2;0);SI((ET(I5>=0,65;I5<0,8));3;0);SI(I5>=0,8;4;0))

Est que cela correspond à ce qui est recherché?
Si c'est pas le cas, serait il possible de donner un table de correspondance plus précise..

 

[abcd]

Re : Pb avec une formule

Bonjour,

Autre possibilité parmi beaucoup de solutions :
=(I5>=0.25)+(I5>=0.5)+(I5>=0.65)+(I5>=0.8)

Il y a aussi :
=CHOISIR(EQUIV(I5;{0;0.25;0.5;0.65;0.8});0;1;2;3;4)

abcd

 

[Bcar]

Re : Pb avec une formule

Merci Bcharef, c'est le resultat attendu.
Bon week end.
Cordialement,
Bcar

 

[bcharef]

Re : Pb avec une formule

Re bonjour Bcar, Gael & tbft,
Re bonjour à toutes et à tous.

La solution proposée par notre ami Gael est génial.

=EQUIV(I5;{0;0,25;0,5;0,65;0,8})-1.

J'ai constater que la fonction CHOISIR() a disparu de ma vue.

A cet effet, je souhaiterai de la part de notre ami des éclaircicements de la formule proposée ainsi que des points marqués ci haut par bleu gras .

A vous lire et bon courage.

Cordialement

Bcharef.

Edit: Salut abcd

 

[Bcar]

Re : Pb avec une formule

Tout d'abord merci à l'ensemble des contributeurs,
Gael,
Peux tu expliciter ta proposition qui m'intrigue par sa simplicité?
Merci par avance,
Bcar

 

[Gael]

Re : Pb avec une formule

Bonjour à tous,

J'avais fait au départ la même formule que Abcd avec Choisir(equiv).

Equiv renvoie un n° qui correspond à la position de la valeur trouvée dans la matrice {0;0,25;0,5;0,65;0,8} et CHOISIR se sert de cet index pour associer la valeur correspondante soit 0;1;2;3;4 . On peut simplifier la formule puisque dans ce cas précis, equiv va renvoyer 1,2,3,4 ou 5 et donc l'index -1 donne le chiffre recherché.

Ce n'est possible que parce que les chiffres se suivent, sinon, il faudrait garder "Choisir" pour une association plus aléatoire.

Bcharef, les points marqués en bleu correspondent aux différents pourcentages limites soit 0,25 0,50 ... comme dans la fonction SI.

@+

Gael

 

[Bcar]

Re : Pb avec une formule

Gael,

Si j'ai bien compris le principe la formule suivante est OK:
=CHOISIR(EQUIV($H5;{"debutant";"executant";"confrme";"expert"});1;2;3;4 )
Cependant pour I5=confirme j'ai en retour #NA alors que le reste fonctionne!
Quel est le pb?
Merci par avance,

 

[bcharef]

Re : Pb avec une formule

Re bonjour Bcar, Gael, tbft & abcd,
Re bonjour à toutes et à tous.

Gael,
En premier lieu, je n'ai pas pu identifier qu'il s'agissait de pourcentage, mais l'intervention de notre ami abcd m'a permis de les deceler, car il a utilsé des points au lieu des virgules, qui m'ont induit en erreur de conception, en supposant que l'utilité des virgules étaient un composant de formule au lieu de les lire comme des nombres décimaux.

A cet effet, j'ai le grand plaisir de vous déclarer que j'apprend du jour au jour grace à l'intervention de ce type de compétence.

Dans l'espoir de vous rencontrer sur un autre fil.

Cordialement.

Bcharef.

 

[Gael]

Re : Pb avec une formule

Rebonjour,

=CHOISIR(EQUIV($H5;{"debutant";"executant";"confirme";"expert"});1;2;3;4 )
Cependant pour I5=confirme j'ai en retour #NA alors que le reste fonctionne!

Il y a un paramètre supplémentaire pour la fonction Equiv qui est le type de recherche. Par défaut, il est égal à 1 et equiv recherche la première valeur inférieure ou égale à la valeur cherchée, c'est ce que j'ai utilisé pour la pourcentages. La condition est que les valeurs possibles soient classées par ordre croissant.

Dans ton exemple, les valeurs sont classées par ordre croissant sauf "Confirme" qui te renvoie donc #NA.

Dans ce cas, il faut ajouter le type "0" qui signifie que l'on recherche une valeur exacte, ce qui donne:

=CHOISIR(EQUIV($H5;{"debutant";"executant";"confirme";"expert"}[COLOR=red];0[/COLOR]);1;2;3;4 )

On peut aussi mettre -1 avec des valeurs décroissantes et une recherche de la première valeur supérieure ou égale à l'argument de recherche.

@+

Gael

 

[abcd]

Re : Pb avec une formule

Re,

La fonction CHOISIR peut également être employée dans l'autre sens, attribuer une valeur texte à un nombre.

Exemple :
=CHOISIR(EQUIV(A1;{0;8;10;12;14;16});"très mauvais";"mauvais";"satisfaisant";"bon";"très bon";"excellent")

abcd