Ordonner des lettres

[JJ1]

Bonjour,
Je souhaiterais ordonner une base de 5 lettres désordonnées en un classement ordonné U D V T Q. Ici la fonction petite.valeur, bien utile, ne peut fonctionner.
Merci de votre aide.
Bon samedi à vous tous.

 

[Tibo]

Re : Ordonner des lettres

Bonjour,

Un essai en I9 avec :

=SI(NB.SI($C9:$G9;"U")>NB.SI($H9:H9;"U");"U";SI(NB.SI($C9:$G9;"D")>
NB.SI($H9:H9;"D");"D";SI(NB.SI($C9:$G9;"V")>NB.SI($H9:H9;"V");"V";
SI(NB.SI($C9:$G9;"T")>NB.SI($H9:H9;"T");"T";SI(NB.SI($C9:$G9;"Q")>
NB.SI($H9:H9;"Q");"Q";"")))))

à recopier vers le bas et vers la droite

Essaye et dis-nous

@+

 

[BOISGONTIER]

Re : Ordonner des lettres

Bonjour,


-Sélectionner I9:N9
=STXT("UDVTQ";PETITE.VALEUR(TROUVE(C9:G9;"UDVTQ");COLONNE(INDIRECT("1:"&COLONNES(C9:G9))));1)
-Valider avec maj+ctrl+entrée

ou

=STXT("UDVTQ";PETITE.VALEUR(TROUVE(C9:G9;"UDVTQ");{1.2.3.4.5});1)


JB
Formation Excel VBA JB

 

[JJ1]

Re : Ordonner des lettres

Bonjour Tibo, Boisgontier,
Merci pour vos 2 formules (pas simple !) je vais installer dans mon fichier.
Contrairement à ce que j'écrivais, petite.valeur peut être utilisée mais quelle formule!
Encore merci et bon WE

 

[BOISGONTIER]

Re : Ordonner des lettres

-TROUVE(champ;"UDVTQ") transforme les lettres en 1,2,3,..
=PETITE.VALEUR(TROUVE(champ;"UDVTQ");{1.2.3.4.5}) classe les nombres
-STXT("UDVTQ";PETITE.VALEUR(TROUVE(champ;"UDVTQ");{1.2.3.4.5});1) transforme les nombres en lettres

JB