Nombre de jours mensuels sur une période

[katluaza@yahoo.]

Bonjour à tous,
J'ai essayé de chercher la solution sur les forums. Mais les solutions trouvées ne semblent pas s'adapter à ce que je souhaiterais (Fonctions Fin.Mois et Si) où plutôt j'y arrive pas.
J'ai deux colonnes de dates (Début et Fin de contrat). J'aimerai avoir le nombre de jours mois par mois pendant court le contrat.

Fichier joint pour illustration.

D'avance merci beaucoup

 

[job75]

Re : Nombre de jours mensuels sur une période

Bonjour katluaza@yahoo,

Formule en I4 :

=MAX(DATE(ANNEE(I$3);MOIS(I$3)+1;0)-MAX($C4;I$3-1);0)*($D4>=I$3)

Mettez bien cette cellule au format Standard et tirez-la pour la copier sur tout le tableau en vert.

Edit : en C4 il y a 28/09/2010. Si l'on veut 2 en I4, il faut évidemment 28/11/2010...

A+

 

[katluaza@yahoo.]

Re : Nombre de jours mensuels sur une période

Merci Job 75.
La formule me donne le nombre de jours dans mois sur ma plage. Mais elle ne prend pas en compte mes dates de de début et fin de contrat.
En fait, si mon contrat commence le 28 sept. par exemple et s'arrête le 31 déc., je voudrais avoir 2 pour le mois de sept, 30 pour oct et 31 pour décembre. et rien pour les mois suivants (janvier ...)
Encore merci. C'est cette formule que j'essaie de retravailler depuis des jours.

 

[job75]

Re : Nombre de jours mensuels sur une période

Re,

J'avais oublié *($D4>=I$3) dans la formule, j'ai corrigé le post précédent...

A+

 

[ROGER2327]

Re : Nombre de jours mensuels sur une période

Bonjour à tous

Je proposerais volontiers ceci :

[COLOR=DarkSlateGray][B]=SI((FIN.MOIS(I$3;-1)<$C4)*($C4<=FIN.MOIS(I$3;0));FIN.MOIS($C4;0)-$C4;)+SI((FIN.MOIS(I$3;-1)>=$C4)*(($D4="")+($D4>=FIN.MOIS(I$3;0)));FIN.MOIS(I$3;0)-FIN.MOIS(I$3;-1);)+SI((FIN.MOIS(I$3;-1)<$D4)*($D4<FIN.MOIS(I$3;0));$D4-FIN.MOIS($D4;-1);)[/B][/COLOR]

en I4, à recopier à droite et vers le bas, mais on obtiendra pas vraiment les résultats que vous indiquez.
Pourriez-vous préciser le raisonnement qui vous fait dire qu'un contrat courant du 28/09/2010 au 31/12/2010 compte 2 jours en novembre 2010 ?
Ou qu'un contrat à durée indéterminée commençant le 10/11/2010 compte 30 jours en octobre 2010 ?
​

ROGER2327
#4679

Vendredi 6 Sable 138 (Saint Navet et Perruque, humanistes, SQ)
16 Frimaire An CCXIX
2010-W49-1T11:02:24Z

 

[job75]

Re : Nombre de jours mensuels sur une période

Re encore,

Si l'on veut le nombre de jours même si la date de fin de contrat (colonne D) n'est pas entrée, utiliser :

=MAX(DATE(ANNEE(I$3);MOIS(I$3)+1;0)-MAX($C4;I$3-1);0)*OU($D4>=I$3;[COLOR="Red"]$D4=""[/COLOR])

Edit 1 : bonjour Roger, excusez-moi, pas rafraîchi 🙂

Edit 2 : salut tototiti, il commence a y avoir du monde 😀

A+

 

[tototiti2008]

Re : Nombre de jours mensuels sur une période

Bonjour katluaza, Bonjour job, Bonjour Roger 😉

basé sur la formule de job (je n'avais pas trouvé le début)

=SI(OU(CNUM(ANNEE($D4)&TEXTE(MOIS($D4);"00"))>CNUM(ANNEE(I$3)&TEXTE(MOIS(I$3);"00"));$D4="");MAX(DATE(ANNEE(I$3);MOIS(I$3)+1;0)-MAX($C4;I$3-1);0);MAX($D4-I$3+1;0))

Edit : en i4, bien sûr, dés fois que les contrats ne se terminent pas en fin de mois 🙂

 

[ROGER2327]

Re : Nombre de jours mensuels sur une période

Re…

Merci Job 75.
La formule me donne le nombre de jours dans mois sur ma plage. Mais elle ne prend pas en compte mes dates de de début et fin de contrat.
En fait, si mon contrat commence le 28 sept. par exemple et s'arrête le 31 déc., je voudrais avoir 2 pour le mois de sept, 30 pour oct et 31 pour décembre. et rien pour les mois suivants (janvier ...)
(…)

Pas clair ! À moins qu'il ne faille lire "…31 pour oct et 30 pour décembre…"
​

ROGER2327
#4680

Vendredi 6 Sable 138 (Saint Navet et Perruque, humanistes, SQ)
16 Frimaire An CCXIX
2010-W49-1T11:11:11Z

 

[katluaza@yahoo.]

Re : Nombre de jours mensuels sur une période

Excusez-moi.
En fait pour mon exemple : Contrat du 28 sept 2010 au 31 décembre 2010. J'aurai donc :
- 2 jours pour sept 2010 (le mois de sept compte 30)
- 30 jours pour octobre 2010
- 30 jours pour novembre 2010
- 31 pour décembre 2010
Et pour ce contrat j'aurai donc en janvier 2011, février 2011 ... = 0

Nous avons admis comme règle de calcul le nombre de jours total dans le mois pour nos calculs.
Encore Merci

 

[ROGER2327]

Re : Nombre de jours mensuels sur une période

Re...

D'accord. Je passe…
​

ROGER2327
#4681

Vendredi 6 Sable 138 (Saint Navet et Perruque, humanistes, SQ)
16 Frimaire An CCXIX
2010-W49-1T11:21:45Z

 

[job75]

Re : Nombre de jours mensuels sur une période

Re,

En I3, il faut que le mois corresponde au minimum des dates de début de contrat...

Donc en I3 entrer la formule :

=DATE(ANNEE(MIN($C:$C));MOIS(MIN($C:$C))+COLONNES($I4:I4)-1;1)

Fichier joint.

A+

 

[katluaza@yahoo.]

Re : Nombre de jours mensuels sur une période

Merci à tous.
Et un tout particulier à Job75.
ça marche.🙂
Cheers./.

 

[tototiti2008]

Re : Nombre de jours mensuels sur une période

Re,

pour le plaisir, une autre solution

=SOMMEPROD((MOIS(LIGNE(INDIRECT($C4&":"&SI($D4="";65000;$D4))))=MOIS(I$3))*(ANNEE(LIGNE(INDIRECT($C4&":"&SI($D4="";65000;$D4))))=ANNEE(I$3)))

 

[job75]

Re : Nombre de jours mensuels sur une période

Re,

Merci à tous.
Et un tout particulier à Job75.
ça marche.🙂
Cheers./.

Oui ça marche si la date de fin de contrat est toujours une fin de mois.

Sinon, il faut une formule plus générale en I4 :

=MAX(SI(OU(DATE(ANNEE(I$3);MOIS(I$3)+1;0)<=$D4;$D4="");DATE(ANNEE(I$3);MOIS(I$3)+1;0);$D4)-MAX($C4;I$3-1);0)

Fichier (2) joint.

PS : vous savez, vous avez accablé Roger (j'ai failli l'être) avec votre mois d'octobre de 30 jours...

Ainsi qu'avec votre mois de novembre en I3...

A+

 

[katluaza@yahoo.]

Re : Nombre de jours mensuels sur une période

Mes excuses à Roger aussi.
Je regardais les dates sur un calendrier chinois, que mon restaurant chinois m'a remis. Et dessus ils accolent les dates 23/30 et 24/31.
Milles excuses. Et encore merci