nombre de colonnes

[JJ1]

Bonjour,
C'est peut être très simple et évident mais je ne trouve pas de façon de combiner NB.SI "x" avec en résultat le nombre de colonnes nécessaires pour obtenir 3 x (dans mon exemple joint)
Merci de votre solution.


Bon AM à tous.

 

[R@chid]

Re : nombre de colonnes

Bonjour JJ1,
je voie que la demande n'est pas claire,
essayer en J1 :

=NB.SI(DECALER(A1;;;;I1);"x")

@ tirer vers le bas
Amicalement

 

[JJ1]

Re : nombre de colonnes

Re,

Merci mais apparemment la formule ne fonctionne pas, je compte le nombre de colonnes pour aboutir à 3 x, donc en première ligne A:E=5

Merci

 

[tototiti2008]

Re : nombre de colonnes

Bonjour JJ1 🙂, Bonjour Rachid 🙂

Peut-être

=EQUIV(3;NB.SI(DECALER(A1;;;;COLONNE(A:H));"x");0)

à valider par Ctrl+Maj+Entrée

 

[JHA]

Re : nombre de colonnes

Bonjour à tous,

en attendant de trouver mieux,

=SI(NB.SI(A1:H1;"x")=0;"";SI(NB.SI(A1:C1;"x")=3;COLONNE(C1);SI(NB.SI(A1😀1;"x")=3;COLONNE(D1);SI(NB.SI(A1:E1;"x")=3;COLONNE(E1);SI(NB.SI(A1:F1;"x")=3;COLONNE(F1);SI(NB.SI(A1:G1;"x")=3;COLONNE(G1);COLONNE(H1)))))))

Edit: Bonjour Tototiti et bravo pour cette formule peut être en ajoutant un "si" pour éviter les "N/A"
Bonjour également à Rachid_0661

=SI(NB.SI($A1:$H1;"x")=0;"";EQUIV(3;NB.SI(DECALER(A1;;;;COLONNE(A:H));"x");0))

JHA

 

[JJ1]

Re : nombre de colonnes

Bonsoir,

Bravo pour ces formules, la plus courte de Tototiti n'était pas évidente à dénicher, Bill aurait pu nous créer une Fonction NB.COL ???

Je précise que cette formule est valable numériquement en remplaçant "x" par ">0".

Merci encore

A+

 

[R@chid]

Re : nombre de colonnes

Bonjour @ tous,
j'ai dit que la demande n'etait pas claire, essayer en J1 avec :

=PETITE.VALEUR(SI(A1:H1="X";COLONNE(A:H));3)

@ valider par Ctrl+Maj+Entree
@ tirer vers le bas
Amicalement

 

[R@chid]

Re : nombre de colonnes

Bonsoir @ tous,
Belle remarque JHA, moi aussi j'aime bien un fichier sans valeurs d'erreurs, mais je voie que pour eviter les #N/A il faut mettre <3 a la place de =0 .
Amicalement