Modif Formule avec ESTTEXTE

[herve62]

Bonjour à tous
J'essaye de m'y mettre mais les débuts sont durs !!!
j'aimerai modifier cette formule :

=SOMME(SI(ESTTEXTE(C6:R6);1;0))

Afin qu'elle ne cumule 1 que si la valeur de cellule =X OU =C ou =M
J'ai commencé par :
=SOMME(SI(esttext(C6:R6);SI((C6:R6)="X";1;0);0)) ...... mais bien sûr Erreur

Merci à vous

 

[job75]

Re : Modif Formule avec ESTTEXTE

Bonjour herve62,

Classique :

=SOMMEPROD((C6:R6="X")+(C6:R6="C")+(C6:R6="M"))

Moins classique :

=SOMMEPROD(N(C6:R6={"X";"C";"M"}))

A+

 

[job75]

Re : Modif Formule avec ESTTEXTE

Re,

Et s'il y a des valeurs d'erreur dans la plage C6:R6 :

=NB(1/((C6:R6="X")+(C6:R6="C")+(C6:R6="M")))
=NB(1/(C6:R6={"X";"C";"M"}))

Ce sont des formules matricielles à valider par Ctrl+Maj+Entrée.

A+

 

[R@chid]

Re : Modif Formule avec ESTTEXTE

Salut @ tous,
pourquoi pas,

=SOMMEPROD(N(ESTTEXTE(C6:R6)))

et tu peux modifier pour Les X Y Z, comme ca :

=SOMMEPROD(NB.SI(C6:S6;E13:E15))

La plage E13:E15, contient Les valeurs X, Y, et Z.
Amicalement

 

[job75]

Re : Modif Formule avec ESTTEXTE

Bonjour Rachid,

En effet s'il y a des valeurs d'erreur, pas besoin de formule matricielle :

SOMMEPROD(NB.SI(C6:R6;{"X";"C";"M"}))

A+

 

[herve62]

Re : Modif Formule avec ESTTEXTE

Re
Merci à vous
Mais bon quand je "post" je cherche aussi en // ( ce que beaucoup ne font pas)
j'ai trouvé ça :
=SOMME(NB.SI(C6:R6;"X");NB.SI(C6:R6;"C");NB.SI(C6:R6;"M"))
Ce qui se rapproche fortement de JOB au "post2"
je peux entrer n'importe quoi d'autres .. pas d'erreur , et ca compte bien
mais je garde vos solutions aussi ... ca peut servir

encore merci de votre implication

 

[R@chid]

Re : Modif Formule avec ESTTEXTE

Bonjour Rachid,

En effet s'il y a des valeurs d'erreur, pas besoin de formule matricielle :

SOMMEPROD(NB.SI(C6:R6;{"X";"C";"M"}))

A+

Salut @ tous,
ma formule : =SOMMEPROD(NB.SI(C6:S6;E13:E15)) donne le bon resultat malgre les valeurs d'erreurs
Amicalement

 

[R@chid]

Re : Modif Formule avec ESTTEXTE

Re,
Voir PJ.
Amicalement