Mise à jour commentaire de toutes mes feuilles en une fois

[marcelio]

Bonjour à tous,
Je rentre des données sur la feuille départ
Ceux-ci sont ensuite renvoyer sur les différentes feuilles (environ 20 feuilles) de mon classeur qui ont un commentaire, et 30 sans commentaires.
Sur chaque feuille avec commentaire j'ai un bouton (mise à jour ) qui me permet de voir les résultats obtenus sur le commentaire.

J'aimerais si cela est possible c'est de faire en 1 clic sur la feuille départ la mise à jour de tous les commentaires.

J'ai testé différentes solutions mais celles-ci n'ont pas fonctionner
merci d'avance de cotre aide.
Marcelio

 

[job75]

Re : Mise à jour commentaire de toutes mes feuilles en une fois

Bonjour marcelio, le forum,

Si comme dans l'exemple les plages DD11: DI22 sont les copies (par liaisons) de depart!G23:L34 elles sont inutiles.

Par ailleurs les boutons et leurs macros paraissent aussi inutiles.

Remplacez-les par cette unique macro dans ThisWorkbook :

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
Dim Plage As Range, Cel As Range
Set Plage = Feuil1.[G23:L34] 'CodeName de la feuille depart
'Set Plage = Sh.[DD11:DI22] 'si c'est utile
Set Cel = Sh.[H7]
If Cel.Comment Is Nothing Then Exit Sub
Application.ScreenUpdating = False
Sh.Unprotect
'Plage.EntireRow.Hidden = False 'si nécessaire
'Plage.EntireColumn.Hidden = False
Plage.CopyPicture
With Workbooks.Add 'nouveau document (Zoom 100%)
  With .Sheets(1).ChartObjects.Add(0, 0, Plage.Width, Plage.Height).Chart
    .Paste
    .Export ThisWorkbook.Path & "\MonImage.gif", "GIF"
  End With
  .Sheets(1).[A1].Copy .Sheets(1).[A1] 'vide le presse-papier
  .Close False 'supprime le document avec le graphique temporaire
End With
Cel.Comment.Delete
With Cel.AddComment("").Shape
  .Width = Plage.Width
  .Height = Plage.Height
  .Fill.UserPicture ThisWorkbook.Path & "\MonImage.gif"
End With
Kill ThisWorkbook.Path & "\MonImage.gif" 'supprime le fichier gif
'Plage.EntireColumn.Hidden = True 'si nécessaire
Sh.Protect
End Sub

Bonne journée.

 

[marcelio]

Re : Mise à jour commentaire de toutes mes feuilles en une fois

Bonjour Job et le forum,
Merci pour ce nouveau code qui est super et qui fonctionne très bien.
Bonne idée de le mettre dans ThisWorkbook c’est encore mieux pour moi
Bonne journée à toi et au forum

Marcelio