Masquer l'onglet de création de nouvelle feuille

[apnart]

Bonjour,

Je voudrais masquer l'onglet de création de nouvelles feuilles... et je ne trouve pas 😡

Je sais masquer un onglet avec "xlVeryHidden", mais pas celui qui permet de créer les autres...

des idées ?

Merci d'avance,
A+
Bruno.

 

[mromain]

Re : Masquer l'onglet de création de nouvelle feuille

Bonjour Bruno, le forum,

Je pense que tu ne peux pas masquer ce bouton (et non onglet).
Par contre, tu peux interdire la création de nouveaux onglets en rajoutant ce code dans ThisWorkbook.

Private Sub Workbook_NewSheet(ByVal Sh As Object)
Dim mem As Boolean
    On Error Resume Next
    mem = Application.DisplayAlerts: Application.DisplayAlerts = False
    Sh.Delete
    Application.DisplayAlerts = mem
    On Error GoTo 0
End Sub

A+
Miki

 

[piga25]

Re : Masquer l'onglet de création de nouvelle feuille

Bonjour,

Une autre solution sans VBA pourrait être de protéger le classeur
Onglet Révision - Protéger le classeur
Cocher Structure
Taper éventuellement un mot de passe
OK

 

[apnart]

Re : Masquer l'onglet de création de nouvelle feuille

Merci mromain et Piga25 🙂

Pour le code, mon soucis c'est que je voudrais pouvoir l'activer dans certaines conditions et le désactiver dans d'autres (du style certaines personnes ont des accès privilégiés par menus et pas d'autres), et le fait de le mettre sur le workbook m'empêche de le faire 🙁

Pour les protections, effectivement ça peut le faire, mais ça oblige à des manips supplémentaires quand on entre en mode "privilégié" 🙁

L'idéal étant pour moi de mettre ça dans 2 macros : 1 qui active, l'autre qui désactive.

D'autres idées ?

 

[mromain]

Re : Masquer l'onglet de création de nouvelle feuille

Bonjour Bruno, Piga25, le forum,

L'idéal étant pour moi de mettre ça dans 2 macros : 1 qui active, l'autre qui désactive.

Voici une adaptation de ma proposition initiale :

Code à mettre dans ThisWorkbook :

Private Sub Workbook_NewSheet(ByVal Sh As Object)
Dim mem As Boolean
    If Not interdireNouvFeuilles Then Exit Sub
    On Error Resume Next
    mem = Application.DisplayAlerts: Application.DisplayAlerts = False
    Sh.Delete
    Application.DisplayAlerts = mem
    On Error GoTo 0
End Sub

Code à mettre dans un module standard :

Public interdireNouvFeuilles As Boolean

Public Sub Autoriser()
    interdireNouvFeuilles = False
End Sub

Public Sub Interdire()
    interdireNouvFeuilles = True
End Sub

Ainsi, tu possèdes deux macros (Autoriser et Interdire) qui respectivement autorisent et interdisent la création de feuilles.

A+

 

[david84]

Re : Masquer l'onglet de création de nouvelle feuille

Bonsoir,
le 1er code proposé par mromain🙂 répond à la commande initiale mais n'empêche pas la possibilité de dupliquer une feuille par le biais d'une sélection de l'onglet et de sa duplication via la touche Ctrl.
Le fait de protéger le classeur comme proposé par Piga25🙂 ne permet pas cette possibilité.
A+

 

[david84]

Re : Masquer l'onglet de création de nouvelle feuille

Re

Par macro :

ThisWorkbook.Protect Password:="toto", Structure:=True, Windows:=True

A+

 

[apnart]

Re : Masquer l'onglet de création de nouvelle feuille

😀 Merci beaucoup Romain et David, je vais ajouter ça à ma p'tite appli 😉

Bonne journée à tous