XL 2013 liste en fonction de case à cocher

[306255]

Bonjour à tous,

j'aimerais avoir une liste des magasins lorsque je coche les cases.

Merci pour votre aide

 

[sylvanu]

Bonjour 306255,
Un essai en PJ avec la macro :

Sub Worksheet_Activate()
    With Sheets("MAG")
        [A1:Z1000].ClearContents
        Application.ScreenUpdating = false
        Ligne = 1
        For C = 15 To 19 Step 2         ' colonnes O Q S
            For L = 1 To 25             ' longueur de la liste
                If LCase(.Cells(L, C)) = "vrai" Then
                    Cells(Ligne, "A") = .Cells(L, 2 * C - 26)   ' 2C-26 donnent colonnes DHL pour les colonnes OQS
                    Ligne = Ligne + 1
                End If
            Next L
        Next C
    End With
End Sub

Cette macro s'active automatiquement lorsque la feuille "Liste" est sélectionnée.

 

[Dudu2]

Bonjour @306255, @sylvanu,

@sylvanu, tu as été plus rapide que moi. J'ai ramé pour trouver la valeur d'une CheckBox de Contrôle de Formulaire (j'étais parti sur des Shapes) et j'ai fini par trouver la réponse ici:

Loop Through All Form Control Checkboxes On Excel Spreadsheet

This code will loop through each of your Form Control checkboxes and let you 'do something' based on if the checkbox is checked or not.

www.thespreadsheetguru.com

Sub ListeMagasins()
    Dim cb As CheckBox
    Dim TabMagasins() As Variant
    Dim NbMagasins As Integer
   
    For Each cb In ThisWorkbook.Worksheets("MAG").CheckBoxes
        If cb.Value = xlOn Then
            NbMagasins = NbMagasins + 1
            ReDim Preserve TabMagasins(1 To NbMagasins)
            TabMagasins(NbMagasins) = cb.TopLeftCell.Offset(, 1).Value
        End If
    Next cb
   
    With ThisWorkbook.Worksheets("Liste")
        .Cells(1, 1).Resize(Rows.Count).ClearContents
        If NbMagasins > 0 Then
            .Cells(1, 1).Resize(NbMagasins).Value = WorksheetFunction.Transpose(TabMagasins)
        End If
    End With
End Sub

 

[Dudu2]

Edit: Mince, j'ai oublié le cas 0 magasins ! J'ai modifié le code et le fichier ci-dessus !

A noter que les CheckBoxex 9, 14, 33, 34, 41, 52, 56 et certainement d'autres sont mal placées.
Avec mon code, quand elles sont mal alignées on ne peut pas faire le lien entre la CheckBox et le Magasin.

 

[sylvanu]

Bonjour Dudu,

A noter que la CheckBox 33, 34, 58 et certainement d'autres sont mal placées.

Celle là, je ne l'avais pas vu.
Ouf! J'ai vérifié sur mon fichier, ça à l'air de marcher.

 

[Dudu2]

@sylvanu,
Parce que tu as utilisé les colonnes O, Q et S qui sont VRAI ou FAUX selon la CheckBox.

Par contre je ne comprends pas comment les valeurs en colonnes O, Q et S sont valorisées.
Je ne trouve pas trace du code qui fait ça. Il y a bien des macros associées aux CheckBoxes mais je ne les trouve pas dans le code !!!

 

[Dudu2]

Ah ok.
Ce sont des cellules liées je suppose.

https://fr.extendoffice.com/documents/excel/2689-excel-link-checkbox-to-multiple-cells.html

 

[sylvanu]

@Dudu2,
Si on fait clic droit sur la Checkboxex en C1 et Format de contrôle, on voit que la cellule liée est O1.
Donc O1 sera VRAI si la checkbox est cliquée, sinon FAUX.
Et c'est la même chose pour toutes les checkbox.

 

[Dudu2]

Si on fait clic droit sur la Checkboxex en C1 et Format de contrôle

Ok, j'avais fait ça mais pas remarqué 😡