Lien hypertexte

[C@thy]

Bonjour le forum,

dans une cellule, je récupère l'intitulé tronqué du lien hypertexte,
par contre lorsque j'approche la souris je peux lire dans la bulle ce lien en entier,
et lorsque j'active le lien (clic) cela fonctionne.

Ce qu'il faudrait : l'intitulé complet du lien dans la feuille matrice ainsi que dans la feuille mars et feuil1.

Jusqu'à présent l'utilisateur le fait à la mano, par copier/coller, mais cela se répète tous les trimestres...🙁🙁
J'ai essayé par l'enregistreur, mais ça ne donne rien.

accessoirement : la mise à jour du graphique sur mars et feuil1 (pareil, c'est fait à la mano!!!)

Un grand MERCIiiiiiiii à vous🙂

Bises

C@thy

 

[C@thy]

Re : Lien hypertexte

Oups! Oublié le fichier!!!😱

le voici.

Bizz

C@thy

 

[job75]

Re : Lien hypertexte

Bonjour C@thy 🙂 ça fait un bout de temps...

Tout bêtement :

Sub Adresse()
Dim cel As Range
On Error Resume Next 'sécurité, si pas de lien hypertexte
For Each cel In Range("A1", [A65536].End(xlUp))
  cel = cel.Hyperlinks(1).Address
Next
End Sub

A+

 

[job75]

Re : Lien hypertexte

Re,

Et pour le dimensionnement des images en Feuil1 et mars :

Sub Images()
Dim coef#, p As Object
coef = 22 'à adapter
For Each p In ActiveSheet.Pictures
  p.Width = p.TopLeftCell.Offset(, -1) / coef
Next
End Sub

A+

 

[C@thy]

Re : Lien hypertexte

Coucou Job,

oui, tu as raison, cela faisait longtemps...

ta soluce me va impec!!! (comme d'hab!!!), c'est super génial,

un grand MERCI!!!

Bises

C@thy

 

[C@thy]

Re : Lien hypertexte

Oups! Je rectifie :

tes soluces me vont impec!!!

Vraiment super, je ne sais pas comment tu fais tout ça, mais vraiment, tu le fais bien!!!

et si vite!!! pfiou!!!

Bises

C@thy

 

[C@thy]

Re : Lien hypertexte

Re coucou,

juste un truc (Ah les femmes!!!)

dans ma colonne d'adresses e-mail j'ai un renvoi à la ligne automatique, et donc la hauteur de mes lignes varie,

par conséquent il arrive que l'image ne soit pas en face de la bonne colonne...😡

Serait-il possible de mettre 1 image par ligne et pas plus (pas moins non plus)???
(au besoin créer l'image par macro, car en fait le nombre de lignes est susceptible de varier également...
donc si on rajoute des ligne il faut rajouter des images...

Edit : l'idéal serait que la barre (l'image) soit positionnée en face du chiffre, mais ça, c'est pas facile, j'imagine...😱 et en plus qu'elles soient toutes alignées à gauche (ça, c'est plus facile)...

En te remerciant

Bises

C@thy

 

[job75]

Re : Lien hypertexte

Re,

Pour la feuille Feuil1 on traite la colonne D :

Sub CreerShapes()
Dim coef#, h#, s As Shape, cel As Range
coef = 22 'à adapter
h = 8 'hauteur des Shapes, à adapter
Application.ScreenUpdating = False
'---suppression de toutes les Shapes---
For Each s In ActiveSheet.Shapes
  s.Delete
Next
'---création des nouvelles Shapes---
For Each cel In Range("D1", [D65536].End(xlUp))
  If IsNumeric(cel.Text) Then
    Set s = ActiveSheet.Shapes.AddShape(msoShapeRectangle, _
      cel.Offset(, 1).Left, cel.Top, cel / coef, h)
    s.Fill.ForeColor.SchemeColor = 12 'bleu '10 'rouge
  End If
Next
End Sub

Edit : bien sûr, alignement vertical Haut des cellules en colonne D.

Adapte à la colonne C pour la feuille mars.

A+

 

[C@thy]

Re : Lien hypertexte

Quoi??? Tu travailles encore à cette heure-ci??? veux-tu quitter ton PC!!! Que va dire Mme Job???

En te remerciant mille fois

Bises

C@thy

 

[C@thy]

Re : Lien hypertexte

Merci Gérard, c'est GEANT!!!

Bises

C@thy

 

[job75]

Re : Lien hypertexte

Re,

Il vaut mieux l'alignement vertical centré pour la colonne D (ou C), avec la macro :

Sub CreerShapes()
Dim coef#, h#, s As Shape, cel As Range
coef = 22 'à adapter
h = 8 'hauteur des Shapes, à adapter
Application.ScreenUpdating = False
'---suppression de toutes les Shapes---
For Each s In ActiveSheet.Shapes
  s.Delete
Next
'---création des nouvelles Shapes---
For Each cel In Range("D1", [D65536].End(xlUp))
  If IsNumeric(cel.Text) Then
    Set s = ActiveSheet.Shapes.AddShape(msoShapeRectangle, _
      cel.Offset(, 1).Left, cel.Top + (cel.Height - h) / 2, cel / coef, h)
    s.Fill.ForeColor.SchemeColor = 12 'bleu '10 'rouge
  End If
Next
End Sub

A+

 

[C@thy]

Re : Lien hypertexte

Ah oui, comme ça, c'est plus que parfait!...
juste une petite chose : comment je modifie

For Each cel In Range("D1", [D65536].End(xlUp))

pour qu'il ne fasse pas la dernière ligne (le total)?
(j'ai essayé For Each cel In Range("D1", [D65536].End(xlUp)-1) mais c'est pas bon)

Merci à toi, bises et bonne journée

C@thy

 

[C@thy]

Re : Lien hypertexte

Arf! j'ai trouvé :

For Each cel In Range("D1", [D65536].End(xlUp).Offset(-1, 0))

Bises et merci encore pour ton aide, ce que tu as fait est carrément génial!!

C@thy

 

[job75]

Re : Lien hypertexte

Bonjour C@thy 🙂

Oui, et on peut aussi écrire :

For Each cel In Range("D1", [D65536].End(xlUp)(0))

Mais il y a une autre solution (qui évite d'ailleurs un test) :

'---création des nouvelles Shapes---
On Error Resume Next 'si aucune constante numérique
For Each cel In [D:D].SpecialCells(xlCellTypeConstants, 1)
  Set s = ActiveSheet.Shapes.AddShape(msoShapeRectangle, _
    cel.Offset(, 1).Left, cel.Top + (cel.Height - h) / 2, cel / coef, h)
  s.Fill.ForeColor.SchemeColor = 12 'bleu '10 'rouge
Next
End Sub

La dernière ligne contenant une formule, elle ne sera pas traitée.

A+