Re: formules matricielles
Bonjour,
Sur la feuille où tu saisis tes données :
Dans une cellule quelconque, tu nommes "an" les quatre chiffres de l'année
Tu insères une colonne qui te donnera le mois
si les dates sont dans la colonne A, ça donne =SI(ESTVIDE(A5);"";MOIS(A5))
Tu nommes cette colonne "mois"
Tu as déjà une colonne pour les codes, tu la nommes "code"
Tu nommes "credit" et "debit" tes 2 colonnes de mouvement, s'il y en a 2
Tu peux nommer "montant" l'ensemble de ces 2 plages
Dans le tableau de récap mensuelle :
Colonne A : rubrique
Colonne B : code (tu peux masquer cette colonne B)
Ligne 3 à partir de C3 : le mois, sous la forme =DATE(an;1;1) pour janvier, =DATE(an;1;1) pour février, etc
Format personnalisé de ces cellules mmm ou mmmm (janv ou janvier)
En C4, tu choisis l'une de ces formules, à valider par ctrl + maj + entrée
=SOMME(SI((code=$B4)*(mois=MOIS(C$3));debit;0))
=SOMME(SI((code=$B4)*(mois=MOIS(C$3));credit;0))
=SOMME(SI((code=$B4)*(mois=MOIS(C$3));credit+debit;0))
=SOMME(SI((code=$B4)*(mois=MOIS(C$3));montant;0))
Pour nommer les plages de cellules :
Tu sélectionnes la plage à nommer
Barre de menus - Insertion - Nom - Définir
Et tu tapes le nom choisi.
Ou bien tu sélectionnes ta plage et tu écris directement le nom dans le petit rectangle "zone nom", à gauche de la barre de formule.
Toutes les plages "mois", "code", "debit", credit", "montant" devront avoir le même longueur.
Tu ne donnes pas un nom à la colonne entière, les formules matricielles n'aiment pas ça.
D'autre part, les formules matricielles en grand nombre ralentissent la vitesse de calcul.
Ces formules-ci ne sont pas matricielles mais ne te donneront pas de répartition mensuelle :
=SOMME.SI(code;B4;debit)
=SOMME.SI(code;B4;credit)
ou bien simplement =SOMME.SI(code;B4;montant)