je bloque sur une formule

[telemark]

salut,

je suis débutant, j'ai créé un fichier regie pour mon travail, mais je bloque sur une formule.

j'ai une colonne total (M3) exemple 3.70€, je voudrais connaître combien de fois il y a 1.1 € enl (k3) et combien de fois il y a 0.30 € en (L3).

je vous joins mon fichier.
il devrait me mettre 2 dans la colonne K et 5 dans la colonne L.

 

[tototiti2008]

Re : je bloque sur une formule

Bonjour telemark,

Bienvenue sur XLD

un essai

en K3

=ENT(M3/1,1)

en L3

=ENT((M3-K3*1,1)/0,3)

 

[manikam]

Re : je bloque sur une formule

bonjour,

Tototiti2008 : au fait je pense qu'il cherche plutot à determiner des coeficients a et b telque :

a*1.1 + b*0.3 = total

sans qu'il y'ai de reste parceque si tu applique la formule que tu a mis tu auras un reste :
en k3 : =ENT(M3/1,1) ==> 3.3 ==>3
et en l3 =ENT((M3-K3*1,1)/0,3) ==>1
notons bien ici que 3*1.1 + 1*03 = 3.6 et il te reste 0.1

Je pense que le problème est de trouver les deux entiers qui permettent de retrouver un total sans reste.

 

[telemark]

Re : je bloque sur une formule

tout a fait manikam

 

[tototiti2008]

Re : je bloque sur une formule

Bonjour manikam,
Re,

Comment résoudre une équation à 2 inconnues si on a qu'une équation ?
c'est vrai qu'on a d'autres infos : a et b >=0 et a et b entiers
Est-ce sûr qu'il y a une solution pour chaque ligne ?

 

[tototiti2008]

Re : je bloque sur une formule

Re,

peut-être... en K3

=EQUIV(MIN(ABS(MOD(ARRONDI(M3-(LIGNE(DECALER($A$1;0;0;ENT(M3/1,1)+1;1))-1)*1,1;2);0,3)));ABS(MOD(ARRONDI(M3-(LIGNE(DECALER($A$1;0;0;ENT(M3/1,1)+1;1))-1)*1,1;2);0,3));0)-1

à valider par Ctrl+Maj+Entrée

 

[manikam]

Re : je bloque sur une formule

super tototiti2008

je relis et j’essaie de décrypter ta formule mais j'arrive pas tellement à comprendre bcp.

 

[telemark]

Re : je bloque sur une formule

c'est bon j'ai trouvé un moyen plus simple

ma solution :

c'est pour mon fichier régie.

j'ai une colonne heure de connexion et une colonne impressions

1.10 € l'heure de connexion et 0,30 € l'impression

j'ai donc créer deux colonnes :
-1 colonne pour le total d'heure de connexion
-1 colonne pour le total d'impressions

et non plus une seul colonne total

 

[tototiti2008]

Re : je bloque sur une formule

Bonjour à tous,

ce n'est pas que je ne veuille pas expliquer ma formule mais c'est un peu chaud
Le principe : on essaye des facteurs entiers de 0 au nombre maximum de 1,1 qui rentrent dans la valeur en M3
on fait M3 - tous les facteurs * 1,1, ce qui nous donne une matrice de résultats

ARRONDI(M3-(LIGNE(DECALER($A$1;0;0;ENT(M3/1,1)+1;1))-1)*1,1;2)

On arrondit le tout à 2 décimales parce que les calculs sur les heures entrainent souvent des soucis de décimales
On prend la valeur absolue du reste de la division entière des résultats par 0,3

ABS(MOD(ARRONDI(M3-(LIGNE(DECALER($A$1;0;0;ENT(M3/1,1)+1;1))-1)*1,1;2);0,3))

Le plus proche de 0 (ou égal à 0) doit être un nombre divisible par 0,3 (ou proche)
en prenant le minimum de ça, on saura lequel est divisible par 0,3 (ou presque)

MIN(ABS(MOD(ARRONDI(M3-(LIGNE(DECALER($A$1;0;0;ENT(M3/1,1)+1;1))-1)*1,1;2);0,3)))

et on recherche sa position dans la liste des facteurs entiers, auquel on retranche 1 puiqu'on avait des facteurs commençant à 0

=EQUIV(MIN(ABS(MOD(ARRONDI(M3-(LIGNE(DECALER($A$1;0;0;ENT(M3/1,1)+1;1))-1)*1,1;2);0,3)));ABS(MOD(ARRONDI(M3-(LIGNE(DECALER($A$1;0;0;ENT(M3/1,1)+1;1))-1)*1,1;2);0,3));0)-1

J'ai essayé d'expliquer mais pas sûr que ça aide...