inputbox avec plage

[jeffe]

bonjour le forum,
grâce à votre aide, j'ai réalisé un fichier qui fonctionne très bien, mais je souhaite l’améliorer un peut pour être utilisé par d'autres personnes.
je voudrais, par l’intermédiaire de 2 input box, que l'utilisateur du fichier puisse renseigner 2 plages de travail pour que la macro s’exécute.sur les bonnes plages
Pour le moment, ces plages sont écrites en dur dans la macro, je voudrais les rendre interactives.
merci

 

[mapomme]

Re : inputbox avec plage

Bonsoir jeffe,

Une piste dans le code suivant:

Sub Test()
Dim xrg As Range, s As String

Do
  Set xrg = Nothing
  On Error Resume Next
  Set xrg = Application.InputBox("Sélectionner une plage de cellule", Type:=8)
  On Error GoTo 0
Loop Until Not xrg Is Nothing

s = "La plage est sur la feuille '" & xrg.Parent.Name & "'" & vbLf & "Elle comporte "
s = s & xrg.Areas.Count & " zone(s) pour un total de " & xrg.Count
s = s & " cellules()." & vbLf & "L'adresse de la plage est: " & vbLf & xrg.Address(0, 0)
MsgBox s

End Sub

ou un code qui accepte l'annulation de la saisie :

Sub Test2()
Dim xrg As Range, s As String

Set xrg = Nothing
On Error Resume Next
Set xrg = Application.InputBox("Sélectionner une plage de cellule", Type:=8)
On Error GoTo 0

If xrg Is Nothing Then
  MsgBox "Aucune zone choisie -> abandon"
  Exit Sub
Else
  s = "La plage est sur la feuille '" & xrg.Parent.Name & "'" & vbLf & "Elle comporte "
  s = s & xrg.Areas.Count & " zone(s) pour un total de " & xrg.Count
  s = s & " cellules()." & vbLf & "L'adresse de la plage est: " & vbLf & xrg.Address(0, 0)
  MsgBox s
End If

End Sub

Attention ! : l'utilisateur peut sélectionner une plage quelconque de cellules (contigües ou non - plage à plusieurs zones) y compris sur une autre feuille du classeur!. Ce sera à vous de vérifier que la plage sélectionnée est une plage correcte par rapport à ce que vous désirez pour votre macro.

 

[jeffe]

Re : inputbox avec plage

Bonjour mapomme, le forum,
je viens de regarder ceque tu me proposes, c'est nikel, mais je n'arrive pas à intégrer comme je le voudrais: comment récupérer juste le numéro de colonne de la plage sélectionnée?
si je selectionne K17 à M32, je voudrais utiliser juste le K et le M pour redefinir ma plage
merci

 

[jeffe]

Re : inputbox avec plage

hello, je reviens après quelques tests infructueux, j'ai utilisé Rng.Column, je récupère bien le num de colonne, mais pas la lettre, dans mon cas, je n'aurai jamais plus de 20 colonnes possibles à sélectionner.
merci

 

[camarchepas]

Re : inputbox avec plage

bonjour ,

Selon le trés bon code de MaPomme que je salue au passage ,

pour avoir par exemple 4 si l'on à sélectionné la colonne D, il suffit de faire :

Sub Test2()
Dim xrg As Range, s As String

Set xrg = Nothing
On Error Resume Next
Set xrg = Application.InputBox("Sélectionner une plage de cellule", Type:=8)
On Error GoTo 0

If xrg Is Nothing Then
MsgBox "Aucune zone choisie -> abandon"
Exit Sub
Else
s = xrg.Column
MsgBox s
End If

End Sub

 

[jeffe]

Re : inputbox avec plage

bien le bonjour,
merci, mais justement, le .column me donne le chiffre mais pas la lettre, donc je cherche à récupérer la lettre, ou adapter me macro pour utiliser le chiffre et pas la lettre. voici le petit bout de code que je voudrais rendre selectionable:
[ Range("K" & Lig & "😛" & Lig).ClearContents ' efface le contenu de la ligne selectionnée de la colone "Op1 àOp6"
Range("K" & Lig & "😛" & Lig).Interior.ColorIndex = xlNone]
je m'y perd avec les cells, range...

 

[camarchepas]

Re : inputbox avec plage

Re ,

Ok comme ceci alors :

s= Split(xrg.Address, "$")(1)

 

[jeffe]

Re : inputbox avec plage

Ouaiiii, merci de ton aide, je viens juste de poser ce que tu m'as répondu, nickel, je vais essayer d'aller vers mon résultat final.
je reviendrai peut être après mes prochains essais la semaine prochaine.
merci et bon WE à vous tous