indiquer où commence l'écart entre 2 chaines de caractères

[Batiscaf]

Bonjour à tous,
Je cherche une formule (éventuellement un code) qui permet de dire à partir de quel numéro de caractère les 2 chaines ci-dessous divergent.
Colonne A : V1MG 10DRMrDE LA LLETHIBAULTDE
Colonne B : V1MG 10DRMfDE LA LLETHIBAULTDE
dans la réalité ces chaines sont la concaténation d'une trentaine de colonnes soit environ 350 caractères.
Merci de votre aide.
Batiscaf

 

[R@chid]

Re : indiquer où commence l'écart entre 2 chaines de caractères

Bonsoir,
En A1 premier texte, en B1 le 2em texte..

Formule en C1,

=EQUIV(VRAI;STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1)<>STXT(B1;LIGNE(INDIRECT("1:"&NBCAR(B1)));1);0)

@ valider par Ctrl+Maj+Entree
@ tirer vers le bas
@ + +

 

[Batiscaf]

Re : indiquer où commence l'écart entre 2 chaines de caractères

super merci !
Bonne nuit.

 

[ROGER2327]

Re : indiquer où commence l'écart entre 2 chaines de caractères

Bonjour Batiscaf, R@chid.

Si on préfère DECALER à INDIRECT :​

=SIERREUR(EQUIV(FAUX;EXACT(STXT(A1;LIGNE(DECALER($A$1;;;MAX(NBCAR(A1);NBCAR(B1))));1);STXT(B1;LIGNE(DECALER($A$1;;;MAX(NBCAR(A1);NBCAR(B1))));1));0);"")

(À valider par Ctrl Maj Entrée bien sûr !)​

ℝOGER2327
#6962

Samedi 7 As 141 (Saint Cyrano de Bergerac, explorateur - fête Suprême Quarte)
19 Brumaire An CCXXII, 0,8480h - grenade
2013-W45-6T02:02:07Z

 

[Batiscaf]

Re : indiquer où commence l'écart entre 2 chaines de caractères

Bonjour Roger,
Effectivement je n'avais pas envisager le problème de la casse. Très bonne solution également.
Merci et bonne journée..

 

[R@chid]

Re : indiquer où commence l'écart entre 2 chaines de caractères

Re,
Oui bien vu Roger au niveau de la casse j'en n'ai pas pensé, et aussi quand le nombre de caractère est différent.

=SIERREUR(EQUIV(FAUX;EXACT(STXT(A2;LIGNE(INDIRECT("1:"&MAX(NBCAR(A2:B2))));1);STXT(B2;LIGNE(INDIRECT("1:"&MAX(NBCAR(A2:B2))));1));0);"")

@ valider par Ctrl+Maj+Entree

Juste le : MAX(NBCAR(A2:B2))

@ + +