indiquer où commence l'écart entre 2 chaines de caractères

R@chid

XLDnaute Barbatruc

• 9 Novembre 2013

• #2

Re : indiquer où commence l'écart entre 2 chaines de caractères

Bonsoir,
En A1 premier texte, en B1 le 2em texte..

Formule en C1,

Code:

=EQUIV(VRAI;STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1)<>STXT(B1;LIGNE(INDIRECT("1:"&NBCAR(B1)));1);0)

@ valider par Ctrl+Maj+Entree
@ tirer vers le bas
@ + +

 

Vote positif 0 Vote négatif

B

Batiscaf

XLDnaute Occasionnel

• 9 Novembre 2013

• #3

Re : indiquer où commence l'écart entre 2 chaines de caractères

super merci !
Bonne nuit.

 

Vote positif 0 Vote négatif

ROGER2327

XLDnaute Barbatruc

• 9 Novembre 2013

• #4

Re : indiquer où commence l'écart entre 2 chaines de caractères

Bonjour Batiscaf, R@chid.

Si on préfère DECALER à INDIRECT :​

Code:

=SIERREUR(EQUIV(FAUX;EXACT(STXT(A1;LIGNE(DECALER($A$1;;;MAX(NBCAR(A1);NBCAR(B1))));1);STXT(B1;LIGNE(DECALER($A$1;;;MAX(NBCAR(A1);NBCAR(B1))));1));0);"")

(À valider par Ctrl Maj Entrée bien sûr !)​

ℝOGER2327
#6962

Samedi 7 As 141 (Saint Cyrano de Bergerac, explorateur - fête Suprême Quarte)
19 Brumaire An CCXXII, 0,8480h - grenade
2013-W45-6T02:02:07Z

 

Pièces jointes

• Classeur2.xlsx

  11.2 KB · Affichages: 51
• Classeur2.xlsx

  11.2 KB · Affichages: 54
• Classeur2.xlsx

  11.2 KB · Affichages: 55

Vote positif 0 Vote négatif

B

Batiscaf

XLDnaute Occasionnel

• 9 Novembre 2013

• #5

Re : indiquer où commence l'écart entre 2 chaines de caractères

Bonjour Roger,
Effectivement je n'avais pas envisager le problème de la casse. Très bonne solution également.
Merci et bonne journée..

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

• 9 Novembre 2013

• #6

Re : indiquer où commence l'écart entre 2 chaines de caractères

Re,
Oui bien vu Roger au niveau de la casse j'en n'ai pas pensé, et aussi quand le nombre de caractère est différent.

Code:

=SIERREUR(EQUIV(FAUX;EXACT(STXT(A2;LIGNE(INDIRECT("1:"&MAX(NBCAR(A2:B2))));1);STXT(B2;LIGNE(INDIRECT("1:"&MAX(NBCAR(A2:B2))));1));0);"")

@ valider par Ctrl+Maj+Entree

Juste le : MAX(NBCAR(A2:B2))

@ + +

 

Vote positif 0 Vote négatif