Microsoft 365 Index de feuilles

[INIME-]

Bonjour à tous,

Peut-on changer l'index d'une feuille Excel dans le vba ?

Merci

 

[Dudu2]

Bonjour,
Indirectement, oui...

Sub a()
    With ThisWorkbook
        .Worksheets(2).Move before:=.Worksheets(1)
    End With
End Sub

 

[Dudu2]

Autre exemple pour le classement des onglets selon leurs noms:

Sub TriOnglets()
    Dim TabNomsFeuilles() As String
    Dim TempNom As String
    Dim i As Integer
    Dim j As Integer

    With ThisWorkbook
        ReDim TabNomsFeuilles(1 To .Worksheets.Count)

        'Charge la table des noms des feuilles
        For i = 1 To .Worksheets.Count
            TabNomsFeuilles(i) = .Worksheets(i).Name
        Next i

        'Trie la table des noms des feuilles
        For i = 1 To UBound(TabNomsFeuilles) - 1
            For j = i + 1 To UBound(TabNomsFeuilles)
                If TabNomsFeuilles(j) < TabNomsFeuilles(i) Then
                    TempNom = TabNomsFeuilles(j)
                    TabNomsFeuilles(j) = TabNomsFeuilles(i)
                    TabNomsFeuilles(i) = TempNom
                End If
            Next j
        Next i

        'Classement des feuilles selon le tri
        Application.ScreenUpdating = False
        For i = UBound(TabNomsFeuilles) To 1 Step -1
            .Worksheets(TabNomsFeuilles(i)).Move before:=.Worksheets(1)
        Next i
        Application.ScreenUpdating = True
    End With
End Sub