Incrémentation d'année scolaire

[rodge5895]

Bonjour à tous !

Je n'arrive pas à trouver la formule qui incrémente une année scolaire en plus ou moins selon exemple joint (cf cellule jaune)

par avance merci à celui qui a la solution (et aux autres qui auront cherché aussi !)🙄
Rodge

 

[CHALET53]

Re : Incrémentation d'année scolaire

Bonjour,
Un essai

=GAUCHE(B7;4)+1 &"/"& DROITE(B7;2)+1

a+

 

[st007]

Re : Incrémentation d'année scolaire

Bonjour,

j'aime bien la proposition de chalet53

=GAUCHE($B$7;4)+LIGNE(1:1) &"/"& DROITE($B$7;2)+LIGNE(1:1)

pour pouvoir étirer sur la colonne

=GAUCHE($B$7;4)-LIGNE(1:1) &"/"& DROITE($B$7;2)-LIGNE(1:1)

dans le même ordre d'idée

 

[rodge5895]

Re : Incrémentation d'année scolaire

bonjour
Ca marche bien avec les 2 formules, sous réserve de 2 pb mineurs :
- on ne peut pas étirer la formule horizontalement (seul le vertical fonctionne)
- pour les années < 2010, la formule indique par 2008/9 au lieu de 2008/09 (idéalement)
A voir s'il existe une solution ?
Rodge

 

[Efgé]

Re : Incrémentation d'année scolaire

Bonjour à tous
Pour remonter dans le temps:
=GAUCHE($B$7;4)-COLONNES($A:A)&"/"&DROITE(2000+(DROITE($B$7;2))-COLONNES($A:A);2)
Ou
=GAUCHE($B$7;4)-COLONNES($A:A)&"/"&TEXTE(DROITE((GAUCHE($B$7;4)-COLONNES($A:A));2)+1;"00")

Pour aller vers l'avenir:
=GAUCHE($B$7;4)+COLONNES($A:A)&"/"&DROITE(2000+(DROITE($B$7;2))+COLONNES($A:A);2)
Ou
=GAUCHE($B$7;4)+COLONNES($A:A)&"/"&TEXTE(DROITE((GAUCHE($B$7;4)+COLONNES($A:A));2)+1;"00")

A étirer en ligne. Prends en compte les années avant 2000

Cordialement

 

[Modeste geedee]

Re : Incrémentation d'année scolaire

Bonsour®

pour incrémenter l'année en cours :
=(GAUCHE($B$2;4)+x)&"/"&TEXTE(MOD(DROITE($B$2;2)+x;100);"00")
l'année en cours se trouve en $B$2
x représente l'incrément (positif ou négatif)