Microsoft 365 Import informations de fichiers fermés

Sub Consolider()
Dim chemin$, fichier$, F As Worksheet, lig&, w As Worksheet, h&
chemin = ThisWorkbook.Path & "\"
fichier = Dir(chemin & "isitelFacturation*.xlsm") '1er fichier du dossier
Set F = Sheets("Consolidation")
lig = 2 '1ère ligne de restitution
Application.ScreenUpdating = False
F.Rows(lig & ":" & F.Rows.Count).Delete 'RAZ
If fichier = "" Then MsgBox "Aucun fichier de facturation trouvé...": Exit Sub
While fichier <> ""
    With Workbooks.Open(chemin & fichier) 'ouverture du fichier
        For Each w In .Worksheets
            If w.FilterMode Then w.ShowAllData 'si la feuille est filtrée
            w.UsedRange = w.UsedRange.Value 'supprime les formules
            w.Columns(1).Replace 0, "", xlWhole 'supprime la valeur zéro
            h = w.Cells(w.Rows.Count, 1).End(xlUp).Row - 79
            If h > 0 Then
                w.Range("A80:AG80").Resize(h).Copy F.Cells(lig, 2) 'copier-coller sur colonne B
                F.Cells(lig, 1).Resize(h) = w.Name 'client en colonne A
                lig = lig + h
            End If
        Next
        .Close False 'fermeture du fichier
    End With
    fichier = Dir 'fichier suivant
Wend
If lig > 2 Then
    With F.Range("A2:AH" & lig - 1)
        .Borders.Weight = xlHairline
        .BorderAround Weight:=xlThin 'pourtour
    End With
End If
With F.UsedRange: End With 'actualise la barre de défilement verticale
End Sub

            If h > 0 Then
                w.Range("A80:AG80").Resize(h).Copy F.Cells(lig, 3) 'copier-coller sur colonne C
                F.Cells(lig, 1).Resize(h) = .Name 'nom du fichier en colonne A
                F.Cells(lig, 2).Resize(h) = w.Name 'client en colonne B
                lig = lig + h
            End If