HELP : formule conditionnelle

[JANO]

Bonjour le forum,

je n'arrive pas à faire la formule suivante :

= si C2 est = à 3 mais plus petit que 6 alors D2 * I2 sinon
= si C2 est = à 6 mais plus petit que 9 alors D2 * I3 sinon
= si C2 est = à 9 mais plus petit que 12 alors D2 * I4 sinon
= si C2 est = à 12 mais plus petit que 15 alors D2 * I5 sinon
= si C2 est = à 15 mais plus petit que 18 alors D2 * I6 sinon
= si C2 est = à 18 mais plus petit que 20 alors D2 * I7 sinon
= si C2 est = ou plus grand que 20 alors D2 * I8 sinon zero
Pouvez vous m'aider ?
merci
bonne journée à tous

 

[hoerwind]

Re : HELP : formule conditionnelle

Bonjour,

Je ne comprends pas ton énoncé : si C2 = 3, C2 est forcément < 6 !
Ne voudrais-tu pas dire : Si C2 >=3 et < 6 ?

 

[Hicsygrek]

Re : HELP : formule conditionnelle

Hello JANO,

entre la formule suivante :

=SI(C2<H8;SI(C2<H7;SI(C2<H6;SI(C2<H5;SI(C2<H4;SI(C2<H3;SI(C2<H2;0;D2*I2);D2*I3);D2*I4);D2*I5);D2*I6);D2*I7);D2*I8)

Bonne journée 🙂
A+

 

[mth]

Re : HELP : formule conditionnelle

Bonjour à tous 🙂

une autre tentative:

=SI(ESTNA(EQUIV(C2;$H$2:$H$8;1));0;INDEX($I$2:$I$8;EQUIV(C2;$H$2:$H$8;1)))*D2

Bonne journée,

mth

 

[JANO]

Re : HELP : formule conditionnelle

Superbe, merci à tous.
j'ai utilisé la formules de mth.

bonne journée

 

[fvelaurence]

Re : HELP : formule conditionnelle

Bonjour

Une autre option serait d'utiliser recherchev Par exemple

=RECHERCHEV(C2;$H$2:$I$8;2;VRAI)*D2 cad

C2 la valeur dont vous chercher l'équivalence dans la table $H$2:$I$8
$H$2:$I$8 représente votre base de données dans laquelle sont enregistrées les taux
VRAI indique qu'Excel prendra la valeur inférieure par défaut. Donc si une personne ne possède que 4 ans d'ancienneté, seule la valeur correspondant à 3 ans sera utilisée, et ainsi de suite.
Bonne journée

 

[hoerwind]

Re : HELP : formule conditionnelle

Bonjour, salut les autres,

Une autre possibilité :

=SI(C2<3;0;D$2*DECALER(I$1;MIN(6;ENT(C2/3))+(C2>19);))

 

[JANO]

Re : HELP : formule conditionnelle

C'est bon j'ai la solution avec la formule de fvelaurence.
merci à tous


désoler, je me suis trompé, cela doit se déclencher seulement si la valeur de C2 est = à une valeur de G2:G8.

Autrement dit si j'ai 4 en C2 le résultat doit être 0

pouvez vous m'aider encore.

merci

 

[JANO]

Re : HELP : formule conditionnelle

désolé,je ne sais plus ou j' habite !! 😕


cela doit se déclencher seulement si la valeur de C2 est = à une valeur de G2:G8.

Autrement dit si j'ai 4 en C2 le résultat doit être 0

pouvez vous m'aider encore.

merci

 

[mth]

Re : HELP : formule conditionnelle

re à tous 🙂

En repartant de ta formule, modifie VRAI par FAUX (pour avoir la valeur exacte), + gestion d'erreur pour éviter les #N/A

=SI(ESTERREUR(RECHERCHEV(C2;$G$2:$H$8;2;FAUX));0;RECHERCHEV(C2;$G$2:$H$8;2;FAUX)*D2)

Bonne journée à tous 🙂

mth

 

[JANO]

Re : HELP : formule conditionnelle

super merci !!!!!!!!!!!
bonne journée à tous