Autres Générer un mail depuis Excel à travers une VBA

[hse]

Bonjour à tous,

J'ai trouvé un code VBA pour pouvoir générer un mail automatique depuis Excel.

Le seul souci que j'ai, est que le 'Body' du mail est sur plusieurs lignes


J'aimerai que les lignes de D6 à D12 soit repris dans l'ordre dans le corp de mon mail.

J'utilise la fonction Body = Range ("D6"), ce que je veux, c'est que les cellles D6, D7, D8, D9, D10, D11 et D12 soit repris dans mon mail et dans l'ordre ligne par ligne.


ce que je souhaite, c'est d'avoir le mail ci dessous en automatique



Exemple ci-joint, pouvez vous m'aider SVP ?

Cordialement

 

[Staple1600]

Bonjour


Voir du côté de .HTMLBody
Moult exemples dans les archives du forum
(entre 127 et 223 questions ont déjà abordées ce sujet, surtout les mardis et vendredi après 19 heures)

Pour les trouver, un seul endroit

Effectuez une recherche sur Excel Downloads...

www.excel-downloads.com

 

[patricktoulon]

bonjour

Private Sub CommandButtonl_Click()
Dim Lemail As Variant
Set Lemail = CreateObject("Outlook.Application") 'creating an Outlook object
With Lemail.CreateItem(olMailItem)
    .Subject = Range("D5")
    .To = Range("H2")
    .Body = Join(Application.Transpose([D6:D12]), vbCrLf)
    .Display
End With
End Sub

 

[Staple1600]

Bonjour patricktoulon

Oui, mais pour faire du joli (couleurs etc...)
Voir le message#2

 

[patricktoulon]

bonjour Staple1600
si t'insiste
ben tu passe en htmlbody
le temps de sortir ma gouache et mes pinceaux

Private Sub CommandButtonl_Click()
Dim Lemail As Variant
Set Lemail = CreateObject("Outlook.Application") 'creating an Outlook object
With Lemail.CreateItem(olMailItem)
    .Subject = Range("D5")
    .To = Range("H2")
   
    t = Application.Transpose([D6:D12])
    t(1) = "<b>" & t(1) & "</b>" & "<br/>"
    t(2) = "<font color=red><em>" & t(2) & "</em></font>"
    t(3) = "<div style=""background-color:cyan;color:rgb(150,150,0)"">" & t(3)
    t(4) = t(4) & "</div>" & "<br/>"
    t(5) = "<div style=""background-color:orange;color:rgb(0,0,255)""><b><em><u>" & t(5) & "<u><em><b>"
    t(6) = t(6) & "</div>" & "<br/>"
   
    .htmlBody = Join(t)
    .Display
End With
End Sub

 

[Staple1600]

Re

Euh, moi je n'insiste pas.
Le message#4 était là pour la saluer l'émetteur de message#3 qui n'avait pu passé le message#2
Mais une fois les satuations faites, fallait bien que l'émetteur des messages#2#4#6 dise un truc en rapport avec la question cise en message#1

 

[patricktoulon]

apres on peut tout formater dans les cellule comme on le veut et recupérer le html comme je l'ai deja montré
ca evite pour les moins aguerris avec le langage (html/css (inline) ) ne se prendre la tète

je le redonne au cas ou ça intéresse
voici comment on recupere le texte avec le formatage EN HTML

Function HtmlTextCode(cel)
    With CreateObject("htmlfile")
        code = Replace(Replace(cel(1).Value(xlRangeValueXMLSpreadsheet), "Cell", "Div"), "html:", "")
        .Body.innerhtml = code
        Set div = .getelementsbytagname("DIV")(0)
        If div.ChildNodes.Length > 0 Then x = div.ChildNodes(0).innerhtml Else x = div.innerhtml
        .Body.innerhtml = "<font face=""calibri"">" & Replace(x, "color=#000000", "") & "</font>"
        Set Fonts = .getelementsbytagname("FONT")
        For Each elem In Fonts
            fz = Val(elem.getattribute("size"))
            If fz > 0 Then elem.Style.FontSize = Val(elem.getattribute("size")) & "pt"
            elem.removeattribute ("size")
        Next
        Fonts(0).Style.FontSize = "11pt"
        HtmlTextCode = .Body.innerhtml
    End With
End Function

juste pour tester avec le visuel dans ( I E )

Sub testhtmltext()
    code = HtmlTextCode([A1])
    With CreateObject("internetexplorer.application")
        .Visible = True
        .navigate "about:blank"
        .document.write code
    End With
End Sub

c'est zzzzzoly!!!!!

pour ceux qui sont curieux voici le code obtenu

<FONT style="FONT-SIZE: 11pt" face=calibri><FONT face=Algerian x:Family="Decorative">DU</FONT><FONT> </FONT><B><I><FONT color=#ff0000 face="Blackadder ITC" x:Family="Decorative">TEXTE</FONT></I></B><FONT> </FONT><B><I><FONT color=#538dd5>en</FONT></I></B><FONT> </FONT><FONT color=#da9694 face=Broadway x:Family="Decorative">co</FONT><FONT color=#4bacc6 face=Broadway x:Family="Decorative">u</FONT><FONT color=#ffff00 face=Broadway x:Family="Decorative">leu</FONT><FONT color=#ff0000 face=Broadway x:Family="Decorative">r</FONT><FONT> formaté joli joli </FONT></FONT>

 

[Staple1600]

Re

=>patricktoulon
Quand je te disais que tu étais addict au CreateObject
With CreateObject("htmlfile")
et tu faisais donc pas toujours dans le "pure VB"


PS: MACistes, passez votre chemin

 

[patricktoulon]

re
a ben moi je travaille avec WindoWs, les machistes passez votre chemin ils n'ont qu'a pas avoir (le cul entre deux chaises)
d'ailleurs si il le veulent ,si ils ont cette fonction activé et fonctionnelle (je parle du .value(11))
libre a eux de disséquer façon versaintclitorix en string

LOL

 

[patricktoulon]

re
J'ai travaillé pendant des années en vbs dans le blok note , tu pense bien que maintenant pour changer le bonhomme il faut cravacher

 

[Staple1600]

Re

Le Bloc-Notes aussi c'est la Maison "fenêtre"
Dans le cellier, où sont les Pommes, cela a un autre nom

 

[patricktoulon]

tient comme c'est noel et si ils ont le .value(11) dispo) alors noyeux joel les machistes

Function HtmlCellTextCodeforMac(cel)
    Dim BD, Bfn, iD, iFn, uD, uFn, sD, sFn, cl
    code = Split(Replace(cel.Value(xlRangeValueXMLSpreadsheet), "ss:", ""), "<Data")(1)
    code = Split(Mid(code, InStr(1, code, ">") + 1), "</Data>")(0)
    code = Replace(Replace(code, "html:", ""), "x:Family=""Decorative""", "")
    For I = 1 To 100: code = Replace(code, "Size=""" & I & Chr(34), "style=""font-size:" & I & "pt;"""): Next
    If cel.Font.Bold = True Then BD = "<b>": Bfn = "</b> "
    If cel.Font.Italic = True Then iD = "<i>": iFn = "</i> "
    If cel.Font.Underline > 0 Then uD = "<u>": uFn = "</u> "
    If cel.Font.Strikethrough = True Then sD = "<Strike>": sFn = "</strike>"
    If cel.Font.Color <> vbBlack Then cl = "color=" & coul_XL_to_coul_HTMLX(cel.Font.Color)
    HtmlCellTextCodeforMac = "<font style=""font-size:11pt;""" & cl & ">" & sD & iD & BD & uD & code & uFn & Bfn & iFn & sFn & "</font>"
End Function

'je test quand meme avec IE dans windows (la sub ne fonctionne sur mac )

Sub Test_HtmlCellTextCodeforMac()
    code = HtmlCellTextCodeforMac([A1])
    With CreateObject("internetexplorer.application")
        .Visible = True
        .navigate "about:blank"
        .document.write code
    End With
End Sub

edit: j'ai ajouté la couleur globale
et donc ajouté aussi la fonction couleur excel to htmlcolor

Function coul_XL_to_coul_HTMLX(couleur)
    Dim str0 As String, strf As String
    str0 = Right("000000" & Hex(couleur), 6): strf = Right(str0, 2) & Mid(str0, 3, 2) & Left(str0, 2)
    coul_XL_to_coul_HTMLX = "#" & strf & ""
End Function

 

[hse]

Hello,

Merci beaucoup pour vos réponses,

patricktoulon
​

ta solution a très bien fonctionnée,

Staple1600​

c'est vrai que ça serait mieu avec des parties en couleur et d'autres en gras.

Mais je vous remercie du fond du coeur.

Bonne soirée

 

[Staple1600]

Bonjour le fil

=>hse
Je n'ai jamais dit que c'était mieux.
C'était juste ma manière de porter à ta connaissance la "propriété":
.HTMLBody
qui différe de
.Body