Formules imbriquées

Alban 56

XLDnaute Nouveau
Bonjour à toutes et à tous,

Je n'arrive pas à imbriquer ces 5 conditions pour n'obtenir qu'une seule formule à inscrire dans la cellule A6:
=Si(A1="A";"Première solution";"")
=Si(A1="B";"Deuxième solution";"")
=Si(A1="C";"Troisième solution";"")
=Si(A1="D";"Quatrième solution";"")
=Si(A1="E";"Cinquième solution";"")

D'avance merci pour votre aide,
Alban
 

Brigitte

XLDnaute Barbatruc
Re : Formules imbriquées

Bonjour,

Vite fait, mais d'autres pistes plus simples existent (tableau intermédiaire avec une recherche V ou index/equiv, ou d'autres encore) :

=SI(A1="A";"première solution";SI(A1="B";"deuxième solution";SI(A1="C";"troisième solution";SI(A1="D";"quatrième solution";"cinquième solution"))))

Edit : boum... bonjour ftho. Même combat. J'ai juste pas testé E puisque c forcément ca si les 4 autres marchent pas, donc ca simplifie : un si de moins, toujours ca de gagné ;-) : c'est quoi ton avatar ?
 
Dernière édition:

Monique

Nous a quitté
Repose en paix
Re : Formules imbriquées

Bonjour,

Pour jouer

=INDEX({"première solution";"deuxième solution";"troisième solution";"quatrième solution";"cinquième solution"};EQUIV(A1;{"a";"b";"c";"d";"e"};0))

=RECHERCHEV(A1;{"A"."première solution";"B"."deuxième solution";"C"."troisième solution";"D"."quatrième solution";"E"."cinquième solution"};2;0)

Edit

Suite

=RECHERCHEH(A1;{"A"."B"."C"."D"."E";"première solution"."deuxième solution"."troisième solution"."quatrième solution"."cinquième solution"};2;0)
 
Dernière édition:

Brigitte

XLDnaute Barbatruc
Re : Formules imbriquées

Re,

Qu'avais-je dit ? je pensai tout juste à Monique en mettant : rechercheV, index/equiv et d'autres formules (matricielles).

T'es pas possible, Monique, mais tellement exceptionnelle. Alban mesurera t'il sa chance de voir une réponse de toi sur sa question ? I hope so.

Bisous, doit faire frisquet à St Brieuc, fais gaffe en sortant.
 

Tibo

XLDnaute Barbatruc
Re : Formules imbriquées

Bonjour,

Pour le fun et pour varier les plaisirs, une autre solution avec la fonction CHOISIR :

Code:
=CHOISIR(CODE(MAJUSCULE(A1))-64;"première";"deuxième";"troisième";
"quatrième";"cinquième")&" solution"


Bon WE à tous

@+
 

Discussions similaires

Statistiques des forums

Discussions
312 113
Messages
2 085 422
Membres
102 886
dernier inscrit
eurlece