Formules extraire Date

[Paulle]

Bonjour,

Je voudrai récupérer dans la feuille Synthese le dernier jour de chaque mois et le montant correspondant de la feuille Releve.

J’ai bien tenté des formules =Max(Si(…., mais sans succès.
J’ai mis un fond jaune à titre indicatif pour les cellules du dernier jour de chaque mois.

En récupérant les valeurs Date et Montant de la feuille Synthese, je voudrai faire un graphique dans la feuille Graph.
Cela je pense pouvoir y arriver.

Merci pour votre aide.

 

[job75]

Re,

Avec le Dictionary la feuille source "Releve" peut être triée ou filtrée comme on veut sans inconvénient :

Private Sub Worksheet_Activate()
Dim t, d As Object, i&, x$, n&, j&
With Feuil1 'CodeName de la 1ère feuille
  If Application.Count(.[A:A]) = 0 Then GoTo 1 'si aucune date
  t = .[A1].Resize(Application.Match(9 ^ 9, .[A:A]), 2) 'matrice, plus rapide
End With
Set d = CreateObject("Scripting.Dictionary")
For i = 1 To UBound(t)
  If IsDate(t(i, 1)) Then
    x = Year(t(i, 1)) & Month(t(i, 1))
    If Not d.exists(x) Then n = n + 1: d(x) = n: t(n, 1) = t(i, 1): t(n, 2) = t(i, 2)
    j = d(x)
    If t(i, 1) > t(j, 1) Then t(j, 1) = t(i, 1): t(j, 2) = t(i, 2)
  End If
Next
If n = 0 Then GoTo 1 'sécurité
Application.ScreenUpdating = False
With [A2].Resize(n, 2)
  .Value = t 'restitution
  .Sort .Columns(1), xlAscending, Header:=xlNo 'tri sur les dates
End With
1 Range("A" & n + 2 & ":B" & Rows.Count) = ""
[A1].Resize(n + 1).Name = "X" 'plage nommée
[B1].Resize(n + 1).Name = "Y" 'plage nommée
End Sub

La macro trie à la fin le tableau des résultats.

Fichier (2).

C'est juste un peu moins rapide que précédemment : 0,02 seconde pour 3000 dates et 102 mois.

A+

 

[job75]

Re,

Une évidence mais qu'il est bon de mentionner.

S'il y avait des doublons de dates il faudrait préciser l'heure pour que la dernière soit retenue.

Bonne nuit.

 

[Paulle]

Merci job75.
Dans mon fichier, il n'y a pas de doublons de dates. En général, c'est un relevé journalier.