Microsoft 365 Formules Excel semaine

VBA_dev_Anne_Marie à dit:

Bonjour,

J'aurais une petite question, s'il vous plaît : est-ce qu'il existe une formule Excel qui permet d'incrémenter les semaines pour avoir ces données :

Du 01/01/2024 au 05/01/2024

Du 08/01/2024 au 12/01/2024

Du 15/01/2024 au 20/01/2024

Du 22/01/2024 au 27/01/2024

Merci beaucoup !

Cliquez pour agrandir...

Gégé-45550 à dit:

Pardon @Efgé, je n'avais pas vu ta (excellente) réponse !

Cliquez pour agrandir...

=LET(
Lundi;A1-JOURSEM(A1;3)+SEQUENCE(54;;0;7);
Vendredi;Lundi+4;
LesLundi;ANNEE(Lundi)=ANNEE(A1);
LesVendredi;ANNEE(Vendredi)=ANNEE(A1);
Verif;LesLundi+LesVendredi >0;
MesLundi;FILTRE(Lundi;Verif);
MesVendredi;FILTRE(Vendredi;Verif);
"Du "&TEXTE(MesLundi;"jj/mm/aaaa")&" au "&TEXTE(MesVendredi;"jj/mm/aaaa")
)

Efgé à dit:

Bonjour @VBA_dev_Anne_Marie , Salut @Victor21
Avec 01/01/2024 en A1

VB:

="DU "&TEXTE(A1-JOURSEM(A1;3)+SEQUENCE(54;;0;7);"jj/mm/aa")&" au "&TEXTE(A1-JOURSEM(A1;3)+SEQUENCE(54;;4;7);"jj/mm/aa")

Cordialement

EDIT

Et pour le fun; en limitant les dates sur l'année :

VB:

=LET(
Lundi;A1-JOURSEM(A1;3)+SEQUENCE(54;;0;7);
Vendredi;Lundi+4;
LesLundi;ANNEE(Lundi)=ANNEE(A1);
MesLundi;FILTRE(Lundi;LesLundi);
MesVendredi;FILTRE(Vendredi;LesLundi);
"DU "&TEXTE(MesLundi;"jj/mm/aaaa")&" au "&TEXTE(MesVendredi;"jj/mm/aaaa")
)

Cliquez pour agrandir...

Efgé à dit:

Re
Le 24/02/2024 est un samedi alors que votre demande va du Lundi au Vendredi.

Il vaux mieux utiliser la version du poste 5

Cordialement

Cliquez pour agrandir...

Efgé à dit:

Re
Le 24/02/2024 est un samedi alors que votre demande va du Lundi au Vendredi.
Regarde la pièce jointe 1199554
Il vaux mieux utiliser la version du poste 5

Cordialement

Cliquez pour agrandir...

VBA_dev_Anne_Marie à dit:

A1-JOURSEM(A1;3)

Cliquez pour agrandir...