Bonsoir
Mandyvall, Etoto, le fil,
j'ai vu quelques formules de la feuille "RECAP 03.05-06.06.21" ; c'est vraiment épatant ! 😁 😄 🤣 aussi, les formules qui seront à droite du signe « ➯ » sont celles que je propose en remplacement. 🙂
en
E12 :
=SI(ET(H12="";J12="";K12="");SI(SOMME(B13)<=8,5;SOMME(B13-C13)-SOMME(C13-C13);"");"")
* SOMME(B13) = B13
* SOMME(B13-C13) = B13-C13
* SOMME(C13-C13) = C13-C13 = 0
* SOMME(B13-C13)-SOMME(C13-C13) = (B13-C13) - (C13-C13) = (B13-C13) - 0 = B13-C13
➯ en
E12 :
=SI(ET(H12="";J12="";K12="");SI(B13<=8,5;B13-C13;"");"")
en
F12 :
=SI(SOMME(B12)<=8,5>10;SOMME(C12-B12)-SOMME(C12-C12);"")
* SOMME(B12) = B12
* SOMME(C12-B12) = C12-B12
* SOMME(C12-C12) = C12-C12 = 0
* =SI(SOMME(B12)<=8,5>10; ; horreur ! 😱 ce genre d'intervalle est correct en mathématiques, mais pas du tout avec Excel ! il faut l'écrire ainsi : =SI(ET(B12>=8,5;B12<10); ; signification : si B12 est supérieur ou égal à 8,5 ET si B12 est inférieur à 10 ; donc : si B12 fait partie de cet intervalle mathématique : [ 8,5 ; 10 [ ; de 8,5 inclus à 10 exclu. (attention au sens des crochets !)
➯ en
F12 :
=SI(ET(B12>=8,5;B12<10);C12-B12;"")
en
G12 :
=SI(ET(H12="";J12="";K12="");SI(SOMME(B12)>=10;SOMME(B12-D12)-SOMME(D12-D12);"");"")
* SOMME(B12) = B12
* SOMME(B12-D12) = B12-D12
* SOMME(D12-D12) = D12-D12 = 0
* SOMME(B12-D12)-SOMME(D12-D12) = (B12-D12) - (D12-D12) = (B12-D12) - 0 = B12-D12
➯ en
G12 :
=SI(ET(H12="";J12="";K12="");SI(B12>=10;B12-D12;"");"")
en
H12 :
=SI(JOURSEM(A12;2)=6;SOMME(B12)-SOMME(C12);"")
* SOMME(B12) = B12
* SOMME(C12) = C12
* SOMME(B12)-SOMME(C12) = B12-C12
➯ en
H12 :
=SI(JOURSEM(A12;2)=6;B12-C12;"")
en
J12 :
=SI(JOURSEM(A12;2)=7;SOMME(B12)-SOMME(C12);"")
* SOMME(B12) = B12
* SOMME(C12) = C12
* SOMME(B12)-SOMME(C12) = B12-C12
➯ en
J12 :
=SI(JOURSEM(A12;2)=7;B12-C12;"")
en
K12 :
=SI(ESTERREUR(EQUIV(A12;Fériés!$B$3:$B$11;0));"";SOMME(B12)-SOMME(C12))
* SOMME(B12) = B12
* SOMME(C12) = C12
* SOMME(B12)-SOMME(C12) = B12-C12
➯ en
K12 :
=SI(ESTERREUR(EQUIV(A12;Fériés!$B$3:$B$11;0));"";B12-C12)
c'est juste quelques suggestions, hein ? 😜 mais après tout, pourquoi faire simple quand on peut faire compliqué ? 😁 😂 🤣 😇 allez, courage ! je te mets cette mention : « tu peux mieux faire ! » 😜
soan