Formule Si est erreur + rechercheV

[RaphaelDD]

Bonjour,

J'aurai besoin de votre aide sur cette formule. je voudrais que si la recherchev est #N/A, la valeur renvoyé soit D24.

=SI(D24<>"";RECHERCHEV(D24;Table!AG2:AH28;2;FAUX);"")

Auriez vous une piste car je n'arrive pas a ajouter l'arguement SI est erreur ...

Merci d'avance pour votre aide

 

[Tibo]

Re : Formule Si est erreur + rechercheV

Bonjour,

Essaye avec cette formule :

=SI(NB.SI(Table!AG2:AG28;D24)=0;"";RECHERCHEV(D24;Table!AG2:AH28;2;FAUX))

Principe : on recherche d'abord si la valeur cherchée est présente.

@+

 

[Dranreb]

Re : Formule Si est erreur + rechercheV

Bonjour.
Personellement je préfère dissocier la recherche de la restitution de l'information parallèle dans 2 colonnes distinctes, pour éviter d'avoir à répéter un bout de formule.
Et puis ça peut toujours servir à fin de vérification d'avoir dans une colonne supplémentaire la ligne où on trouve l'information de l'autre coté. Et si vraiment on n'en veut pas on peut toujours la masquer.
Donc en nouvelle cellule xxx vous mettez:

=SI(D24<>"";EQUIV(D24;Table!AG2:AG28;0);"")

Et dans celle où vous aviez votre RECHERCHEV (salopperie cette fonction) vous mettez:

=SI(ESTNUM(xxx);INDEX(Table!AH2:AH28;xxx);D24)

Cordialement

 

[RaphaelDD]

Re : Formule Si est erreur + rechercheV

Merci Tibo pour ta réponse malheureusement elle ne fonctionne pas comme je le voudrais.

Dranreb: Milles mercis ca fonctionne.

En revanche est il possible de ne pas faire apparaitre un 0 dans la cellule de la formule suivante lorsque D24 est vide?

=SI(ESTNUM(Y25);INDEX(Table!AH2:AH28;Y25);D24)

Merci encore pour votre disponibilité !

 

[Dranreb]

Re : Formule Si est erreur + rechercheV

=SI(ESTNUM(Y25);INDEX(Table!AH2:AH28;Y25);D24&"")

 

[RaphaelDD]

Re : Formule Si est erreur + rechercheV

Ca marche !

Merci encore pour votre aide !

 

[R@chid]

Re : Formule Si est erreur + rechercheV

Slt tout le monde.
Si j'ai bein compris c'est peut etre ce que tu recherche :

=si(estna(RECHERCHEV(D24;Table!AG2:AH28;2;FAUX));D24;RECHERCHEV(D24;Table!AG2:AH28;2;FAUX))

 

[Dranreb]

Re : Formule Si est erreur + rechercheV

Bonjour Rachid,
Non, en une seul formule il aurait voulu ce que donne ça :

=SI(D24<>"";SI(ESTNUM(EQUIV(D24;Table!AG2:AG28;0));INDEX(Table!AH2:AH28;EQUIV(D24;Table!AG2:AG28;0));D24);"")

et que je lui ai conseillé de décomposer en deux formules.