Formule pour séparer une phrase

[Sylvie64]

Bonjour,

Est il possible avec une formule en G3 de séparer les prénoms de la phrase ?
Comme l'exemple en ligne 2. (PJ)

Sachant qu'il y a 1/2 voir 3 prénoms.

J'ai eu une formule pour séparer les phrases quand il y avait "né" sur chaque ligne, mais là je suis coincée, il y a : né, un métier, l'âge ....

Merci pour votre aide.

Sylvie

 

[Tibo]

Re : Formule pour séparer une phrase

Bonjour,

A moins d'avoir une liste des métiers dans une autre feuille par exemple, je ne vois pas comment expliquer à Excel la différence entre un métier et un prénom.

Sous réserve que certains prénoms ne soient pas assimilables à des métiers...

Es-tu en mesure d'établir cette liste de métiers ?

@+

 

[Sylvie64]

Re : Formule pour séparer une phrase

Merci Tibo pour la réponse.
Je me douter un peu que cela serait difficile.
Voici le fichier avec en deuxième page une liste de métier.

 

[Tibo]

Re : Formule pour séparer une phrase

Bonjour,

Une première version, pas parfaite :

Commencer par nommer la liste des métiers : métiers
et la liste fils; né : fils_né

Ensuite, en G2, une formule matricielle :

=SI(SOMME(ESTNUM(CHERCHE(métiers;F2))*1)>0;GAUCHE(F2;CHERCHE(
INDEX(métiers;EQUIV(VRAI;ESTNUM(CHERCHE(métiers;F2));0));F2)-2);SI(SOMME(
ESTNUM(CHERCHE(fils_né;F2))*1)>0;GAUCHE(F2;CHERCHE(INDEX(fils_né;
EQUIV(VRAI;ESTNUM(CHERCHE(fils_né;F2));0));F2)-2);F2))

Formule matricielle à valider par CTRL + MAJ + ENTREE

puis à recopier vers le bas

Le souci, c'est lorsque né apparaît avant le métier. La formule reste donc à peaufiner.

Je verrais sans doute ce soir pour améliorer

Je te laisse déjà tester cette première version

Le fait de travailler sur des listes nommées permet d'envisager le traitement d'autres chaînes de caractères (telles que fille de par exemple)

@+

Edit : ne pas oublier dans ta liste de métiers de supprimer les espaces inutiles à la fin de certains métiers

@+

 

[Sylvie64]

Re : Formule pour séparer une phrase

Merci Tibo,

En PJ, j'ai fais comme vous avez dit, il est vrai qu'il y a quelques erreurs mais bon ! c'est déjà un grand avancement car je retaper tout, ligne par ligne !!!

Par contre en colonne H, j'ai repris la même formule (en changeant GAUCHE par DROITE)

mais cela me prend la dernière lettre des prénoms ou/et les prénoms et à la ligne 14,18... le métier est en partie en G et H , bizarre non !!!

Encore un grand merci et félicitation pour cette formule.

 

[Tibo]

Re : Formule pour séparer une phrase

re,

Pour la colonne H, pour aller au plus simple, en H2 :

=SUPPRESPACE(SUBSTITUE(F2;G2;""))

à recopier vers le bas

Je vais voir, pour la première formule (colonne G), s'il est possible de l'améliorer

@+

 

[Tibo]

Re : Formule pour séparer une phrase

re,

Le fait que tu aies posté dans le Forum Excel 2007 fait supposer que tu disposes de cette version.

Dans ce cas, je te propose une formule acceptée par Excel 2007 (mais pas par les versions précédentes compte tenu du nombre de niveaux d'imbrication) :

en G2 :

=SI(SOMME(ESTNUM(CHERCHE(métiers;F2))*1)>0;SI(SOMME(ESTNUM(CHERCHE(fils_né;
F2))*1)>0;GAUCHE(F2;MIN(CHERCHE(INDEX(fils_né;EQUIV(VRAI;ESTNUM(CHERCHE(
fils_né;F2));0));F2);CHERCHE(INDEX(métiers;EQUIV(VRAI;ESTNUM(CHERCHE(métiers;
F2));0));F2))-2);GAUCHE(F2;CHERCHE(INDEX(métiers;EQUIV(VRAI;ESTNUM(CHERCHE(
métiers;F2));0));F2)-2));SI(SOMME(ESTNUM(CHERCHE(fils_né;F2))*1)>0;GAUCHE(F2;
CHERCHE(INDEX(fils_né;EQUIV(VRAI;ESTNUM(CHERCHE(fils_né;F2));0));F2)-2);F2))

Toujours matricielle donc validation par CTRL + MAJ + ENTREE

et à recopier vers le bas

Avec un peu (beaucoup) de temps, on pourrait peut-être trouver plus court.

Je te laisse tester

Bonne soirée

@+

 

[Sylvie64]

Re : Formule pour séparer une phrase

Vraiment un grand merci Tibo pour ton aide.
Pour la colonne H, OK
Pour la colonne G, là c'est plutôt raté, en fessant comme tu as dit cela ne fonctionne pas.

 

[Tibo]

Re : Formule pour séparer une phrase

Bonjour,

Je te joins ton dernier fichier avec les formules proposées.

Fichier au format Excel 2007

@+

 

[Sylvie64]

Re : Formule pour séparer une phrase

Bonjour,

Excellent pour le fichier reçu, impeccable et moi quand je remet la formule sur mon fichier cela ne fonctionne pas!!! 😡

j'ai bien mis la formule et changer la cellule "F2 en F2737"

j'ai pu changer les trois premier mais les suivant ne sont pas de couleur bleu.

Regardez en PJ, mais ou est mon erreur ??? sachant que j'ai fais un copier/colle de votre formule!!!

Merci

Sylvie

 

[Tibo]

Re : Formule pour séparer une phrase

re,

Il faut que ton fichier soit enregistré au format Excel 2007.

Enregistrer sous - Classeur Excel

Le souci que tu rencontres semble être dû au fait que ton fichier est enregistré en Classeur Excel 97-2003

Je te laisse regarder

@+

 

[Sylvie64]

Re : Formule pour séparer une phrase

EXCELLENT un grand merci.
Et merci pour ta patience.
Bonne journée
Sylvie