Formule pour liste sans doublons

[pepsi]

Bonjour

J'ai une formule qui me permet, sans macro de créer des listes sans doublons.

Et suivant ou je la place dans mon document, elle n'affiche pas la liste sans doublons.
et la liste (quand ca marche) n'est pas complète...


Si quelqu'un peut m'aider en regardant mon document

d'avance merci

 

[BOISGONTIER]

Re : Formule pour liste sans doublons

Bonjour,

=INDEX(ch;MIN(SI(ch<>"";SI(NB.SI(K$2:K2;ch)=0;EQUIV(ch;ch;0);LIGNES(ch)))))
Valider avec maj+ctrl+entrée

Sans doublons trié (formule de David84)
=INDEX(champ;EQUIV(PETITE.VALEUR(SI(champ<>"";SI(EQUIV(champ;champ;0)=LIGNE(INDIRECT("1:"&LIGNES(champ)));NB.SI(champ;"<"&champ)));LIGNE(INDIRECT("1:"&LIGNES(champ))));SI(champ<>"";SI(EQUIV(champ;champ;0)=LIGNE(INDIRECT("1:"&LIGNES(champ)));NB.SI(champ;"<"&champ)));0))

JB

 

[R@chid]

Re : Formule pour liste sans doublons

Bonjour @ tous,
en K3 :

=SIERREUR(DECALER(A$2;EQUIV(0;NB.SI(K$2:K2;A$3:A$11);0););"")

@ valider par Ctrl+Shift+Enter
@ tirer vers le bas

Extraction sans doublons mais sans tri.


@ + +

 

[pepsi]

Re : Formule pour liste sans doublons

bonjour,

Merci pour vos solutions, mais je souhaitais éviter les formules matricielles...

ce que je ne comprends pas c'est comment faire pour que la formule dans mon fichier fonctionne;

Pourquoi, selon ou elle se situe dans la feuille elle ne fonctionne plus correctement...

Qu est ce qui bloque dans la formule ?

Si quelqu'un a une piste.

 

[GerardCalc]

Re : Formule pour liste sans doublons

Bonjour,

Premier tableau (doublon "pomme", manque "mangue") :
Attention aux références relatives/absolues pour la recopie. (Colonne J)
=SI(OU(A3="";NB.SI(A$2:A3;A3)>1);"";NB.SI(A$2:A$11;">="&A3))

Second tableau :
=SI(LIGNE()-1>NB($J$18:$J$26);"";etc...
Que renvoie d'après toi LIGNE()-1 lorsque tu est en ligne 18 ?
d'autre part certaines références de plages ne sont pas correctes.
Formule modifiée :
=SI(LIGNE()-17>NB($J$18:$J$26);"";INDEX($A$18:$A$26;EQUIV(GRANDE.VALEUR($J$18:$J$26;LIGNE()-17);$J$18:$J$26;0)))

A+

 

[gosselien]

Re : Formule pour liste sans doublons

Bonjour,

tu veux une liste sans doublon et triée ...
on doit donc éliminer les doublons mais sur base de la colonne des fruits ou de la colonne "J" ou des 2 simultanément ?
Une solution VBA te convient ?

 

[pepsi]

Re : Formule pour liste sans doublons

Bonjour,

Faire une extraction de liste sans doublons, sur la base de la colonne des fruits, la colonne A

et je ne souhaite pas utiliser de vba ...

 

[R@chid]

Re : Formule pour liste sans doublons

Bonjour,
en J3:

=SI(NB.SI(A$3:A3;A3)>1;"";LIGNES($3:3))

@ tirer vers le bas

en K3:

=SIERREUR(INDEX(A$3:A$11;EQUIV(PETITE.VALEUR(J$3:J$11;LIGNES($3:3));J$3:J$11;0));"")

@ tirer vers le bas


@ + +