Microsoft 365 Formule dernière valeur non nulle sur plusieurs tableaux

[moostick]

Bonjour à tous,

Je n'arrive pas à réaliser une formule qui me permette de récupérer la dernière valeur non nulle de 12 mini tableaux qui se remplissent automatiquement.
La position de la dernière valeur est amenée à changer en fonction des paramètres que je rentre.

Pouvez-vous m'apporter votre aide ?

Vous trouverez ci-joint un exemple qui illustrera beaucoup mieux ma problématique.

Je vous remercie par avance de l'aide que vous pourriez m'apporter.

Moostick

 

[Hasco]

Bonjour,

récupérer la dernière valeur non nulle

Vos valeur ne sont pas nulles. Zéro est différent de nul.

Une proposition avec en colonne E (à cacher ?) une fonction agregat. Idem pour la cellule de résultat.

Cordialement

 

[sylvanu]

Bonjour Moostick, Roblochon,
Un essai avec Recherche. Un peu lourd comme formule, mais une fois écrite :

=SI(RECHERCHE(9^9;F69:Q69)>0;RECHERCHE(9^9;F69:Q69);
SI(RECHERCHE(9^9;F64:Q64)>0;RECHERCHE(9^9;F64:Q64);
SI(RECHERCHE(9^9;F59:Q59)>0;RECHERCHE(9^9;F59:Q59);
SI(RECHERCHE(9^9;F54:Q54)>0;RECHERCHE(9^9;F54:Q54);
SI(RECHERCHE(9^9;F49:Q49)>0;RECHERCHE(9^9;F49:Q49);
SI(RECHERCHE(9^9;F44:Q44)>0;RECHERCHE(9^9;F44:Q44);
SI(RECHERCHE(9^9;F39:Q39)>0;RECHERCHE(9^9;F39:Q39);
SI(RECHERCHE(9^9;F34:Q34)>0;RECHERCHE(9^9;F34:Q34);
SI(RECHERCHE(9^9;F29:Q29)>0;RECHERCHE(9^9;F29:Q29);
SI(RECHERCHE(9^9;F24:Q24)>0;RECHERCHE(9^9;F24:Q24);
SI(RECHERCHE(9^9;F19:Q19)>0;RECHERCHE(9^9;F19:Q19);
SI(RECHERCHE(9^9;F14:Q14)>0;RECHERCHE(9^9;F14:Q14);
""))))))))))))

 

[moostick]

Bonjour Sylvanu,
ça fonctionne, c'est super. Merci beaucoup pour ton aide.
Une très bonne journée.

 

[Hasco]

Re,

Sans doute suis-je invisible aujourd'hui 🙂

Cordialement

 

[moostick]

Re,

Sans doute suis-je invisible aujourd'hui 🙂

Cordialement

Bonjour Roblochon,

Milles excuses, j'ai du loucher.
Merci beaucoup pour ton aide

 

[R@chid]

Bonjour @ tous,

=MAX(DECALER(F14;SEQUENCE(LIGNES(F14:Q69)/5+1;;0)*5;;12))

Cordialement

 

[R@chid]

Re,
ma première formule en post #7 fonctionnera bien si les valeurs augmentent d'un mois à l'autre et d'une année à l'autre, mais s'il va y avoir des hauts et des bats, elle ne va renvoyer que la plus grande valeur bien sûr.

Sinon, puisque tu es sous Excel pour Microsoft 365; tu peux profiter de cette jolie formule, mais il faut mettre à jour ton Excel pour avoir la fonction LET() :

=LET(NbLigne;LIGNES(F14:Q69);Nlignes;ENT(SEQUENCE(ENT(NbLigne/5+1)*12;;0)/12)*5+1;Ncolonnes;MOD(SEQUENCE(ENT(NbLigne/5+1)*12;;0);12)+1;MesVals;INDEX(F14:Q69;Nlignes;Ncolonnes);INDEX(FILTRE(MesVals;MesVals<>0);LIGNES(FILTRE(MesVals;MesVals<>0))))

Cordialement