Ceci est une page optimisée pour les mobiles. Cliquez sur ce texte pour afficher la vraie page.

Autres Formule Cellule avec chiffre et texte

U

ultra_v

XLDnaute Occasionnel
bonjour ,

la colonne "A" contient des milliers de données ( numerique , text , numerique & text )
j'en ai pas réussi avec les filtres classiques je voudrais svp une formule :
si la Cellule contient que du texte " aaa aaa a aaa" = renvoie la valeur "text "
si la Cellule contient que du texte & numerique genre " aaa 1589 " = renvoie la valeur "alphanumerique "
si la Cellule contient que du chiffre = renvoie la valeur "numerique "
merci

Excel 2007
 
Trier par date Trier par votes

Jacky67

XLDnaute Barbatruc
Bonjour
A tester
Code: 
=SI(ESTNUM(A1);"Numérique";SI(NBCAR(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(A1;0;"");1;"");2;"");3;"");4;"");5;"");6;"");7;"");8;"");9;""))=NBCAR(A1);"Texte";"Alphanumérique"))
 

Pièces jointes

  • MumAlphaText.xlsx
    15.4 KB · Affichages: 0
Dernière édition:
Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc
Bonjour ultra_v, Jacky67,

Une autre solution dans ce fichier avec en B2 :
Code: 
=SI(A2="";"";SI(SOMMEPROD(-ESTNUM(-STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1)));SI(ESTNUM(-A2);"numérique";"alphanumérique");"alpha"))
A+
 

Pièces jointes

  • Test(1).xlsx
    10.4 KB · Affichages: 4
Dernière édition:
Vote positif 0 Vote négatif

Jacky67

XLDnaute Barbatruc
Hello job75
Certainement que
alpha=texte
Des difficultés avec des nombres avec décimale..

**Ouppss!!, Pas vu que c'était modifié
 
Dernière édition:
Vote positif 0 Vote négatif

Jacky67

XLDnaute Barbatruc
ultra_v à dit:
merci à vous tous
ça marche parfait
une petite modif svp jacky les cellules vides ça me renvoit text
Cliquez pour agrandir...

Re..
Ben ça alors...
Code: 
=SI(A1="";"";SI(ESTNUM(A1);"Numérique";SI(NBCAR(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(A1;0;"");1;"");2;"");3;"");4;"");5;"");6;"");7;"");8;"");9;""))=NBCAR(A1);"Texte";"Alphanumérique")))
 
Vote positif 0 Vote négatif

patricktoulon

XLDnaute Barbatruc
Bonjour à tous
j'ai peut être un moyen de réduire les kilomètres de substitue
fair un equiv 0 matriciel sur une matrice grâce à stxt indirect ligne
grace à cela tout les caractères de la chaine sont passés en revue
et le principe va me donner la première position d'un chiffre dans la chaine le tout dans un si(esterreur ....)bien sur
le tout dans un si esnum( valeur ;"numerique" ; si(estnum(matriciel de recherche ; "alphanumérique" ; "alpha")
la formule ca donnerait ceci
VB: 
=SI(ESTNUM(A2);"numérique";SI(ESTNUM(EQUIV(0;ESTERREUR(STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1)*1)*1;0));"Alphanumérique";"Alpha"))

le résultat me parait cohérent

sinon il y a secence pour 365 mais celle ci valider en matriciel sur <365 fonctionne
donc compatible 2007 à 365
 
Vote positif 0 Vote négatif

patricktoulon

XLDnaute Barbatruc
re
allez en réfléchissant un peu plus je fait avec une matrice codée en dur
la formule est encore plus courte
c'est un peu pareil sauf que la le cherche matriciel me renvoie 0 si pas de chiffre
doncdans la 2d condition si numerique , alors alpha numerique sinon numerique

VB: 
=SI(ESTNUM(A2);"Numerique";SI(MIN(SIERREUR(CHERCHE({0;1;2;3;4;5;6;7;8;9};A2);""))>0;"Alphanumerique";"Alpha"))

là aussi compatible 2007 à 365 (valider en matriciel en dessouis de 365 )
je joins un fichier avec les deux exemples
 

Pièces jointes

  • formule cherche les nombre.xlsm
    8.9 KB · Affichages: 3
Vote positif 0 Vote négatif

Jacky67

XLDnaute Barbatruc
Hello Patrick,
J'avais cherché dans cette direction, sans succès, certainement dû à mon manque de patience.
Bravo
Le seul avantage des rallonges de 'SUBSTITUE' c'est quelle n'a pas de validation matricielle.
 
Dernière édition:
Vote positif 0 Vote négatif

patricktoulon

XLDnaute Barbatruc
re
@Jacky67 , @job75
tiens pour le coup je soulève une autre question
version 1 (2 formules valables)

a
VB: 
=SI(A2<>"";SI(ESTNUM(A2);"numérique";   SI(ESTNUM(EQUIV(0;ESTERREUR(STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1)*1)*1;0));   "Alphanumérique"; "Alpha"));"")

b
Code: 
=SI(ESTNUM(A2);"numérique";   SI(ESTNUM(EQUIV(0;ESTERREUR(STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1)*1)*1;0));   "Alphanumérique"; SI(A2<>"";"Alpha";"")))


version 2 (2 formules valables)

a
Code: 
=SI(A2<>"";SI(ESTNUM(A2);"Numerique";SI(MIN(SIERREUR(CHERCHE({0;1;2;3;4;5;6;7;8;9};A2);""))>0;"Alphanumerique";"Alpha"));"")

b
Code: 
=SI(ESTNUM(A2);"Numerique";SI(MIN(SIERREUR(CHERCHE({0;1;2;3;4;5;6;7;8;9};A2);""))>0;"Alphanumerique";si(A2<>"";"Alpha";"")))

la question;
quelle est l'incidence (en terme de ressource) de faire le test A2<>"" en global ou dans le matriciel?
 
Vote positif 0 Vote négatif
Identifiez-vous ou inscrivez-vous pour participer.

Discussions similaires

C
  • Question
Microsoft 365 Soustraire cellule contenant texte et heure (résolue)
Réponses
2
Affichages
161
Cougar
C
D
  • Question
Microsoft 365 mise en forme conditionnelle : choisir la couleur d'une autre cellule
Réponses
11
Affichages
468
deuxnid
D
S
  • Question
XL 2019 Formule RECHERCHEV avec des valeurs cherchées négatives qui ne fonctionne pas et renvoi #Réf
Réponses
2
Affichages
180
Phil69970
N
  • Question
Microsoft 365 Tableau calcul entre deux dates
Réponses
1
Affichages
172
job75
  • Question
XL 2016 formule si avec du texte
Réponses
14
Affichages
430
richardlion
P
  • Question
XL 2016 excel formule
Réponses
11
Affichages
801
denisR
D
  • Question
XL 2016 Formule nbre de jours ouvrés et cellules vides renvoyant la cellule O à vide
Réponses
3
Affichages
475
Gégé-45550
M
  • Question
Microsoft 365 Résultat #DIV/0! avec fonction si erreur avec formule moyenne
Réponses
8
Affichages
299
Maya3375
M
A
  • Résolu(e)
Microsoft 365 Enregistrer copie d'un fichier avec pour nom le contenu d'une cellule excel (macro)
2
Réponses
15
Affichages
790
firecarl
F
Z
  • Question
XL 2013 Interdire certains caractères (. @ et $)
Réponses
5
Affichages
381
job75
Menu
Connexion
S'inscrire
Les cookies sont requis pour utiliser ce site. Vous devez les accepter pour continuer à utiliser le site. En savoir plus…