Fonction Index, equiv avec Condition

[abouam]

Bonjour
Je cherche une formule telle que INDEX & EQUIV mais j'ajoute une condition
.
REF Code tarif
1 A 15,00 €
1 B 2,50 €
1 C 3,50 €
1 D 4,50 €
2 A 10,00 €
2 B 21,00 €
2 C 14,00 €
2 D 9,00 €
3 A 30,00 €
3 B 25,00 €
3 C 6,00 €
3 D 14,00 €
-----------------------------------------
Ref Code Tarif
1 D ??????

Si joint le fichier exercice.
merci beaucoup !

 

[ROGER2327]

Re : Fonction Index, equiv avec Condition

Bonsoir abouam

Une proposition dans le classeur joint.

[COLOR="DarkSlateGray"][B]=INDEX(C2:C13;SOMME((A2:A13=A19)*(B2:B13=B19)*LIGNE($1:$12)))[/B][/COLOR]

(Formule matricielle)​

ROGER2327
#3863

Dimanche 22 Gidouille 137 (Fête de Gidouille, SS)
18 Messidor An CCXVIII
2010-W27-2T22:42:57Z

 

[Tibo]

Re : Fonction Index, equiv avec Condition

Bonjour,

Une autre solution avec INDEX et EQUIV :

=INDEX(C2:C13;EQUIV(A19&B19;A2:A13&B2:B13;0))

Matricielle à valider par CTRL + MAJ + ENTREE

une solution avec SOMMEPROD (sans INDEX ni EQUIV), valable s'il n'y a pas de doublons :

=SOMMEPROD((A2:A13=A19)*(B2:B13=B19)*C2:C13)

@+

 

[abouam]

Re : Fonction Index, equiv avec Condition

Je TIENS à vous en remercier bcp !
C'est ce que je cherchais !

Merci encore !

 

[abouam]

Re : Fonction Index, equiv avec Condition

Bonsoir abouam

Une proposition dans le classeur joint.

[COLOR="DarkSlateGray"][B]=INDEX(C2:C13;SOMME((A2:A13=A19)*(B2:B13=B19)*LIGNE($1:$12)))[/B][/COLOR]

(Formule matricielle)​

ROGER2327
#3863

Dimanche 22 Gidouille 137 (Fête de Gidouille, SS)
18 Messidor An CCXVIII
2010-W27-2T22:42:57Z

Bonjour
Merci de votre aide.
Cependant, je viens de constater une anomalie et je ne sais pas comment régler.
Au fait quand je saisie une référence fausse qui n'existe pas dans la plage horaire, j'ai pourtant un résultat alotrs que cela risque de fausser mes résultats.
Merci de votre aide !!

 

[abouam]

Re : Fonction Index, equiv avec Condition

Bonjour
merci de votre aide mais je viens de constater une anomalie.
quand je saisie une référence qui n'existe pas, j'ai pourtant un résultat alors je cherche a voir un résultat EXACT.
Merci de votre aide

 

[david84]

Re : Fonction Index, equiv avec Condition

Bonjour,
la formule de Tibo fonctionne correctement.
Possible également avec index et equiv :
=INDEX(C2:C13;EQUIV(1;(A2:A13=A19)*(B2:B13=B19);0))
Formule matricielle à valider par ctrl, maj et entrée.
A+

 

[JHA]

Re : Fonction Index, equiv avec Condition

Bonjour,

avec un contrôle d'erreur:
=SI(ESTERREUR(INDEX(C2:C13;EQUIV(A16&B16;A2:A13&B2:B13;0)));"";INDEX(C2:C13;EQUIV(A16&B16;A2:A13&B2:B13;0)))
A valider par Ctrl+Maj+Entrée

JHA

 

[david84]

Re : Fonction Index, equiv avec Condition

Re,
ci-joint ton fichier en retour avec les 2 formules index et equiv (si ref ou code non valide, la formule l'affiche).
A+

 

[abouam]

Re : Fonction Index, equiv avec Condition

Merci beaucoup !
C'est clair !
Bonne fin de journée !!

 

[ROGER2327]

Re : Fonction Index, equiv avec Condition

Re...

Bonjour
Merci de votre aide.
Cependant, je viens de constater une anomalie et je ne sais pas comment régler.
Au fait quand je saisie une référence fausse qui n'existe pas dans la plage horaire, j'ai pourtant un résultat alotrs que cela risque de fausser mes résultats.
Merci de votre aide !!

[COLOR="DarkSlateGray"][B]=SI(SOMME((A2:A13=A16)*(B2:B13=B16));INDEX(C2:C13;SOMME((A2:A13=A16)*(B2:B13=B16)*LIGNE($1:$12)));)[/B][/COLOR]

(formule matricielle)​

ROGER2327
#3895

Dimanche 1er Tatane 137 (Fête du Père Ubu (Ubu d'été), SPs)
26 Messidor An CCXVIII
2010-W28-3T14:56:35Z