Fonction atteindre sur multiples onglets

[Rick@]

Bonjour,

Comme le titre le dit, il me faut effacer plusieurs "objets" dans plusieurs onglets (+250 ). Histoire de ne pas prendre ma retraite là dessus, j'ai mis en macro la fonction "atteindre" cependant un seul onglet n'est permis à la fois... Comment effacer tous les objets dans tous les onglets en une seule action???

Merci encore et encore!!!!

 

[flyonets44]

Re : Fonction atteindre sur multiples onglets

Bonjour
Sub Select_Sheets()
Dim W As Worksheet
For Each W In ActiveWorkbook.Worksheets
W.Select Replace:=False
Next W
End Sub
Cordialement
Flyonets

 

[Dranreb]

Re : Fonction atteindre sur multiples onglets

Bon jour
Et bien si vous savez le faire pour une feuille F donnée:

Dim F As Worksheet
For Each F In ThisWorkbook.Worksheets
   CeQueJeSaisFaire
   Next F

À+

 

[Rick@]

Re : Fonction atteindre sur multiples onglets

Il semble manquer quelque chose... Voici la macro de base,

Sub Atteindre()
'
' Atteindre Macro
' Macro enregistrée le 2011-08-15 par bh7997
'

'
ActiveSheet.DrawingObjects.Select
End Sub

 

[Dranreb]

Re : Fonction atteindre sur multiples onglets

Il semble manquer quelque chose
votre macro sélectionne une collection mais ne supprime rien.
De plus cette collection .DrawingObjects ne m'est pas proposée. Je connais Shapes. Alors:

Dim F As Worksheet, D As Shape
For Each F In ThisWorkbook.Worksheets
   For Each D In F.Shapes
      D.Delete
      Next D
   Next F

À+

 

[Rick@]

Re : Fonction atteindre sur multiples onglets

Nous sommes sur une bonne piste! La macro efface les objets dans tous les onglets, cependant j'aimerais pouvoir sélectionner moi même les onglets et surtout pouvoir en sélectionner plusieurs à la fois et ainsi y effacer les objets.

 

[Dranreb]

Re : Fonction atteindre sur multiples onglets

Alors sélectionnez les feuilles concernées en maintenant Ctrl appuyé avant de lancer la macro contenant:

Dim F As Worksheet, D As Shape
For Each F In ThisWorkbook.Windows(1).SelectedSheets
   For Each D In F.Shapes
      D.Delete
      Next D
   Next F

À+

 

[Rick@]

Re : Fonction atteindre sur multiples onglets

La touche controle fait "buggé" la macro... Voici un démo

 

[Guest]

Re : Fonction atteindre sur multiples onglets

Bonsoir Rick,
DranReb🙂

Il y a des choses qu'on ne peut pas traiter sur des groupes de feuilles.
Sélectionne tes feuilles comme dit par DranReb et lance la macro suivante.

Elle parcourt les feuilles sélectionnées pour n'en retenir que le nom
elle sélectionne la première d'entre elle (pour déselectionner le groupe)

Sub Atteindre()
    Dim tbl() As String    'Tableau des noms de feuilles sélectionnées
    Dim i As Integer    ' indice de boucle
'Dresser le tableau des noms de feuilles sélectionnées
    With ThisWorkbook.Windows(1).SelectedSheets
        ReDim tbl(1 To .Count)
        For i = 1 To .Count
            tbl(i) = .Item(i).Name
        Next
        'Sélectionne la première des feuilles
        .Item(1).Select
    End With
'Traiter les Shapes des feuilles l'une après l'autre
    For i = 1 To UBound(tbl)
        With ThisWorkbook.Sheets(tbl(i))
            Do While .Shapes.Count > 0
                .Shapes(1).Delete
            Loop
        End With
    Next
End Sub

A+

 

[Dranreb]

Re : Fonction atteindre sur multiples onglets

Savais plus...
Mais on peut quand même l'écrire plus simplement:

Sub Atteindre()
Dim Fs As Sheets, F As Object, D As Shape
Set Fs = ThisWorkbook.Windows(1).SelectedSheets
Fs(1).Select
For Each F In Fs
   For Each D In F.Shapes
      D.Delete
      Next D
   Next F
End Sub

À+

 

[Guest]

Re : Fonction atteindre sur multiples onglets

Re,

DranReb🙂

C'est juste. Parfois on s'en va dans des directions.....

A+

 

[Rick@]

Re : Fonction atteindre sur multiples onglets

Gros merci à vous deux, c'est génial!