Microsoft 365 Extraire texte cellule Excel

Alyssa_jck · 11 Février 2024

Bonjour,

Étant sur un projet Excel, je rencontre un problème, afin d’ extraire un texte entre deux espaces mais aussi le texte se trouvant avant le deuxième espace… existe-t-il des formules nous permettant de résoudre ce problème facilement ?

Exemple :
Ma cellule comporte le texte suivant : IPE A 160 - J’aimerais avoir dans un premier temps : IPE A
Puis pour HE 700 AA - j’aimerais extraire le 700

Merci infiniment par avance,

sylvanu · 11 Février 2024

Bonjour Alyssa, et bienvenu(e) sur XLD,
Un essai en PJ avec cette petite fonction perso :

VB:

Function Separe(C$, N%)
Dim T: T = Split(C, " ")
Select Case N
    Case 1:     Separe = T(0) & " " & T(1)
    Case 2:     Separe = T(1)
End Select
End Function

Ou par formule comme dans la PJ mais c'est plus complexe.

DJunqueira · 11 Février 2024

Avec formule.

=FILTRE.XML("<F><d>"&SUBSTITUE( A3;" ";"</d><d>")&"</d></F>";"//d[translate(.,'1234567890','')!=.]")

=GAUCHE(A2;MIN(SIERREUR(TROUVE(LIGNE(A$1:A$9)-1;A2);999))-1)

R@chid · 12 Février 2024

Bonjour et Bienvenue sur XLD,
Bonjour les amis,
Sous Excel pour Microsoft 365,
pour les valeurs textes :

VB:

=LET(Txt;STXT(A1;SEQUENCE(NBCAR(A1));1);SUPPRESPACE(CONCAT(FILTRE(Txt;ESTERR(--Txt)))))

Pour les valeurs numériques :

Code:

=LET(Txt;STXT(A2;SEQUENCE(NBCAR(A2));1);SUPPRESPACE(CONCAT(FILTRE(Txt;ESTNUM(--Txt)))))

Cordialement

patricktoulon · 13 Février 2024

Bonjour à tous
à l'ancienne
tu veux le 2d tu met 1 ,tu veux le 3eme tu met 2 , etc....

IPE A 160		=SUPPRESPACE(GAUCHE(SUBSTITUE(A2;" ";REPT(" ";255));255*2))
HE 700 AA		=SUPPRESPACE(STXT(SUBSTITUE(A3;" ";REPT(" ";255));255*1;255))

resultat

IPE A 160		IPE A
HE 700 AA		700

ou bien encore comme ça

IPE A 160		=SUPPRESPACE(GAUCHE(SUBSTITUE(A2;" ";REPT(" ";255));255*2))			=GAUCHE(SUBSTITUE(A2;" ";"";2); TROUVE("";SUBSTITUE(A2;" ";"*";2);1) -1 )
HE 700 AA		=SUPPRESPACE(STXT(SUBSTITUE(A3;" ";REPT(" ";255));255*1;255))			= STXT(STXT(A3;TROUVE(" ";A3;1)+1;255);1;TROUVE(" "; STXT(A3;TROUVE(" ";A3;1)+1;255);1))

résultat

IPE A 160	IPE A			IPE A
HE 700 AA	700			700

Microsoft 365 Extraire texte cellule Excel

Alyssa_jck

XLDnaute Nouveau

sylvanu

XLDnaute Barbatruc

Pièces jointes

DJunqueira

XLDnaute Occasionnel

Pièces jointes

R@chid

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

Discussions similaires