extraire date et nombre dans une chaine de caractères

[pascal21]

Date:04/10/2010
Machine:380
Kms:
Heures:
Intervenants:
Interventions:
Détails:

bonjour
j'ai colonne C cette série de caractères présentée à la ligne comme celà
j'aimerais colonne A extraire la date
et colonne B extraire le numéro machine, toujours 3 chiffres
j'ai essayé avec =gauche() mais ça me copie le contenu depuis le mot date
merci de votre aide

 

[Tibo]

Re : extraire date et nombre dans une chaine de caractères

Bonjour,

En A2 :

=STXT(C2;6;TROUVE("Machine";C2)-6)

en B2 :

=STXT(C2;25;TROUVE("Kms";C2)-25)

Je te laisse tester

@+

 

[Pierrot93]

Re : extraire date et nombre dans une chaine de caractères

Bonjour Pascal,

et le dernier code proposé ne fonctionne pas ??? pas de code dans ton fichier...

 

[Pierrot93]

Re : extraire date et nombre dans une chaine de caractères

Re,

de toute facon ne fonctionnera pas... toutes les données dasont dans la même cellule... présenté en l'état, pas facile à deviner....

 

[Pierrot93]

Re : extraire date et nombre dans une chaine de caractères

Re, Bonjour Tibo🙂, Aarf désolé t'avais point vu....

une dernière proposition, si j'ai bien compris :

Option Explicit
Sub test()
Dim c As Range, x() As String
For Each c In Range("C2", Range("C65536").End(xlUp))
    x = Split(c.Value, vbLf)
    c.Offset(0, -2) = Split(x(0), ":")(1)
    c.Offset(0, -1) = Split(x(1), ":")(1)
Next c
End Sub

bonne journée
@+

 

[JNP]

Re : extraire date et nombre dans une chaine de caractères

Bonjour le fil 🙂,
2 petites fonctions personnalisées

Function ExtractionDate(Cellule As Range, Valeur As String) As Date
Dim I As Integer, Tableau
Application.Volatile
Tableau = Split(Cellule, Chr(10))
For I = LBound(Tableau) To UBound(Tableau)
If InStr(1, Tableau(I), Valeur) <> 0 Then
ExtractionDate = CDate(Right(Tableau(I), Len(Tableau(I)) - Len(Valeur)))
Exit For
End If
Next I
End Function

et

Function ExtractionN°Machine(Cellule As Range, Valeur As String) As String
Dim I As Integer, Tableau
Application.Volatile
Tableau = Split(Cellule, Chr(10))
For I = LBound(Tableau) To UBound(Tableau)
If InStr(1, Tableau(I), Valeur) <> 0 Then
ExtractionN°Machine = Right(Tableau(I), Len(Tableau(I)) - Len(Valeur))
Exit For
End If
Next I
End Function

avec en A2

=ExtractionDate(C2;"Date:")

et en B2

=ExtractionN°Machine(C2;"Machine:")

à tirer vers le bas.
Bonne journée 😎

 

[pascal21]

Re : extraire date et nombre dans une chaine de caractères

bonjour
je reviens un peu tardivement sur ce fil
merci Jnp c'est tout à fait ce que je cherchais
je ne sais pas d'où tu l'a sort celle là mais c'est nickel
je sens bien que çà va me servir dans d'autres classeurs
merci aussi à Pierrot pour son aide et SA PATIENCE
bonne journée

 

[Staple1600]

Re : extraire date et nombre dans une chaine de caractères

Bonjour à tous

Le souvent oublié fonctionne aussi: 😉
j'ai nommé : Données/Convertir Séparateur :

Et peut-être couplé avec VBA pour ce qui est de la mise en forme.

PS: JNP: pas de regexp sur ce coup-là ? 😉

 

[JNP]

Re : extraire date et nombre dans une chaine de caractères

Re 🙂,

je ne sais pas d'où tu l'a sort celle là

Bonne question 😛...

PS: JNP: pas de regexp sur ce coup-là ? 😉

Pourquoi pas, pour la date, le pattern est simple, mais pour la machine, il faudrait être sûr qu'il n'y ait que des références à 3chiffres 🙄...
Bonne journée 😎

 

[JNP]

Re : extraire date et nombre dans une chaine de caractères

Re 🙂,

Pourquoi pas, pour la date, le pattern est simple, mais pour la machine, il faudrait être sûr qu'il n'y ait que des références à 3chiffres 🙄...

Finalement, dans ce cas de figure le RegExp est une belle alternative 😛...
Avec la fonction

Function Capture(Texte As String, MonPattern As String) As String
Dim mm
Application.Volatile
With CreateObject("vbscript.regexp")
    .Global = False: .IgnoreCase = True: .Pattern = MonPattern & ".+"
    Set mm = .Execute(Texte)
    Capture = Right(mm(0), Len(mm(0)) - Len(MonPattern))
End With
End Function

il suffit de saisir

=Capture(C2;"Date:")

et

=Capture(C2;"Machine:")

pour récupérer les données 😉...
Bonne soirée 😎

 

[Staple1600]

Re : extraire date et nombre dans une chaine de caractères

Bonsoir à tous

JNP:
L'humeur était déjà bonne ... (°)
Elle est désormais excellente 😉

(°): private joke

PS: je ne regrette décidément pas de t'avoir un jour invité à aller voir du côté de RegExp 😉