XL 2021 Export d'un Userform au format Docx;

jeff1494 · Dimanche à 18:02

Bonsoir à toutes et tous;

Je suis en train de me faire une petite boite à outils me permettant d'avoir des informations pour m'aider à monter une sorte de documentation du projet VBE.
Mon idée est de regrouper des informations du projet me permettant de monter une documentation cohérente du projet.

J'ai créé quelques macros pour me fournir des éléments, qui me serviront à créer de la doc, comme par exemple :

Liste de tous les formulaires du projet.
Liste des contrôles par formulaire.
Liste des feuilles avec les attributs "masquée, protégée".
Liste des noms de cellules et tableaux du classeur.

J'aimerai aussi pouvoir créer au format Word '.Docx' une documentation sur les formulaires. Pouvoir insérer dans un fichier ".docx" une capture des formulaires, et ainsi pouvoir documenter chaque contrôle par exemple.

J'ai trouvé une macro créée par @kiki29 il y a déjà un bon moment (Pris dans son récap des possibilités de jouer avec les PDF et Excel dont voici le lien).

Mon problème est qu'il exporte la capture d'écran au format PDF. Cela fonctionne parfaitement, mais je voudrais bien, en fait, sauvegarder la capture comme image dans un fichier Word.
J'ai bien sûr essayer de voir le code et si je pouvais le modifier. Mais le Hic est que Kiki29 a utilisé des concepts que je ne connais pas. Du genre "Const VK_SNAPSHOT = 44" voire " keybd_event VK_LMENU, 0, KEYEVENTF_EXTENDEDKEY, 0" et d'autres.

Donc j'avoue humblement que d'une part j'aimerais bien comprendre ce genre d'instruction (L'aide sur les "Constantes KeyCode" m'a permis de comprendre l'idée générale, mais c'est tout.).

Je vous joins un fichier exemple très simple qui utilise la macro de Kiki29, et qui marche parfaitement bien.
Si une personne charitable pouvait :

M'expliquer le code de kiki29.
M'aider à créer une macro qui ferait le même genre de chose, à savoir:
1. Prendre un "cliché" du formulaire au format Bmp, ou autre (.jpg, ...). Le format n'est une contrainte pour autant qu'il puisse être inclus dans un document.
2. Pouvoir créer un document Word (format .docx) qui contiendrait ce cliché du formulaire. Le doc sera créé dans le répertoire du classeur, et avec le nom du formulaire.

Je vous joins un petit fichier qui m'a permis de tester la macro de kiki29. Il est minimaliste, juste un formulaire avec quelques contrôles bidons, et 3 boutons.
Un pour l'export vers PDF = "CommandButton1", le deuxième "CommandButton2" qui ne sert à rien d'autre que d'exister, et un troisième "CommandButton3" qui me servirait à créer le fameux document Word;

Si une âme charitable pouvait m'aider je lui en serais reconnaissant.
En attendant je vous souhaite à tous une bonne soirée.

patricktoulon · Dimanche à 23:19

bonsoir jeff

VB:

Private Sub CommandButton3_Click()
    PrintScreen
    DoEvents
    Dim wdApp As Object, wdDoc As Object
    ' creation de l'object application word
    Set wdApp = CreateObject("Word.Application")
    wdApp.Visible = True
    ' on créé un document
    Set wdDoc = wdApp.Documents.Add
    ' on colle la capture dans le document
    wdApp.Selection.Paste
    'on centre le tout
    wdApp.Selection.ParagraphFormat.Alignment = 1 ' 0=Left, 1=Center, 2=Right
    ' enregistrement du document
    wdDoc.SaveAs2 Environ("userprofile") & "\desktop\mon userform.docx"
    'on ferme
    wdDoc.Close
    wdApp.Quit
    MsgBox "enregistrement de la capture dans un fichier docw(word) terminé"
End Sub

jeff1494 · Mercredi à 10:09

@job75 : Je vais tester ta solution, dans la journée et te tiendrais au courant. En principe cela devrait fonctionner.

@patricktoulon : Merci pour ces infos. je vais essayer de décortiquer tout cela.

Bonne journée à vous deux.

job75 · Mercredi à 11:45

jeff1494 à dit:
@job75 : Je vais tester ta solution, dans la journée et te tiendrais au courant. En principe cela devrait fonctionner.

D'après le post #45 de Patrick ça ne va pas, alors Patrick essaie :

VB:

Private Sub CommandButton1_Click()
Dim Wapp As Object, Wdoc As Object
 
    Application.ScreenUpdating = False
    PrintScreen
    DoEvents
  
    Set Wapp = CreateObject("Word.Application")
    Wapp.Visible = True
    Set Wdoc = Wapp.Documents.Add
    Wapp.Selection.Range.Text = "Ci-dessous la copie d'écran" & vbCrLf & vbCrLf & "Fin de la copie d'écran" '3 paragraphes
    Wdoc.Paragraphs(2).Range.Select
    Wapp.Selection.Paste
    Do: DoEvents: Loop Until Wdoc.Shapes.Count + Wdoc.InlineShapes.Count > 0 'en attente du collage
    If Wdoc.Shapes.Count Then
        Wdoc.Shapes(1).Left = (Wdoc.PageSetup.PageWidth - Wdoc.Shapes(1).Width) / 2 - Wdoc.PageSetup.LeftMargin 'centrage
        With Wapp.Selection.ParagraphFormat: .SpaceAfter = .SpaceAfter + Wdoc.Shapes(1).Height - .LineSpacing: End With
    ElseIf Wdoc.InlineShapes.Count Then
        Wapp.Selection.ParagraphFormat.Alignment = 1 'centrage avec le texte
    End If
  
    Wdoc.SaveAs ActiveWorkbook.Path & "\UserForm.docx"
    Wdoc.ExportAsFixedFormat ActiveWorkbook.Path & "\UserForm.pdf", 17 'wdExportFormatPDF
    Wdoc.Close False
    Wapp.Quit
    MsgBox "Les fichiers 'UserForm.docx' et 'UserForm.pdf' ont été créés..."
    Unload Me
End Sub

Si ça ne va toujours pas chez toi je te laisse voir pourquoi et corriger car chez moi c'est bon.

patricktoulon · Mercredi à 12:16

de tout ce que j'ai pu constater
si je me contente de faire simple dans les bonne pratiques a savoir simplement demander le centrage du paragrapheformat c'est nickel
des qu'on sort de ce contexte il y a des soucis
ma conclusion:
mieux vaut rester simple

job75 · Mercredi à 12:20

Oui et ma solution demande juste le centrage du paragraphe pour ce qui te concerne, peux-tu la tester ?

patricktoulon · Mercredi à 14:40

je l'ai testé

job75 · Mercredi à 15:02

Peux-tu voir pourquoi l'image n'est pas centrée (alors que je centre le 2ème paragraphe) et pourquoi "Fin de la copie" n'est pas dessous, merci.

job75 · Mercredi à 15:46

Bon je pense avoir résolu le problème : il faut créer au départ 4 paragraphes pour bien fonctionner avec une InlineShape :

VB:

Private Sub CommandButton1_Click()
Dim Wapp As Object, Wdoc As Object
 
    Application.ScreenUpdating = False
    PrintScreen
    DoEvents
    
    Set Wapp = CreateObject("Word.Application")
    Wapp.Visible = True
    Set Wdoc = Wapp.Documents.Add
    Wapp.Selection.Range.Text = "Ci-dessous la copie d'écran" & vbCrLf & vbCrLf & vbCrLf & "Fin de la copie d'écran" '4 paragraphes
    Wdoc.Paragraphs(2).Range.Select
    Wapp.Selection.Paste
    Do: DoEvents: Loop Until Wdoc.Shapes.Count + Wdoc.InlineShapes.Count > 0 'en attente du collage
    If Wdoc.Shapes.Count Then
        Wdoc.Shapes(1).Left = (Wdoc.PageSetup.PageWidth - Wdoc.Shapes(1).Width) / 2 - Wdoc.PageSetup.LeftMargin 'centrage
        With Wapp.Selection.ParagraphFormat: .SpaceAfter = .SpaceAfter + Wdoc.Shapes(1).Height - .LineSpacing: End With
        Wdoc.Paragraphs(3).Range.Delete 'supprime le 3ème paragraphe
    ElseIf Wdoc.InlineShapes.Count Then
        Wapp.Selection.ParagraphFormat.Alignment = 1 'centrage avec le texte
    End If
    
    Wdoc.SaveAs ActiveWorkbook.Path & "\UserForm.docx"
    Wdoc.ExportAsFixedFormat ActiveWorkbook.Path & "\UserForm.pdf", 17 'wdExportFormatPDF
    Wdoc.Close False
    Wapp.Quit
    MsgBox "Les fichiers 'UserForm.docx' et 'UserForm.pdf' ont été créés..."
    Unload Me
End Sub

J'espère que tout le monde a compris que ce code fonctionne quelle que soit l'image, Shape ou InlineShape.

job75 · Mercredi à 17:21

Maintenant en convertissant la Shape (chez moi) en InlineShape c'est plus simple :

VB:

Private Sub CommandButton1_Click()
Dim Wapp As Object, Wdoc As Object
 
    Application.ScreenUpdating = False
    PrintScreen
    DoEvents
    
    Set Wapp = CreateObject("Word.Application")
    Wapp.Visible = True
    Set Wdoc = Wapp.Documents.Add
    Wapp.Selection.Range.Text = "Ci-dessous la copie d'écran" & vbCrLf & vbCrLf & vbCrLf & "Fin de la copie d'écran" '4 paragraphes
    Wdoc.Paragraphs(2).Range.Select
    Wapp.Selection.Paste
    Do: DoEvents: Loop Until Wdoc.Shapes.Count + Wdoc.InlineShapes.Count > 0 'en attente du collage
    If Wdoc.Shapes.Count Then Wdoc.Shapes(1).ConvertToInlineShape: Wdoc.Paragraphs(3).Range.Delete
    Wapp.Selection.ParagraphFormat.Alignment = 1 'centrage avec le texte
    
    Wdoc.SaveAs ActiveWorkbook.Path & "\UserForm.docx"
    Wdoc.ExportAsFixedFormat ActiveWorkbook.Path & "\UserForm.pdf", 17 'wdExportFormatPDF
    Wdoc.Close False
    Wapp.Quit
    MsgBox "Les fichiers 'UserForm.docx' et 'UserForm.pdf' ont été créés..."
    Unload Me
End Sub

jeff1494 · Mercredi à 18:01

@job75 : Je viens de tester ton dernier code et il fonctionne parfaitement chez moi.
Merci pour ton aide.
Bonne soirée.

patricktoulon · Mercredi à 18:46

test post #52
maintenant tout est centré et enfait ca rempli tout entre les marges droite et gauche

Test post #53
pareil tout est centré mais ajuster aux marges en fait

patricktoulon · Mercredi à 18:52

test du post#53 en reduisant le userform de largeur et hauteur
la on voit que ca centre

et en elargissant on se rend compte que la capture est adaptée a la largeur max

le post #53 est donc un bon compromis entre version simple et complexe

patricktoulon · Mercredi à 18:55

donc pour faire un travail parfait il faudrait redimentionner legerement l'object (shapes ou inlineshape) légerement inferieur au width du page setup pour avoir un effet de centrage par rapport au texte

patricktoulon · Mercredi à 19:01

a d'accords je comprends mieux
tu es revenu au centrage du paragraphe simple en convertissant pour vous le shape en inline shape

VB:

 Do: DoEvents: Loop Until Wdoc.Shapes.Count + Wdoc.InlineShapes.Count > 0 'en attente du collage
    If Wdoc.Shapes.Count Then Wdoc.Shapes(1).ConvertToInlineShape: Wdoc.Paragraphs(3).Range.Delete
    Wapp.Selection.ParagraphFormat.Alignment = 1 'centrage avec le texte

j'avais donc raison depuis le debut c'est bien le paragraphe alignement c'est juste que sur vos versions vous avez accès a la collection shapes et moi non

job75 · Mercredi à 19:24

patricktoulon à dit:
j'avais donc raison depuis le debut

Bien sûr et moi aussi, le paragraphe alignement fonctionne sur les InlineShapes parce qu'elles sont traitées comme des textes.

patricktoulon · Mercredi à 19:41

donc maintenant que le paragraphe alignement fonctionne chez toi
EN CONVERTISSANT EN INLINESHAPE
on peut revenir a mon point de depart
qui etait d'ajouter un paragraphe a chaque ajout texte ou capture
on a ainsi la parfaite maitrise progressive de la construction du document plutot que de shunter des saut de ligne arbitraire
donc on reviens au depart avec :

VB:

Private Sub CommandButton1_Click()
    PrintScreen
    DoEvents
    Dim wApp As Object, wDoc As Object
    ' creation de l'object application word
    Set wApp = CreateObject("Word.Application")
    wApp.Visible = True
    ' on créé un document
    Set wDoc = wApp.Documents.Add
    'on ecrit le texte avant
    wApp.Selection.TypeText "Voici la capture d'écran :" & vbCrLf
    ' on colle la capture dans le document
    wApp.Selection.Paste
    'on centre le shape
    Do: DoEvents: Loop Until wDoc.Shapes.Count + wDoc.InlineShapes.Count > 0 'en attente du collage
    If wDoc.Shapes.Count Then wDoc.Shapes(1).ConvertToInlineShape: wDoc.Paragraphs(3).Range.Delete
    wApp.Selection.ParagraphFormat.Alignment = 1 'centrage avec le texte
    'on ecrit du texte appres
    wApp.Selection.TypeParagraph
    wApp.Selection.ParagraphFormat.Alignment = 0 ' 0=Left, 1=Center, 2=Right
    wApp.Selection.TypeText "Fin de la capture." & vbCrLf
    ' enregistrement du document
    wDoc.SaveAs2 Environ("userprofile") & "\desktop\mon userform.docx"
    'on ferme
    wDoc.Close
    wApp.Quit
    MsgBox "enregistrement de la capture dans un fichier docx (word) terminé"
End Sub

XL 2021 Export d'un Userform au format Docx;

jeff1494

XLDnaute Occasionnel

Pièces jointes

patricktoulon

jeff1494

XLDnaute Occasionnel

job75

XLDnaute Barbatruc

Pièces jointes

patricktoulon

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

Pièces jointes

job75

XLDnaute Barbatruc

Pièces jointes

jeff1494

XLDnaute Occasionnel

patricktoulon

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

Discussions similaires

XL 2021 Export d'un Userform au format Docx;

XLDnaute Occasionnel

Pièces jointes

XLDnaute Occasionnel

XLDnaute Barbatruc

Pièces jointes

XLDnaute Barbatruc

XLDnaute Barbatruc

XLDnaute Barbatruc

XLDnaute Barbatruc

XLDnaute Barbatruc

Pièces jointes

XLDnaute Barbatruc

Pièces jointes

XLDnaute Occasionnel

XLDnaute Barbatruc

XLDnaute Barbatruc

XLDnaute Barbatruc

XLDnaute Barbatruc

XLDnaute Barbatruc

XLDnaute Barbatruc

Discussions similaires

Privacy & Transparency

Privacy & Transparency