Dénombré les doublons

[Harold]

Bonjour à tous,

Voilà, j'ai une formule qui me dit s'il y a des doublons sur une plage
(=SI(MAX(NB.SI(B2:B1000;B2:B1000))>1;"Il y a des doublons";"Il n'y a pas des doublons")-Formule matricielle), mais je n'arrive pas à la modifier ou en créé une pour me donner le nombre de doublons dans la plage donnée
pourriez vous m'aider SVP
Merci d'avance

 

[CB60]

Re : Dénombré les doublons

Bonsoir
Dans ton fichier MJ13 tu peux ajouter celui de Monique et Celeda

 

[MJ13]

Re : Dénombré les doublons

Bonjour Bruno

Merci pour le fichier des "maîtres" Formulistes Monique et Celeda.
Puisque tu l'as mis, c'est très bien.
De plus il peut servir pour ceux qui veulent aller plus loin dans les formules.

Par contre il ne faut pas oublié les filtres élaborés qui peuvent être assez simple à mettre en oeuvre pour par exemple extaire les données sans doublons. Pour cela aller dans les menus:
\Données
\Filtrer
\FIltres élaborés

 

[Fabienc75]

Re : Dénombré les doublons

Bonjour à tout le forum,

j'ai un souci pour dénombrer des doublons dans une colonne qui n'est pas fixe, tous les jours des lignes s'ajoutent dans cette colonne et donc je ne peux pas appliquer une formule que je dois modifier à chaque fois que j'ai une ligne supplémentaire. J'ai essayé la formule suivante mais elle ne fonctionne pas et je ne comprends pas pourquoi (j'ai une version d'excel de 2002), j'ai prise cette formule sur le forum qui était citée comme étant une formule dynamique sans avoir besoin de la changer à chaque ajout de ligne. Même après validation par CTRL + ALT + ENTREE le résultat est faux.

Quelqu'un peut il m'aider svp.

Merci à tous par avance.

=SOMME((FREQUENCE(SI(NB.SI($A$18:$A$1000;$A$18:$A$1000)>1;EQUIV($A$18:$A$1000;$A$18:$A$1000;0));LIGNE($A$18:$A$1000))>0)*1)

 

[JeanMarie]

Re : Dénombré les doublons

Bonjour tout le monde

La formule que tu indiques n'est pas une formule dynamique.

Pour suivre l'évolution de tes données, tu dois définir une plage dynamique.
1) Clique sur le menu Insertion/Nom/Définir...
2) Dans la boîte de dialogue, dans le champ du haut indique un nom (exemple : Plage)
3) Dans le champ "fait référence à :" c'est à cet endroit que l'on va définir la plage dynamique, par une formule

=DECALER($A$18;;;MAX(1;NBVAL($A$:$A$65536)))

4) Clique sur le bouton AJOUTER
5) Change le nom dans le champ du Haut (exemple : PlageLigne)
6) Indique la formule suivante

=DECALER($A$1;;;LIGNES(Plage))

7) Clique sur le bouton OK

La formule dans la cellule devient
=SOMME((FREQUENCE(EQUIV(Plage;Plage;0);LIGNE(PlageLigne))>1)*1)

@+Jean-Marie

 

[Fabienc75]

Re : Dénombré les doublons

Bonjour Jean Marie,

Merci pour cette réponse précise, autant pour moi, j'avais du mal comprendre l'interprétation de cette formule.
Par contre, maintenant je l'ai adaptée à mon tableau, mais il y a encore qq chose qui m'embête car dans mon tableau j'ai des doublons mais parfois je n'en ai pas et par conséquent quand j'ai une ligne sans doublons elle n'est pas compter vu que cette formule ne compte que les doublons.
Comment faire pour mêler les doublons et les sans doublons de façon à ce que si j'ai dans mon tableau 3 lignes avec A, 2 lignes avec B et 1 ligne avec C qu'il me compte 3 en résultat et non simplement 2.

Merci de votre aide à nouveau

 

[JeanMarie]

Re : Dénombré les doublons

Re...

Il suffit de changer la valeur du comparateur

=SOMME((FREQUENCE(EQUIV(Plage;Plage;0);LIGNE(Plage Ligne))>[B]0[/B])*1)

@+Jean-Marie

 

[Fabienc75]

Re : Dénombré les doublons

Re,

Ben oui évidemment, je n'avais pas du tout pensé à cela.
Un grand merci à toi Jean Marie pour m'avoir aiguillé sur la bonne voie, ca marche nickel, c'est exactement ce que je voulais.

Cordialement.