Croiser deux tableaux

[Dadawha]

Bonjour à tous,

Je voudrais croiser deux tableaux pour n'en faire qu'un.
Le mieux est de vosu mettre un exemple.
en feuill1 mon premier tableau
en feuill 2 mon deuxieme tableau
en feuill3 le resultat recherché

Cela ne doit pas etre compliqué je n'ai pas trouvé sur google ou le forum ne sachant pas comment appeller cette manip'

Merci à tous.

Un lecteur fidèle qui va de plus en plus loin avec Excel

 

[Dadawha]

Re : Croiser deux tableaux

Ne seerait-ce pas encore possible avec la formule INDIRECT que je ne gère pas encore tout à fait....

 

[Dadawha]

Re : Croiser deux tableaux

Bon je continue à chercher....La fonction recherchev m'a fait un peu avancer
et maintenant je sais formuler ce que je veux:
Je cherche à regrouper deux tableaux ayant une colonne commune et un nombre de lignes différents dans un seul !

Une solution ?Je continue à chercher activement

 

[Dadawha]

Re : Croiser deux tableaux

Bon je sais ma demande n'est pas passsionante mais cela fait déjà 2h que je recherche des solutions et toujours pas....Je pense aussi qu'elle a déjà été traité plus d'une fois et ca je m'en excuse....vu que je ne gère pas bien tous les parametres je n'arrive pas à adapter les réponses que je trouve.....si quelqu'un m'aiderait je lui en serais extremement reconaissant !! (en formule de préf)

Gloups je suis un peu exigeant, un peu relou à ecrire 10 msg mais je suiis surtout dans le besoin

milles esxcuses

 

[Tibo]

Re : Croiser deux tableaux

Bonjour,

Le problème, malgré son apparente simplicité, n'est pas si facile que ça à traiter.

Il faut donc un peu de patience.

De plus, on ne sait si le fichier que tu nous as mis est représentatif de ton vrai fichier pas.

Sur la base du fichier que tu as joint, une formule valable pour 2 tableaux :

Feuil3 en B2 :

=SI(SOMMEPROD((Feuil1!$B$1:$C$1=Feuil3!B$1)*(Feuil1!$A$2:$A$6=Feuil3!$A2))=1;
INDEX(Feuil1!$B$2:$C$6;EQUIV(Feuil3!$A2;Feuil1!$A$2:$A$6;0);EQUIV(Feuil3!B$1;
Feuil1!$B$1:$C$1;0));SI(SOMMEPROD((Feuil2!$B$1:$C$1=Feuil3!B$1)*
(Feuil2!$A$2:$A$4=Feuil3!$A2))=1;INDEX(Feuil2!$B$2:$C$4;EQUIV(Feuil3!$A2;
Feuil2!$A$2:$A$4;0);EQUIV(Feuil3!B$1;Feuil2!$B$1:$C$1;0));""))

Formule à recopier vers la droite et vers le bas.

Je te laisse tester

@+

 

[Dadawha]

Re : Croiser deux tableaux

Merci je regarde ça ! Desolé pour l'impatience

Effectivement à première vue c'est la bonne solution mais pas forcément adaptable à mon fichier car j'ai bien plus de colonnes et de lignes que ceux que j'ai mis dans l'exemple....

 

[Tibo]

Re : Croiser deux tableaux

re,

Pour adapter, il faut regarder dans la formule les plages des Feuil1 et Feuil2

Adapter le :

Feuil1!$B$1:$C$1
Feuil1!$A$2:$A$6
Feuil1!$B$2:$C$6

Idem pour les plages de la Feuil2

On peut envisager de nommer ces plages de cellules avec la fonction DECALER dans l'hypothèse où tes tableaux seraient de taille variable.

@+

 

[Dadawha]

Re : Croiser deux tableaux

Pour l'instant je n'arrive pas a adapter la formule j'ai des #N/A partout....

 

[Tibo]

Re : Croiser deux tableaux

re,

Dans ce cas, rejoins nous un fichier plus représentatif de ton vrai fichier (sans données confidentielles).

@+

 

[Dadawha]

Re : Croiser deux tableaux

Non vraiment je n'y arrive pas...

Si ça peut aider j'ai donc en feuille 1:
- Une ligne 1 avec les intitulés des colonnes
- Des colonnes allant jusqu'à P dont une seule colonne A identique à la feuille 2
- 296 lignes en tout

en feuille 2
- Une ligne 1 avec les intitulés des colonnes
- Des colonnes allant jusqu'à C : 3 colonnes dont une seule colonne A identique à la feuille 1
- 284 lignes en tout

 

[Dadawha]

Re : Croiser deux tableaux

Voila en Pj un fichier plus représentatif j'ai supprimé les données de tout le tableau sauf ma première colonne pour garder la confidentialité des infos

 

[JHA]

Re : Croiser deux tableaux

Bonjour Dadawha, le forum,

Ci joint un exemple du forum pour la recherche des numéros de la colonne A et la formule de Tibo.

Si cela peut t'aider

JHA

 

[Tibo]

Re : Croiser deux tableaux

re,

En rajoutant une feuille 3 avec en 1ère lignes les mêmes intitulés

en B2 :

=SI(SOMMEPROD((Feuil1!$B$1:$P$1=Feuil3!B$1)*(DECALER(Feuil1!$A$2;0;0;
NBVAL(Feuil1!$A:$A)-1)=Feuil3!$A2))=1;INDEX(DECALER(Feuil1!$B$2;0;0;
NBVAL(Feuil1!$A:$A)-1;15);EQUIV(Feuil3!$A2;DECALER(Feuil1!$A$2;0;0;
NBVAL(Feuil1!$A:$A));0);EQUIV(Feuil3!B$1;Feuil1!$B$1:$P$1;0));SI(SOMMEPROD((
Feuil2!$B$1:$C$1=Feuil3!B$1)*(DECALER(Feuil2!$A$2;0;0;NBVAL(Feuil2!$A:$A)-1)=
Feuil3!$A2))=1;
INDEX(DECALER(Feuil2!$B$2;0;0;NBVAL(Feuil2!$A:$A)-1;2);EQUIV(Feuil3!$A2;DECALER(
Feuil2!$A$2;0;0;NBVAL(Feuil2!$A:$A)-1);0);EQUIV(Feuil3!B$1;Feuil2!$B$1:$C$1
;0));""))

à recopier vers la droite et vers le bas

J'ai utilisé la fonction DECALER qui permet ainsi de gérer l'ajout d'identifiants.

Attention : cette formule étant basée sur la fonction SOMMEPROD (fonction matricielle), le temps de calcul est sensiblement important compte tenu de la taille de ton fichier.

Je joins le fichier (je n'ai pas recopié la formule partout because sinon taille fichier).

@+

Edit : Bing ! Salut JHA, t'avais pas vu passer 🙂

@+

 

[Dadawha]

Re : Croiser deux tableaux

Enorme !

un grand grand merci à toi Tibo pour une longue longue formule qui marche du tonnerre !!
Respect à vous tous !