Sub MàJ_MFC_Feuille_Tableau()
Const Gris = 11184814, Orange = 49407, Bleu = 12611584
'Nouvelle plage d'application des formats conditionnels
Dim Rg As Range
With Sh_Tableau.[L_1#]
Set Rg = .Offset(-1, -1).Resize(.Rows.Count + 1, .Columns.Count + 1)
End With
'Suppression des anciens formats conditionnels
Sh_Tableau.Cells.FormatConditions.Delete
'Recréer les formats conditionnels
'Cellules grises horizontales
With Rg.FormatConditions.Add(Type:=xlExpression, Formula1:="=MOD(LIGNE()-LIGNE(L_1);13)=12")
.Interior.Color = Gris
.StopIfTrue = False
End With
'Cellules grises verticales
With Rg.FormatConditions.Add(Type:=xlExpression, Formula1:="=(MOD(COLONNE()-COLONNE(L_1);4)=3)*((COLONNE()<COLONNE(L_1))+(COLONNE()=(COLONNE(L_1)+COLONNES(L_1#)-1)))")
.Interior.Color = Gris
.StopIfTrue = False
End With
'Fond orange, texte bleu, gras pour le nom des équipes
With Rg.FormatConditions.Add(Type:=xlExpression, Formula1:="=(MOD(LIGNE()-LIGNE(L_1);13)=0)*(MOD(COLONNE()-COLONNE(L_1);4)<>3)*(DECALER(B3;0;1-MOD(COLONNE()-COLONNE(L_1);4);1;1)<>"""")")
.Interior.Color = Orange
.Font.Color = Bleu
.Font.Bold = True
.StopIfTrue = False
End With
'Trait horizontal supérieur
With Rg.FormatConditions.Add(Type:=xlExpression, Formula1:="=(MOD(LIGNE()-LIGNE(L_1);13)=1)*(MOD(COLONNE()-COLONNE(L_1);4)<>3)*(B3<>"""")")
.Borders(xlTop).LineStyle = xlContinuous
.StopIfTrue = False
End With
'Trait vertical Gauche
With Rg.FormatConditions.Add(Type:=xlExpression, Formula1:="=(MOD(COLONNE()-COLONNE(L_1);4)=0)*(B3<>"""")")
.Borders(xlLeft).LineStyle = xlContinuous
.StopIfTrue = False
End With
'Trait vertical droit
With Rg.FormatConditions.Add(Type:=xlExpression, Formula1:="=(MOD(COLONNE()-COLONNE(L_1);4)=2)*(B3<>"""")")
.Borders(xlRight).LineStyle = xlContinuous
.StopIfTrue = False
End With
'Trait horizontal inférieur
With Rg.FormatConditions.Add(Type:=xlExpression, Formula1:="=(B3<>"""")*(B4="""")")
.Borders(xlBottom).LineStyle = xlContinuous
.StopIfTrue = False
End With
End Sub