XL 2016 Création d'un fichier excel à partir d'un bouton

[Utilisateur_X]

Bonjour à tous

Je sollicite votre aide pour trouver une solution à mon problème. J'ai un fichier " Impr.Avancement CTP" qui comporte une extraction de notre base de donnée. Chaque semaine j'imprime ce tableau par "CTP" selon la sélection de liste déroulante que j'ai créé. Certaine personne aimerais l'avoir en version papier et d'autre en version excel.Je veux rajouter un bouton "Export Excel" en dessous de "Imprimer" qui copie le contenu du tableau entier "section => remarques" et créé un nouveau fichier avec ce tableau.
Ce nouveaux fichier doit comporter les même entête de tableau ainsi que les même MFC (si possible)

le contenu du tableau varie selon la selection de la liste déroulante déjà existante donc il n'a pas de taille fixe

J'ai une formule filtre en B4 et quelques MFC.

Je vous joint le fichier.

Encore merci pour votre aide

 

[AtTheOne]

Bonjour à toutes & à tous, bonjour @Utilisateur_X
D'abord la base mise sous forme de Tableau Structuré (TS_BdD)
Une petite macro avec les CodeName des feuilles modifiés :

et les deux boutons nommés (Btn_Imprimer et Btn_Exporter) :

Sub exporter()
     Sh_Extraction.Copy
     With ActiveSheet
          .UsedRange.Cells.Value = .UsedRange.Cells.Value
          .Shapes("Btn_Imprimer").Delete
          .Shapes("Btn_Exporter").Delete
          .[A1:A2].Validation.Delete
          .Parent.Names("CTP_list").Delete
     End With
End Sub

Voir Fichier joint
À bientôt

 

[fanfan38]

Bonjour
Ci joint ma solution

A+ François

 

[Utilisateur_X]

Bonjour

Merci à vous

C'est parfait !!

 

[AtTheOne]

Re, et bonjour @fanfan38

Ci joint ma solution

Juste une petite remarque @fanfan38, en ne faisant qu'une simple copie tu embarques des liaisons vers le fichier "Père".
Mais ce n'est peut-être pas gênant 😉

À Bientôt

 

[Utilisateur_X]

Excusez moi de vous demander une petite requête de nouveau .
Est il possible de faire un tri de A à Z sur la colonne H (N° d'affaire) quand le nouveau fichier est généré ?

Encore merci : Le fichier est impécable

 

[AtTheOne]

Bonjour à toutes & à tous, bonjour @Utilisateur_X

Est il possible de faire un tri de A à Z sur la colonne H (N° d'affaire) quand le nouveau fichier est généré ?

Voilà c'est fait :
Code :

Sub Exporter()
     
     Dim RgExtraction As Range, DerLgn As Long
     Application.ScreenUpdating = False
     
     'Copie de la feuille Extraction vers un nouveau classeur
     Sh_Extraction.Copy
     
     With ActiveSheet
     
          'Effacement des formules
          .UsedRange.Cells.Value = .UsedRange.Cells.Value
          'Effacement des boutons
          .Shapes("Btn_Imprimer").Delete
          .Shapes("Btn_Exporter").Delete
          'Effacement des validations de données
          .[A1:A2].Validation.Delete
          'Effacement du nom défini servant pour les validations de données
          .Parent.Names("CTP_list").Delete
          
          'Tri du tableau extrait
          DerLgn = .Cells(.Rows.Count, 2).End(xlUp).Row
          Set RgExtraction = Range(.Cells(3, 2), .Cells(DerLgn, 12))
          With .Sort
               .SortFields.Clear
               .SortFields.Add2 Key:=RgExtraction.Columns(7), SortOn:=xlSortOnValues, Order:=xlAscending
               .SetRange RgExtraction
               .Header = xlYes
               .Apply
          End With
          
          'Aller sur le tableau extrait
          Application.Goto .[A1], Scroll:=True  '(haut de la feuille)
          ActiveWindow.Zoom = 80
          Application.Goto RgExtraction         '(tableau extrait)
               
     End With
     
     Application.ScreenUpdating = True
     
End Sub

Voir fichier Joint
À bienôt

 

[Utilisateur_X]

Parfait

Merci énormément