XL 2021 copier en B7 la valeur de la cellule active (Cells(ActiveCell.Row, 7)) de la feuille "Appels"

[Usine à gaz]

Bonjour à toutes et à tous 🙂

Le titre dit tout mon besoin (enfin, je pense).
Formule ou vba je n'y arrive pas.

Voudriez-vous m'aider ?

Grand merci à toutes et à tous
Je joins le petit fichier test et je continue mes recherches...
🙂

 

[sylvanu]

Bonjour Lionel,
Peut être avec dans feuille Appels :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Target.Count > 1 Then Exit Sub
    Sheets("Mon besoin").[B7] = Target
End Sub
Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count > 1 Then Exit Sub
    Sheets("Mon besoin").[B7] = Target
End Sub

Le premier cas si on clique sur une cellule.
Le second cas si on modifie une valeur.

 

[job75]

Bonjour Lionel, sylvanu,

Place dans le code de la feuille Appels :

Private Sub Worksheet_Deactivate()
Dim F As Object
Set F = ActiveSheet
Application.ScreenUpdating = False
Application.EnableEvents = False
Me.Activate
Sheets("Mon besoin").[B7] = Cells(ActiveCell.Row, 7)
F.Activate
Application.EnableEvents = True
End Sub

A+

 

[Usine à gaz]

Bjr sylvanu 🙂, Bjr Gérard 🙂,

Un grand merci pour vos retours 🙂
@sylvanu
Ton code m'intéresse, je te remercie, et je le conserve pour un autre besoin 🙂

@Gérard
Ton code correspond mieux à mon présent besoin.
Merci Gérard 🙂

LOL, voilà le fil le plus court de "ma carrière d'usine à gaz" 😉
Quoique... 🙂

EZncore merci à vous deux 🙂

 

[job75]

Evidemment si l'on ne va jamais sur la feuille Appels la cellule B7 ne se remplira pas.

On peut alors ajouter ce code dans ThisWorkbook :

Private Sub Workbook_Open()
Dim F As Object
Set F = ActiveSheet
Application.ScreenUpdating = False
Sheets("Appels").Activate
F.Activate
End Sub

 

[Usine à gaz]

Merci gérard 🙂
Mais lol :
En fait, je n'avais pas donné tout le contexte car je pensais qu'un code dans la feuille "Mon besoin" pourrait s'exécuter à la sélection de la feuille.

Le but du code est de récupérer (à l'activation de la feuille "Mon besoin") et en B7 la valeur de la cellule active (Cells(ActiveCell.Row, 7)) de la feuille "Appels"

si on reste sur le code de Gérard, il suffirait d'ajouter la condition que le code ne s'exécute qu'uniquement si c'est la feuille "Mon besoin" qui est activée (donc ne s'exécute pas si une autre feuille est activée).

Code dans la feuille "Appels"

Private Sub Worksheet_Deactivate()
[B][U]condition : le code s'exécute uniquement si la feuille "Mon besoin" est activée[/U][/B]
Dim F As Object
Set F = ActiveSheet
Application.ScreenUpdating = False
Application.EnableEvents = False
Me.Activate
Sheets("Mon besoin").[B7] = Cells(ActiveCell.Row, 7)
F.Activate
Application.EnableEvents = True
End Sub

Je remets le fichier avec des onglets en + et j'essaie de voir comment coder la condition.
🙂

 

[sylvanu]

Re,

voilà le fil le plus court de "ma carrière d'usine à gaz"

Ca m'étonnais aussi ! 😂

Un essai en PJ avec :
Module standard :

Public AppelsActiveCell

Feuille Appels :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Target.Count > 1 Then Exit Sub
    AppelsActiveCell = Cells(ActiveCell.Row, 7)
End Sub
Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count > 1 Then Exit Sub
    AppelsActiveCell = Cells(ActiveCell.Row, 7)
End Sub

Feuille Besoin :

Sub Worksheet_Activate()
    [B7] = AppelsActiveCell
End Sub

 

[Usine à gaz]

bsr sylvanu 🙂
Ca m'étonnais aussi ! 😂 et moi donc lol

Nickel tout bien, merci à toi.

c'est fini ...... Peut-être lol 🤪
🙂

 

[job75]

Bonsoir Lionel, sylvanu,

Utiliser ici une variable Public n'est pas une bonne idée.

Placez plutôt cette macro dans le code de la feuille "Mon besoin" :

Private Sub Worksheet_Activate()
Application.ScreenUpdating = False
Application.EnableEvents = False
With Sheets("Appels")
    .Activate
    [B7] = .Cells(ActiveCell.Row, 7)
End With
Me.Activate
Application.EnableEvents = True
End Sub

Elle se déclenche quand on active la feuille.

A+

 

[sylvanu]

Bonsoir Lionel, Job,

Utiliser ici une variable Public n'est pas une bonne idée.

Job, pour quelle raison ?

 

[Usine à gaz]

Bonjour Gérard 🙂, Bonjour sylvanu 🙂

Merci Gérard pour ce nouveau code qui me convient encore mieux 🙂

Mais OUI dis-donc pourquoi variable Public n'est pas une bonne idée ? sgrognieugnieu !😇
🙂

 

[job75]

Bonjour Lionel, sylvanu,

Mais OUI dis-donc pourquoi variable Public n'est pas une bonne idée ? sgrognieugnieu !😇🙂

Etant sur la feuille "Appels" enregistrez et fermez le fichier, cela réinitialise la variable Public.

Puis rouvrez le fichier, ne modifiez pas la sélection et allez sur la feuille "Mon besoin"...

A+

 

[Usine à gaz]

Re-Gérard 🙂
Waouu ! en voilà une réponse qu'elle est bonne et bonne à connaître.
Merci gérard 🙂