Convertir Hexadecimal en decimal

[thomasv]

Bonjour,

Je cherche à convertir un champ en Hexadecimal en decimal: "04859D7ABF2980"
J'ai cherché un peu avant d'en venir à créer un post, toutefois la particularité est qu'il est établi sur 14 caractères ( c'est pas commode apparemment).


D'avance merci pour votre aide !


NB: Je suis complétement novice dans l'utilisation d'excel ;-)

 

[ROGER2327]

Re : Convertir Hexadecimal en decimal

Bonjour thomasv.

Si vos données sont toujours bien formatées sur quatorze caractères :​

=HEXDEC(GAUCHE(A1;7))*268435456+HEXDEC(DROITE(A1;7))

Si les zéros non significatifs peuvent être omis :​

=HEXDEC(GAUCHE(DROITE(REPT(0;13)&A1;14);7))*268435456+HEXDEC(DROITE(A1;7))

Bonne soirée.


ℝOGER2327
#7066

Jeudi 19 Sable 141 (Gravidité de Mère Ubu - fête Suprême Tierce)
29 Frimaire An CCXXII, 6,4577h - olive
2013-W51-4T15:29:55Z

 

[thomasv]

Re : Convertir Hexadecimal en decimal

Bonjour et merci pour votre réponse.
Cela fonctionne excepté pour le dernier caractère. Celui-ci n'est pas correct du à un arrondi ? Quel format de cellule dois-je sélectionner ?

 

[ROGER2327]

Re : Convertir Hexadecimal en decimal

Re...

Bonjour et merci pour votre réponse.
Cela fonctionne excepté pour le dernier caractère. Celui-ci n'est pas correct du à un arrondi ? Quel format de cellule dois-je sélectionner ?

Merci de fournir des exemples de données posant problème. (Un petit classeur fera l'affaire.)


ℝOGER2327
#7067

Jeudi 19 Sable 141 (Gravidité de Mère Ubu - fête Suprême Tierce)
29 Frimaire An CCXXII, 6,6855h - olive
2013-W51-4T16:02:43Z

 

[thomasv]

Re : Convertir Hexadecimal en decimal

Le voici, merci de votre aide.

 

[ROGER2327]

Re : Convertir Hexadecimal en decimal

Re...

Effectivement, j'ai oublié qu'Excel ne digère pas bien les nombres de plus de quinze chiffres. Il va falloir sortir les résultats sous forme de chaînes de caractères, et ça va compliquer !
Peut-on envisager une fonction personnalisée écrite en VBA ?​

ℝOGER2327
#7069

Jeudi 19 Sable 141 (Gravidité de Mère Ubu - fête Suprême Tierce)
29 Frimaire An CCXXII, 7,1346h - olive
2013-W51-4T17:07:23Z

 

[thomasv]

Re : Convertir Hexadecimal en decimal

VBA? qu'es ce que c'est ?
Si il n'y a pas d'autres solutions je suis pret...

 

[ROGER2327]

Re : Convertir Hexadecimal en decimal

Suite...

VBA? qu'es ce que c'est ?
(...)

Il va falloir taper dans le dur ! Mais vous trouverez des réponses sur ce site.

En deux mots, Visual Basic pour Application (VBA pour les intimes) est le langage de programmation concocté par Microsoft pour étendre les possibilités de ses applications. Il permet par exemple d'écrire des fonctions personnalisées pour compléter les fonctions natives d'Excel.​

(...)
Si il n'y a pas d'autres solutions je suis pret...

Il est certainement possible de bricoler une formule complexe (je n'en ai pas sous la main). En attendant que quelqu'un s'y colle, et pour faire vite, je vous propose une fonction personnalisée nommée HEX14_DEC (pour conversion d'un hexadécimal (de quatorze chiffres au plus) en décimal : vous la verrez à l’œuvre dans la colonne J de l'onglet Essai du classeur joint.

Pour l'écrire, j'ai réutilisé deux autres fonctions développées dans une autre discussion. Ces fonctions, nommées LONGPRODUIT et LONGUESOMME permettent respectivement de calculer le produit et la somme de deux entiers à nombre quelconque de chiffres et de renvoyer le résultat sous forme de chaînes de caractères.
Ce sont des marteaux-pilons pour écraser une mouche, mais ça à l'air de fonctionner...
(On pourrait faire plus simple, mais je n'ai pas le temps immédiatement : c'est pourquoi je recycle un travail antérieur.)
​

Bonne journée.


ℝOGER2327
#7070

Vendredi 20 Sable 141 (Saint Sabre, allopathe - fête Suprême Quarte)
30 Frimaire An CCXXII, 0,6536h - pelle
2013-W51-5T01:34:08Z

 

[ROGER2327]

Re : Convertir Hexadecimal en decimal

Bonjour à tous.

Bonjour thomasv.

Pas de nouvelle, bonne nouvelle...


Bien que je me demande si ça en vaut vraiment la peine, j'ai repris le truc lourdingue proposé ci-dessus.
Donc, code très-simplifié dans le classeur joint, plus une formule Excel un peu lourde :​

=SI([@V]="";"";
DROITE("00000000"&((
ENT(HEXDEC(GAUCHE(DROITE("0000000000000"&[@V];14);7))/10000)*26843+ENT((
ENT(HEXDEC(GAUCHE(DROITE("0000000000000"&[@V];14);7))/10000)*5456+
MOD(HEXDEC(GAUCHE(DROITE("0000000000000"&[@V];14);7));10000)*26843+ENT((
MOD(HEXDEC(GAUCHE(DROITE("0000000000000"&[@V];14);7));10000)*5456
                          +HEXDEC(DROITE([@V];7)))/10000))/10000))&DROITE("0000"&(
ENT(HEXDEC(GAUCHE(DROITE("0000000000000"&[@V];14);7))/10000)*5456+
MOD(HEXDEC(GAUCHE(DROITE("0000000000000"&[@V];14);7));10000)*26843+ENT((
MOD(HEXDEC(GAUCHE(DROITE("0000000000000"&[@V];14);7));10000)*5456
                          +HEXDEC(DROITE([@V];7)))/10000));4)&DROITE("0000"&(
MOD(HEXDEC(GAUCHE(DROITE("0000000000000"&[@V];14);7));10000)*5456
                          +HEXDEC(DROITE([@V];7)));4));17))

ℝOGER2327
#7109

Mercredi 18 Décervelage 141 (Saints Pirates et Flibustiers, thaumathurges - fête Suprême Quarte)
26 Nivôse An CCXXII, 6,3610h - étain
2014-W03-3T15:15:59Z

 

[thomasv]

Re : Convertir Hexadecimal en decimal

PA-RFAIT !

Merci beaucoup