Microsoft 365 Compter le nombre de date par trimestre

[Tartanpions]

Bonsoir,
Par formule uniquement, je souhaiterai compter le nombre de dates de la colonne A, ça je sais faire, par trimestre
- les dates sont dans la colonne A
- je voudrais que les cellules B1, B2, B3 et B4 par exemple donnent le nombre d'occurences des dates par trimestre comme 1er trimestre en B1, 2eme trimestre en B2 et ainsi de suite
Merci de votre aide

 

[TooFatBoy]

Bonjour,

Une proposition :

=SOMMEPROD((DATEVAL("1/1/23")<=A$2:A$100)*(A$2:A$100<DATEVAL("1/4/23")))
=SOMMEPROD((DATEVAL("1/4/23")<=A$2:A$100)*(A$2:A$100<DATEVAL("1/7/23")))
=SOMMEPROD((DATEVAL("1/7/23")<=A$2:A$100)*(A$2:A$100<DATEVAL("1/10/23")))
=SOMMEPROD((DATEVAL("1/10/23")<=A$2:A$100)*(A$2:A$100<DATEVAL("1/1/24")))

 

[JHA]

Bonjour à tous,

Peux-tu mettrez un exemple de quelques dates afin de voir la disposition sur ton fichier.
Autrement 2 solutions dans le fichier joint.

JHA

 

[Tartanpions]

Merci beaucoup a tout les 2 je vais voir ça
JHA à quoi correspond le ‹4 à la fin de la formule, s'il te plaît?

 

[Tartanpions]

JHA la prochaine fois je lirai ton tableau jusqu'au bout le ‹4 , 4 c'est le 4eme mois
Merci encore

 

[Gégé-45550]

Bonjour,

Une proposition :

=SOMMEPROD((DATEVAL("1/1/23")<=A$2:A$100)*(A$2:A$100<DATEVAL("1/4/23")))
=SOMMEPROD((DATEVAL("1/4/23")<=A$2:A$100)*(A$2:A$100<DATEVAL("1/7/23")))
=SOMMEPROD((DATEVAL("1/7/23")<=A$2:A$100)*(A$2:A$100<DATEVAL("1/10/23")))
=SOMMEPROD((DATEVAL("1/10/23")<=A$2:A$100)*(A$2:A$100<DATEVAL("1/1/24")))

Salut l'ami !
Tu es toujours le meilleur SOMMEPRODucteur que je connaisse.
Bravo !

 

[mapomme]

Bonjour à tous,

Une autre formule pour O365 en E2 à copier vers la droite et vers le bas :

=NB(FILTRE(Tableau1[Dates];(ANNEE(Tableau1[Dates])=E$1)*((1+ENT((MOIS(Tableau1[Dates])-1)/3))=$D2)))

 

[mapomme]

Re,

Ou bien un sommeprod pour toutes les versions d'Excel.
Une autre formule pour O365 en E2 à copier vers la droite et vers le bas :

=SOMMEPROD((ANNEE(Tableau1[Dates])=E$1)*((1+ENT((MOIS(Tableau1[Dates])-1)/3)=$D2)))

 

[job75]

Bonjour,

Dès le moment où l'on utilise des dates comme limites on peut utiliser NB.SI.ENS :

=NB.SI.ENS(A:A;">="&--"1/1/23";A:A;"<"&--"1/4/23")
=NB.SI.ENS(A:A;">="&--"1/4/23";A:A;"<"&--"1/7/23")

L'intérêt c'est que les plages peuvent être illimitées.

Edit : pas besoin de parenthèses pour encadrer les dates.

A+
:

 

[Tartanpions]

Bonjour,

Dès le moment où l'on utilise des dates comme limites on peut utiliser NB.SI.ENS :

=NB.SI.ENS(A:A;">="&--("1/1/23");A:A;"<"&--("1/4/23"))
=NB.SI.ENS(A:A;">="&--("1/4/23");A:A;"<"&--("1/7/23"))

L'intérêt c'est que les plages peuvent être illimitées.

A+
:

salut, j'aime bien ta formule. J'aurai juste un petir eclaisissement à demander:
à quoi correspondent les 2 tirets du 6 : &--
Merci beaucoup, je vais tester ça

 

[Tartanpions]

voici mon fichier. Du cote vert, j'ai droit à 4 levées de conteneur par trimestre. Je ne sais compter que le nombre total, vous verrez l'évolution du truc
Encore merci à tous de votre aide

 

[job75]

à quoi correspondent les 2 tirets du 6 : &--

Ils permettent de convertir le texte à droite en nombre.

J'enlève les parenthèses inutiles.

 

[Tartanpions]

Désolé d'avoir été si long. J'ai pris la solution de JHA , c'est celle que je "comprends" le mieux et que j'adapte le plus facilement a mon problème
Merci encore à toutes et tous.