Comparaison des notes

[aek16]

Salut tout le monde
J'ai un fichier Excel qui contient des notes des trois trimestres, je voudrai mettre une fonction pour comparer les notes et indiquer s'il y a une croissance ou décroissance pour cela je veux si quelqu'un dans le forum m'aider pour résoudre ce problème
Merci d'avance

 

[job75]

Re : Comparaison des notes

Bonjour aek16,

Pour voir l'évolution des notes, on peut étudier la pente de la droite de régression des 3 notes, en utilisant la fonction DROITEREG.

Formule en D5 à tirer vers le bas :

=CHOISIR(2+SIGNE(DROITEREG(A5:C5));"-";"=";"+")

Fichier joint.

A+

 

[ROGER2327]

Re : Comparaison des notes

Bonjour à tous

Comme il n'y a que trois notes, la formule de job75 peut s'écrire simplement

[COLOR="DarkSlateGray"]=CHOISIR(2+SIGNE(C5-A5);"-";"=";"+")[/COLOR]

On utilise moins de ressources (la fonction DROITEREG est une fonction matricielle compliquée).
Dans le cas présent, DROITEREG(A5:C5) renvoie (C5-A5)/2 qui a évidemment le même signe que C5-A5.
On remarquera que la deuxième note n'a aucune influence sur le résultat trouvé.
Bien entendu, ces remarques ne sont plus valables dès lors qu'il y a plus de trois notes à prendre en compte.​

ROGER2327

 

[job75]

Re : Comparaison des notes

Bonjour Roger,

Bravo, c'est bien vu avec 3 notes, merci.

Je pense d'ailleurs qu'il faut revoir encore la formule, car des trimestres peuvent ne pa être renseignés (ou même contenir un texte comme "abs").

1) Afin d'alléger 2), définir (D5 étant sélectionnée) le nom Col par la formule :

=SI(ESTNUM(ورقة1!A5:C5);COLONNE(ورقة1!A5:C5))

2) Entrer en D5 et tirer vers le bas la formule :

=CHOISIR(2+SIGNE(INDEX(A5:C5;MAX(Col))-INDEX(A5:C5;MIN(Col)));"-";"=";"+")

A+

 

[job75]

Re : Comparaison des notes

Re,

Une modification sur la 2ème formule pour le cas où aucune note n'est entrée :

=CHOISIR(2+SIGNE(N(INDEX(A5:C5;MAX(Col)))-N(INDEX(A5:C5;MIN(Col))));"-";SI(NB(A5:C5);"=";"");"+")

A+