XL 2016 Combien de si

[Scorpio]

Bien le bonjour à tous,
J'ai dans ce classeur un exemple de 66 fois la fonction si.
J'aimerais si possible volontier savoir si il existe une autre méthode pour faire plus cour ?
Merci à vous et à plus

 

[Chris401]

Bonsoir
Vu la formule :

=SI(OU(A2="";A2>66);"Différent d'un nombre allant de 1 à 6";"VAL"&A2)

 

[M12]

Bonjour, en reprenant ta formule simplifiée

=SI(A2<67;"Val"&A2;"Différent d'un nombre allant de 1 à 6")

Mais cela ne donne pas toujours le bon résultat, car les chiffres en 7, 8, 9 sont différents d'un nombre allant de 1 à 6, comme dans ta formule

 

[job75]

Bonsoir à tous,

S'il n'y a jamais de valeurs d'erreur en colonne A, formule en B2 :

=SI(SOMMEPROD(N(A2=LIGNE(INDIRECT("1:66"))));"Val"&A2;"Différent d'un nombre entier allant de 1 à 66")

S'il peut y avoir des valeurs d'erreur en colonne A :

=SI(ESTNUM(LN(SOMMEPROD(N(A2=LIGNE(INDIRECT("1:66"))))));"Val"&A2;"Différent d'un nombre entier allant de 1 à 66")

Edit : on peut aussi utiliser des formules matricielles :

=SI(OU(A2=LIGNE(INDIRECT("1:66")));"Val"&A2;"Différent d'un nombre entier allant de 1 à 66")

=SI(ESTNUM(EQUIV(A2;LIGNE(INDIRECT("1:66"));0));"Val"&A2;"Différent d'un nombre entier allant de 1 à 66")

toutes deux à valider par Ctrl+Maj+Entrée.

A+

 

[TooFatBoy]

Bonjour,

Allez, je propose aussi ma formule 😉 :
=SI(ET(ENT(A2)=A2;A2>0;A2<67);"Val"&A2;"Différent d'un nombre allant de 1 à 66")

 

[M12]

Bonjour à tous,

Moi ma réflexion partait de la condition Différent d'un nombre allant de 1 à 6 comme noté dans sa formule
donc, je comprend avec ma p'tite tête que les nombre ne dépasse pas 66 (aucun soucis) mais que les nombre intermédiaire ne doivent pas contenir les chiffres supérieur à 6 (comme 7, 8 , 17 ,29 etc) 😉

 

[TooFatBoy]

Certes, mais ce n'est pas ce que fait sa formule avec ses 66 SI. 😉

 

[M12]

Bonsoir Marcel

C'est ce que j'ai précisé dans le post #3

Mais cela ne donne pas toujours le bon résultat, car les chiffres en 7, 8, 9 sont différents d'un nombre allant de 1 à 6, comme dans ta formule

 

[TooFatBoy]

Toutafé. 😉

 

[job75]

Bonjour le fil, le forum,

@ M12 : Scorpio a écrit "1 à 6" par erreur, il voulait bien sûr dire "1 à 66".

Avec cette formule A2 peut être un nombre, une valeur logique ou un texte :

=SI(OU(MOD(N(A2);1);A2<1;A2>66);"Différent d'un nombre entier allant de 1 à 66";"Val"&A2)

Si en plus A2 peut être une valeur d'erreur :

=SI(ESTERREUR(LN(NON(OU(MOD(A2;1);A2<1;A2>66))));"Différent d'un nombre entier allant de 1 à 66";"Val"&A2)

ou mieux, à partir d'Excel 2007 :

=SIERREUR(REPT("Val"&A2;1/NON(OU(MOD(A2;1);A2<1;A2>66)));"Différent d'un nombre entier allant de 1 à 66")

REPT évite la fonction SI qui "pèse" lourd en nombre d'octets.

Bonne journée.

 

[Scorpio]

Salut à tous, et merci de votre super soutient
Merci à job75, Marcel32, et M12
Effectivement, il y avait une erreur dans ma formule avec
Différent d'un nombre entier allant de 1 à 6, faux
Différent d'un nombre entier allant de 1 à 66, juste
Merci encore et bonne journée
A++++